Функция, возвращающая целое (вещественное) число в виде строки

function IntToString(k: integer): string;
var
  z: string;
begin
  if k < 0 then z := '-' else z := ''; //запоминаем знак числа
  k := abs(k); //убираем знак
  Result := ''; //пока результат пустая строка
  repeat //цикл преобразования числа в строку
    Result := char(ord('0') + k mod 10) + Result; //выделяем текущий младший разряд и приписываем к результату
    k := k div 10 //убираем младший разряд
  until k = 0; //продолжаем до тех пор, пока не кончатся разряды
  Result := z + Result //добавляем знак к результату
end;
//Вызывающая программа
var
  n: integer;
begin
  write('n = ');
  readln(n);
  writeln('s = ', IntToString(n));
  readln
end.

function IntToString(k: integer): string;
var
  z: string;
begin
  if k < 0 then z := '-' else z := '';
  k := abs(k);
  Result := '';
  repeat
    Result := char(ord('0') + k mod 10) + Result;
    k := k div 10
  until k = 0;
  Result := z + Result
end;
 
function RealToString(x: real): string;
var
  z: string;
  i, p: integer;
begin
  if x = 0 then Result := '0' //если число 0, то сразу результат 0
  else //иначе преобразуем число в строку
    begin
      if x < 0 then z := '-' else z := ''; //запоминаем знак
      x := abs(x); //убираем знак
      Result := ''; //результат пока пустая строка
      p := 0; //порядок пока 0
      while x < 1 do //подсчитываем порядок и нормализуем мантиссу
        begin
          dec(p);
          x := x * 10
        end;
      while x >= 10 do
        begin
          inc(p);
          x := x / 10
        end;
      for i := 1 to 15 do //цикл выделения разрядов мантиссы
        begin
          Result += char(ord('0') + trunc(x)); //выделяем и дописываем текущий старший разряд мантиссы к результату
          x := frac(x) * 10 //убираем старший разряд, на его место сдвигаем следующий
        end;
      if p in [1..15] then insert('.', Result, p + 2) else insert('.', Result, 2); //вставляем десятичную точку
      while Result[length(Result)] = '0' do delete(Result, length(Result), 1); //убираем незначащие нули
      if Result[length(Result)] = '.' then delete(Result, length(Result), 1); //если дробной части у мантиссы нет, то убираем десятичную точку
      if not (p in [0..15]) then Result += 'E' + IntToString(p); //при необходимости приписываем к числу порядок
      Result := z + Result //добавляем знак числа
    end
end;
//Вызывающая программа
var
  n: real;
begin
  write('n = ');
  readln(n);
  writeln('s = ', RealToString(n));
  readln
end.

function RealToString(x: real): string;
var
  z: string;
  i, p: integer;
begin
  if x = 0 then Result := '0'
  else
    begin
      if x < 0 then z := '-' else z := '';
      x := abs(x);
      Result := '';
      p := 0;
      while x < 1 do
        begin
          dec(p);
          x := x * 10
        end;
      while x >= 10 do
        begin
          inc(p);
          x := x / 10
        end;
      for i := 1 to 15 do
        begin
          Result += char(ord('0') + trunc(x));
          x := frac(x) * 10
        end;
      if p > 15 then for i := 16 to p do Result += '0'
      else
        begin
          if p < 0 then
            begin
              for i := p + 2 to 0 do Result := '0' + Result;
              Result := '0.' + Result
            end
          else insert('.', Result, p + 2);
          while Result[length(Result)] = '0' do delete(Result, length(Result), 1);
          if Result[length(Result)] = '.' then delete(Result, length(Result), 1)
        end;
      Result := z + Result
    end
end;
//Вызывающая программа
var
  n: real;
begin
  write('n = ');
  readln(n);
  writeln('s = ', RealToString(n));
  readln
end.