Разработать тип данных Prop, представляющий утверждения заданного вида

import Data.List
 
data Prop = C Bool
          | V String
          | And Prop Prop
          | Or Prop Prop 
          | Not  Prop
          deriving Show
 
vars :: Prop -> [String]
vars (C _) = []
vars (V n) = [n]
vars (And p0 p1) = vars p0 `union` vars p1
vars (Or  p0 p1) = vars p0 `union` vars p1
vars (Not p0)    = vars p0
 
truthValue :: Prop -> [(String,Bool)] -> Bool
truthValue prop v = go prop
    where go (C b) = b
          go (V n) = case lookup n v of
                        (Just r) -> r
                        _ -> error $ "truthValue : variable " ++ n ++ " not found"
          go (And p0 p1) = go p0 && go p1
          go (Or  p0 p1) = go p0 || go p1
          go (Not p0) = not $ go p0
 
mkVs :: [String] -> [[(String,Bool)]] 
mkVs = foldl (\ vs x -> concatMap (\ v -> [(x, b) : v | b <- [False, True]]) vs) [[]] 
          
tautology :: Prop -> Bool
tautology prop = all (truthValue prop) $ mkVs $ vars prop
 
main :: IO ()
main = do
    let p =  And (Or (Not $ V "y") (C False)) (V "x")
    print $ vars p  
    print $ mkVs $ vars p  
    print $ truthValue p [("x",True),("y",False)]
    print $ truthValue p [("x",True),("y",True)]
    print $ tautology p
    print $ tautology $ Or (V "x") (Not (V "x"))