Помощь в разборе программы

program q166146;
 
const
  BITS = 32; //Размерность чисел
 
function IntToBin(dec: longint): string;
var i: integer;
    res: string;
begin
  if dec=0 then begin IntToBin:='0'; Exit; end;
  SetLength(res,BITS);
  for i:=BITS downto 1 do begin
    res[i]:=Chr((dec and 1)+48);
    dec:=dec shr 1;
  end;
  Delete(res,1,Pos('1',res)-1); //Убрать впередистоящие нули
  IntToBin:=res;
end;
 
function BinToInt(bin: string): longint;
var i: integer;
    res: longint;
begin
  res:=0;
  For i:=1 to Length(bin) do begin
    res:=res shl 1; //Сдвиг всех битов влево
    if bin[i]='1' then res:=res or 1;  //Если встретилась 1, то вставить её в число
  end;
  BinToInt:=res;
end;
 
function SumBits(b1,b2: char; var c: byte): char; //c - бит переноса
var Sum: byte;
begin
  Sum:=Ord(b1)-48+Ord(b2)-48+c;
  SumBits:=Chr(Sum mod 2 + 48);
  c:=Sum div 2; //бит переноса
end;
 
{ ---------- Сложение -------------- }
function BinsAdd(bin1,bin2: string): string;
var i: integer;
    Perenos: byte;
    res: string;
begin
  { Для сложения и вычитания нужно выровнить все строки }
  for i:=1 to BITS-Length(bin1) do bin1:='0'+bin1;
  for i:=1 to BITS-Length(bin2) do bin2:='0'+bin2;
  SetLength(res,BITS);
  Perenos:=0;
  { Цикл сложения }
  for i:=BITS downto 1 do
    res[i]:=SumBits(bin1[i], bin2[i], Perenos);
  Delete(res,1,Pos('1',res)-1); //Убрать впередистоящие нули
  BinsAdd:=res;
end;
 
{ ---------- Вычитание ------------- }
{ Вычитание делается инверсией вычитаемого, потом сложением, потом + 1}
{ c = b - a = b + inv(a) + 1 }
function BinsSub(bin1,bin2: string): string; //Возвращает bin1-bin2
var i: integer;
    Perenos: byte;
    res: string;
begin
  { Для сложения и вычитания нужно выровнить все строки }
  for i:=1 to BITS-Length(bin1) do bin1:='0'+bin1;
  for i:=1 to BITS-Length(bin2) do bin2:='0'+bin2;
  SetLength(res,BITS);
  for i:=1 to BITS do //Цикл инверсии
    if bin2[i]='0' then bin2[i]:='1' else bin2[i]:='0';
  Perenos:=1; //Сразу добавим 1
  { Цикл сложения }
  for i:=BITS downto 1 do
    res[i]:=SumBits(bin1[i], bin2[i], Perenos);
  Delete(res,1,Pos('1',res)-1); //Убрать впередистоящие нули
  BinsSub:=res;
end;
 
var
  d1,d2: longint;
  b1,b2,add,sub: string;
  Dadd,Dsub: longint;
begin
  write('Enter D1: ');
  readln(d1);
  b1:=IntToBin(d1);
  writeln(d1,' = ',b1);
  write('Enter D2: ');
  readln(d2);
  b2:=IntToBin(d2);
  writeln(d2,' = ',b2);
  add:=BinsAdd(b1,b2);
  Dadd:=BinToInt(add);
  writeln(b1,' + ',b2,' = ',add,' = ',Dadd);
  sub:=BinsSub(b1,b2);
  Dsub:=BinToInt(sub);
  writeln(b1,' - ',b2,' = ',sub,' = ',Dsub);
  readln;
end.