Функция min4, по четырём вещественным возвращающая наименьшее из них

@Iriska-kiska · Регистрация: 28.11.2011

Студворк — интернет-сервис помощи студентам

Дорогие мои!
Помогите пожалуйста!!!
Определите функцию: функция min4, по четырём вещественным возвращающая наименьшее из них.
Ну не как не могу сделать это задание.

@Nameless One · 11.04.2012, 08:21

bokunopico, никакого математического аппарата, просто последовательно вручную применял определение композиции (в уме вряд ли получится для числа параметров, большего двух), преобразовывая выражение функции к эквивалентному и удаляя параметры справа.

Для определения #2:

Haskell
1
2
3
4
5
6
7
8
9
10
11
--min4 a b c d = min (min (min a b) c) d -- удаляем d
--min4 a b c = min (min (min a b) c) -- применяем правило композиции для c
--min4 a b c = (min . (min (min a b))) c -- удаляем c
--min4 a b = min . (min (min a b)) -- композиция для b
--min4 a b = min . ((min . (min a)) b) -- (a . b) == ((.) a b) (префиксная запись инфиксного оператора)
--min4 a b = (.) min ((min . (min a)) b) -- композиция для b; меняем префиксную запись оператора (.) на инфиксную
--min4 a b = ((min .) . ((min . (min a)))) b --удаляем b
--min4 a = (min .) . (min . (min a)) -- меняем инфиксную запись на префиксную; композиция для a
--min4 a = (.) (min .) ((((.) min) . (min)) a) -- композиция для a
--min4 a = (((.) (min .)) . (((.) min) . (min))) a -- удаляем a; меняем префиксную запись на инфиксную
min4 = ((min .) .) . (min .) . min -- окончательная запись

Для определения #1 посложнее:

Haskell
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
min4 :: Double -> Double -> Double -> Double -> Double
--min4 a b c d = min a (min b (min c d))
--min4 a b c d = min a (((min b) . (min c)) d)
--min4 a b c d = ((min a) . ((min b) . (min c))) d
--min4 a b c = (min a) . ((min b) . (min c))
--min4 a b  = ((.) (min a)) . ((((.) . min) b) . min)
--min4 a b  = ((.) (min a)) . ((. min) (((.) . min) b))
--min4 a b  = (.) ((.) (min a)) ((. min) (((.) . min) b))
--min4 a b  = (.) ((.) (min a)) (((. min) . ((.) . min)) b)
--min4 a = (.) ((.) (min a)) . ((. min) . (.) . min)
--min4 a = flip (.) ((. min) . (.) . min) ((.) ((.) (min a))) -- (flip (.) a) == (. a)
--min4 a = (. (. min) . (.) . min) ((.) ((.) (min a)))
--min4 a = (. (. min) . (.) . min) ((.) (((.) . min) a))
--min4 a = (. (. min) . (.) . min) (((.) . (((.) . min))) a)
--min4 = (. (. min) . (.) . min) . (((.) . (((.) . min))))
--min4 = (. (. min) . (.) . min) . ((.) . (((.) . min)))
--min4 = (. (. min) . (.) . min) . ((.) . ((.) . min))
min4 = (. (. min) . (.) . min) . (.) . (.) . min -- окончательная запись

Сообщение от 9Символов

А почему он называется безточечным?

http://www.haskell.org/haskellwiki/Pointfree

A common misconception is that the 'points' of pointfree style are the (.) operator (function composition, as an ASCII symbol), which uses the same identifier as the decimal point. This is wrong. The term originated in topology, a branch of mathematics which works with spaces composed of points, and functions between those spaces. So a 'points-free' definition of a function is one which does not explicitly mention the points (values) of the space on which the function acts. In Haskell, our 'space' is some type, and 'points' are values. In the declaration

Haskell
1
f x = x + 1

we define the function f in terms of its action on an arbitrary point x. Contrast this with the points-free version:

Haskell
1
f = (+ 1)

where there is no mention of the value on which the function is acting.

@9Символов · 11.04.2012, 08:26

Nameless One, Опа! Нашёл в википедии: по-русски это комбинаторное программирование.

@Nameless One · 11.04.2012, 08:30

9Символов, термин «безточечный» в применении к Хаскелю распространен больше.

@Buckminster · 11.04.2012, 16:00

Сообщение от 9Символов

А почему он называется безточечным?

данные – это точки в топологическом пространстве, над которым производятся преобразования (функции)...
нет данных – нет точек...

Сообщение от Nameless One

термин «безточечный» в применении к Хаскелю распространен больше

м-да, особенно тонко в этом смысле звучит выражение "pointless Haskell"

Сообщение от Nameless One

никакого математического аппарата, просто последовательно вручную применял определение композиции [..], преобразовывая выражение функции к эквивалентному и удаляя параметры справа

тогда уж можно пойти ещё дальше, и удалить и

функции

Haskell
1
2
3
4
5
6
7
8
9
10
--min3 a b c = min (min a b) c 
--min3 = (.) ((.) min) min
 
--dd f g = (.) ((.) f) g
dd = (.).(.)
 
min3 = dd min min
 
> min3 2 1 3
1

или даже

так

Haskell
1
2
3
4
5
6
7
8
--dd = (.)(.)(.)
d = (.)
dd = d d d 
 
> dd min min 2 1 3
1
> dd (+) (*) 2 2 2
6

правда, для большего числа аргументов уже не так

изящно

Haskell
1
2
3
4
5
6
7
8
--min4 = ((min .) .) . (min .) . min
--ddd f g h = ((f .) .) . (g .) . h
ddd = d (flip d d) (d (d d) ((d d) (d d d)))
 
> ddd min min min 2 3 1 4
1
> ddd (+) (-) (^) 2 3 1 4
11

@Nameless One · 11.04.2012, 16:08

Buckminster, поздравляю, ты придумал еще один комбинатор

@Buckminster · 11.04.2012, 16:52

Не по теме:

Сообщение от Nameless One

Buckminster, поздравляю, ты придумал еще один комбинатор :D

подумаешь! 8-)

в общем, предлагаю считать окончательным следующий весьма естественный вариант:

Haskell
1
2
3
4
5
6
7
min4 :: Ord a => a -> a -> a -> a -> a
min4 = ((.(.)).((.)(.).((.).((.).(.))))) min min min
 
--или просто:
> ((.(.)).((.)(.).((.).((.).(.))))) min min min 2 1 3 4
1
--по-моему, очень симпатично :)

@9Символов · 11.04.2012, 19:28

Насчёт безточечного определения.
ВОт есть например:

Haskell
1
2
f = sqrt
g a b c= a+b+c

Хотим привести функцию к безточечному стилю.
Ну начали:

Haskell
1
2
3
k a b c = f (g a b c) --начальная функция
k a b = f . (g a b) --отбросил с
k a b = (f . g a b) --застрял, так как вроде-бы не к чему тут композицию применить

Возможно ли её дальше с помощью "." преобразовать? И если да, то как?

p.s. До этого определения дошёл методом тыка.

@Buckminster · 12.04.2012, 13:18

Сообщение от 9Символов

Возможно ли её дальше с помощью "." преобразовать?

Haskell
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
f = sqrt
g a b c= a+b+c
 
--k a b c = f (g a b c)
--k a b c = f ((g a b) c)
--k a b c = (f . (g a b)) c
 
--k a b = f . (g a b)
--k a b = (f .) ((g a) b)
--k a b = ((f .) . (g a)) b
 
--k a = (f .) . (g a)
--k a = ((f .) .) (g a)
--k a = (((f .) .) . g) a
 
k = ((f .) .) . g

app

и традиционно уже избавимся также и от функций:

Haskell
1
2
3
4
5
6
7
8
9
--k = ((f .) .) . g
--k' f g = ((f .) .) . g
--k' f = (((f .) .) .)
--k' f = ((((.) f) .) .)
--k' f = (((.) ((.) f)) .)
--k' f = (.) ((.) ((.) f))
--k' f = (.) (((.).(.)) f)
--k' f = ((.).((.).(.))) f
k' = (.).((.).(.))

или через комбинатор d:

Haskell
1
2
3
4
d = (.)
 
--k' = (.) (.) ((.) (.) (.))
k' = d d (d d d)

в итоге получаем:

Haskell
1
2
> d d (d d d) f g 2 3 4
3.0

всё это, с одной стороны, довольно забавно, но чтобы тут во всём хорошенько разобраться, нужны, конечно же, глубокие самостоятельные исследования (пора бы мне уже и самому прочитать пару книжек по Haskell, а то на голом энтузязизьме далеко не уедешь)... вот ещё одна статья про комбинаторы: Комбинаторы — это просто! (2006)

@9Символов · 14.04.2012, 11:41

Пытался сделать более обобщённый комбиатор: вводишь ему цифру -- кол-во переменных у "2-ой" функции, от которой берётся первая ф-я от 1-й переменной. Ну из ваших выкладо, очевидно:

Haskell
1
2
 (( . ) . ( . )) -- комбинатор для ф-ий 1 и 2 переменных.
(( . ) . ( . ) . ( . )) -- для 1 и 3х переменных

Напрашивается обобщение:

Haskell
1
(\n->foldl1 (.) (replicate n (.)))

Но не получается.

Haskell
1
2
3
4
5
6
7
8
9
10
11
12
13
<interactive>:1:31:
    Occurs check: cannot construct the infinite type: c0 = a0 -> c0
    Expected type: (b0 -> c0) -> b0 -> c0
      Actual type: (b0 -> c0) -> (a0 -> b0) -> a0 -> c0
    In the second argument of `replicate', namely `(.)'
    In the second argument of `foldl1', namely `(replicate n (.))'
 
<interactive>:1:31:
    Occurs check: cannot construct the infinite type: b0 = a0 -> b0
    Expected type: (b0 -> c0) -> b0 -> c0
      Actual type: (b0 -> c0) -> (a0 -> b0) -> a0 -> c0
    In the second argument of `replicate', namely `(.)'
    In the second argument of `foldl1', namely `(replicate n (.))'

И я, честно-говоря, не знаю, как ему скормить что-то подобное.

Не по теме:

И это... как вы так код "прячете"?

@Buckminster · 14.04.2012, 14:32

off

Сообщение от 9Символов

как вы так код "прячете"?

кнопка CUT на панели инструментов (п.4)

Сообщение от 9Символов

Occurs check: cannot construct the infinite type

а каков будет тип полученной функции? интерпретатор должен это знать наверняка... а в данной ситуации тип не определён...

собственно, по ошибке:

types

Haskell
1
2
3
4
5
6
7
8
> :t foldl1
foldl1 :: (a -> a -> a) -> [a] -> a
 
> :t (.)
(.) :: (b -> c) -> (a -> b) -> a -> c
 
> :t replicate 2 (.)
replicate 2 (.) :: [(b -> c) -> (a -> b) -> a -> c]

т.е., функция foldl1 требует на входе функцию вида
(a -> a -> a)
а получает
(.) :: (b -> c) -> (a -> b) -> a -> c
в то время как согласно типу элементов списка должна получать
((b -> c) -> (a -> b) -> a -> c) -> ((b -> c) -> (a -> b) -> a -> c) -> ((b -> c) -> (a -> b) -> a -> c)

тогда уж лучше использовать этот подход (возвращается либо число, либо функция – по аналогии с printf)...
или, опять же, Template Haskell – он вроде как позволяет формировать код "на лету"...

why

очень знакомая ситуация...

Surely You're Joking, Mr. Feynman!

Сообщение от Вы, конечно, шутите, мистер Фейнман!

...А что касается мистера Френкеля, который затеял всю эту деятельность, то он начал страдать от компьютерной болезни - о ней сегодня знает каждый, кто работал с компьютерами. Это очень серьезная болезнь, и работать при ней невозможно. Беда с компьютерами состоит в том, что ты с ними играешь. Они так прекрасны, столько возможностей - если четное число, делаешь это, если нечетное, делаешь то, и очень скоро на одной-единственной машине можно делать все более и более изощренные вещи, если только ты достаточно умен.

Через некоторое время вся система развалилась. Френкель не обращал на нее никакого внимания, он больше никем не руководил. Система действовала очень-очень медленно, а он в это время сидел в комнате, прикидывая, как бы заставить один из табуляторов автоматически печатать арктангенс x. Потом табулятор включался, печатал колонки, потом - бац, бац, бац - вычислял арктангенс автоматически путем интегрирования и составлял всю таблицу за одну операцию.

Абсолютно бесполезное занятие. Ведь у нас уже были таблицы арктангенсов. Но если вы когда-нибудь работали с компьютерами, вы понимаете, что это за болезнь - восхищение от возможности увидеть, как много можно сделать. Френкель подцепил эту болезнь впервые, бедный парень; бедный парень, который изобрел всю эту штуку.

@9Символов · 14.04.2012, 14:39

Сообщение от Buckminster

функция foldl1 требует на входе функцию вида
(a -> a -> a)
а получает
(.) :: (b -> c) -> (a -> b) -> a -> c
в то время как согласно типу элементов списка должна получать

Хм... то-есть вы хотите сказать, что ( . ) не применима в foldr1?
Но ведь это работает:

Haskell
1
2
Prelude> foldl1 ( . ) [sqrt, (+2)] 1
1.7320508075688772

@Buckminster · 14.04.2012, 14:46

Сообщение от 9Символов

Но ведь это работае

тип функции, подаваемой на вход foldl1, должен соответствовать типу элементов списка... здесь всё в порядке:

Haskell
1
2
3
4
5
6
7
8
9
10
11
12
13
14
> :t sqrt
sqrt :: Floating a => a -> a
 
> :t (+2)
(+2) :: Num a => a -> a
 
> :t [sqrt, (+2)]
[sqrt, (+2)] :: Floating a => [a -> a]
 
> :t (.)
(.) :: (b -> c) -> (a -> b) -> a -> c
 
> :t foldl1 (.) [sqrt, (+2)]
foldl1 (.) [sqrt, (+2)] :: Floating c => c -> c

@9Символов · 14.04.2012, 15:01

Но здесь-то, например точка посредине ведёт себя таким образом:

Haskell
1
(( . ) . ( . ))

то есть берёт 2 комбинатора одного типа, возвращает 3-ий того-же типа.
А в foldr1 почему она подобно себя не ведёт? Может всё-таки версия про то, что надо исп. template haskell вернее? Ведь если бы просто тип не соответствовал, он бы так и писал, то ожидается одно, а на деле ему дают другое.

@Buckminster · 14.04.2012, 15:07

Сообщение от 9Символов

Но здесь-то, например точка посредине ведёт себя таким образом: [...] берёт 2 комбинатора одного типа, возвращает 3-ий того-же типа

не совсем, типы не совпадают:

Haskell
1
2
3
4
5
> :t (.)
(.) :: (b -> c) -> (a -> b) -> a -> c
 
> :t (.).(.)
(.).(.) :: (b -> c) -> (a -> a1 -> b) -> a -> a1 -> c

Сообщение от 9Символов

если бы просто тип не соответствовал, он бы так и писал, то ожидается одно, а на деле ему дают другое

собственно, он так и пишет:

Haskell
1
2
3
    Occurs check: cannot construct the infinite type: c0 = a0 -> c0
    Expected type: (b0 -> c0) -> b0 -> c0
      Actual type: (b0 -> c0) -> (a0 -> b0) -> a0 -> c0

т.е. нужен c0, а получает c0 = a0 -> c0, отсюда зацикливание и бесконечный тип (infinite type)...

@9Символов · 14.04.2012, 15:10

Сообщение от Buckminster

не совсем, типы не совпадают:

Haskell
1
2
3
4
5
> :t (.)
(.) :: (b -> c) -> (a -> b) -> a -> c
 
> :t (.).(.)
(.).(.) :: (b -> c) -> (a -> a1 -> b) -> a -> a1 -> c

И вправду, сморозил фигню.

@Iriska-kiska · 04.05.2012, 15:32 **[ТС]**

Друзья, а как это все осуществить в компиляторе GHCi?
Вместо ответа одни ошибки.

@Nameless One · 04.05.2012, 15:33

Iriska-kiska, либо использовать let перед определением функции, либо записывать определение функции в файл и делать

Code
1
:load файл

в GHCi

Новые блоги и статьи Все статьи Все блоги /
Особенности gif сгенерированных в Си russiannick 21.10.2026 Рассмотрим генерацию gif файлов, которые в Си имеют свои особенности. Gif представляет собой графический формат популярный в интернете. Посмотрим на палитру. Gif файл сгенерированный в си отличается. . .	FPS контроллер с анимированными Y-Bot и 3D-звуком miniaudio (Box3D, Recast, BehaviorTree.CPP, ozz-animation, ImGui, OpenGL и SDL3) 8Observer8 18.10.2026 Содержание блога \| English Version Полное мультиплатформенное руководство по стартовому проекту с FPS-контроллером игрока, анимированными роботами Y-Bot с 4-слойным блендингом, 3D-физикой Box3D,. . .	Локальный http сервер Argus19 17.10.2026 Локальный http сервер На работе, на двух локальных компьютерах круглосуточно работают программы опроса приборов с записью в книги Excel,которые раз в сутки записываются на сервер компании. Т. к. . . .	Копировать Windows на новый диск на UEFI damix 17.10.2026 https:/ / uriesk. wordpress. com/ 2016/ 11/ 01/ move-window-10-to-ssd-on-a-uefi-dualboot-system-with-basic-linux-tools/ TL DR Вставляем диск, а старый подключаем через переходник, грузимся с лайва. . .
ИИ не может найти нужный язык в списке Supersumestria 05.10.2026 Я ему даю вот такое изображение и прошу найти и подчеркнуть немецкий язык. Возвращает он вот это: https:/ / i. **********/ vqBWLe2. png Нужную строчку в 3й колонке просто выдумал. . Это. . .	Новая последняя моя музыка в SUNO zorxor 05.10.2026 Здравствуйте, дорогие мои друзья! С большой радостью я хотел бы представить вам свою новую последнею музыку, которую сгенерировала мне по моей просьбе нейросеть SUNO. С уважением, zorxor. Это. . .	Программный домашний кинотеатр russiannick 27.09.2026 Сподобился на программный домашний кинотеатр. В качестве ЯВУ по традиции выбрал js. В помощники взял Яндекс-Алису. Было создано три зала на разные интересы. исторические и ретро сериал Хичкок. . .	Беседа с ИИ о программистах, недопускающих к созданию и правке кода генеративные ИИ и причины этого zorxor 21.09.2026 Раньше я радовался или получал некоторые эмоции, пусть небольшие, но всё же, от самого процесса написания кода, рекомпиляции и запуска, видя постепенное развитие программы и прочее. А теперь лень. . .

@Iriska-kiska 89 / 10 / 0 Регистрация: 28.11.2011 Сообщений: 21

	Функция min4, по четырём вещественным возвращающая наименьшее из них 09.04.2012, 14:20. Показов 5321. Ответов 36 Метки нет (Все метки) Дорогие мои! Помогите пожалуйста!!! Определите функцию: функция min4, по четырём вещественным возвращающая наименьшее из них. Ну не как не могу сделать это задание. 0

@9Символов 7 / 7 / 0 Регистрация: 25.03.2012 Сообщений: 72
	11.04.2012, 08:26
	Nameless One, Опа! Нашёл в википедии: по-русски это комбинаторное программирование. 0

@Nameless One 5828 / 3479 / 358 Регистрация: 08.02.2010 Сообщений: 7,448
	11.04.2012, 08:30
	9Символов, термин «безточечный» в применении к Хаскелю распространен больше. 0

@Nameless One 5828 / 3479 / 358 Регистрация: 08.02.2010 Сообщений: 7,448
	11.04.2012, 16:08
	Buckminster, поздравляю, ты придумал еще один комбинатор 0

@Iriska-kiska 89 / 10 / 0 Регистрация: 28.11.2011 Сообщений: 21
	04.05.2012, 15:32 [ТС]
	Друзья, а как это все осуществить в компиляторе GHCi? Вместо ответа одни ошибки. 0

Функция min4, по четырём вещественным возвращающая наименьшее из них

Решение