Clojure Дать описание фрагмента программы, в котором определяется количество нечетных, отрицательных четных и прочих элементов

(defun task (lst)
  (let* ((num-odd (length (remove-if-not #'oddp lst)))
         (num-neg-even (length (remove-if-not #'(lambda (x) (and (minusp x) (evenp x))) lst)))
         (num-other (- (length lst) num-odd num-neg-even)))
    (list num-odd num-neg-even num-other)))
 
==> task
 
(task '(1 2 3 -1 -2 -3))
 
==> (4 1 1)

(defun task (lst &optional (num-odd 0) (num-neg-even 0) (num-other 0))
  (cond ((null lst) (list num-odd num-neg-even num-other))
        ((oddp (car lst)) (task (cdr lst) (+ 1 num-odd) num-neg-even num-other))
        ((and (evenp (car lst)) (minusp (car lst))) (task (cdr lst) num-odd (+ 1 num-neg-even) num-other))
        (t (task (cdr lst) num-odd num-neg-even (+ 1 num-other)))))
 
 
==> task
 
(task '(1 2 3 -1 -2 -3))
 
==> (4 1 1)

(defun task (lst)
  (let ((num-odd 0)
        (num-neg-even 0)
        (num-other 0))
    (dolist (i lst (list num-odd num-neg-even num-other))
        (cond ((oddp i) (setq num-odd (+ 1 num-odd)))
              ((and (evenp i) (minusp i)) (setq num-neg-even (+ 1 num-neg-even)))
              (t (setq num-other (+ 1 num-other))))))) 
 
==> task
 
(task '(1 2 3 -1 -2 -3))
 
==> (4 1 1)

(defun Score (ls)
  (defstruct score (odd 0) (neg-even 0) (other 0))
  (let ((ins (make-score)))
    (dolist (i ls)
      (cond
        ((oddp i)
         (setf (score-odd ins)
               (1+ (score-odd ins))))
        ((and (evenp i) (minusp i))
         (setf (score-neg-even ins)
               (1+ (score-neg-even ins))))
        (t (setf (score-other ins)
                 (1+ (score-other ins))))))
    (format t "ODD: ~12D~%NEGATIVE-EVEN: ~2D~%OTHER: ~10D~%"
      (score-odd ins) (score-neg-even ins) (score-other ins))))
 
> (Score '(11 -63 51 -32 98 -6 44 -59 55 -67 18 -24 0 -85 29 -20 36 -62 22 -41))
ODD:            9
NEGATIVE-EVEN:  5
OTHER:          6

(defun count-all (w)
  (values (count-if #'oddp w)
          (count-if #'(lambda (a) (and (minusp a) (evenp a))) w)
          (count-if-not #'(lambda (a)
                            (or (oddp a)
                                (and (minusp a) (evenp a))))
                        w)))
 
> (count-all '(1 2 3 -1 -2 -3))
4
1
1
> (count-all '(11 -63 51 -32 98 -6 44 -59 55 -67 18 -24 0 -85 29 -20 36 -62 22 -41))
9
5
6

(defun count-all (w &aux
                  (a (count-if #'oddp w))
                  (b (count-if #'(lambda (a)
                                   (and (minusp a)
                                        (evenp a)))
                               w)))
  (values a b (- (length w) a b)))
 
> (count-all '(1 2 3 -1 -2 -3))
4
1
1
> (count-all '(11 -63 51 -32 98 -6 44 -59 55 -67 18 -24 0 -85 29 -20 36 -62 22 -41))
9
5
6

(defn task [coll]
  (map count ((juxt (partial filter odd?)
                    (partial filter (every-pred even? neg?))
                    (partial remove (some-fn odd? neg?)))
              coll)))
;; => #'user/task
 
(task '(1 2 3 0 -1 -2 -3))
;; => (4 1 2)
 
(task '(11 -63 51 -32 98 -6 44 -59 55 -67 18 -24 0 -85 29 -20 36 -62 22 -41))
;; => (9 5 6)

(defun count-all (w)
  (loop for a in w
        if (oddp a)
        collect a into odds
        else
        if (and (minusp a) (evenp a))
        collect a into mevens
        else collect a into ramp
        finally (return (values (length odds)
                                (length mevens)
                                (length ramp)
                                odds
                                mevens
                                ramp))))
 
> (count-all '(1 2 3 -1 -2 -3))
4
1
1
(1 3 -1 -3)
(-2)
(2)
> (count-all '(11 -63 51 -32 98 -6 44 -59 55 -67 18 -24 0 -85 29 -20 36 -62 22 -41))
9
5
6
(11 -63 51 -59 55 -67 -85 29 -41)
(-32 -6 -24 -20 -62)
(98 44 18 0 36 22)

(defun count-all (w &optional o me r &aux (a (car w)) (d (cdr w)))
  (cond ((null w) (values (length o) (length me) (length r) o me r))
        ((oddp a) (count-all d (cons a o) me r))
        ((and (minusp a) (evenp a)) (count-all d o (cons a me) r))
        (t (count-all d o me (cons a r)))))
 
> (count-all '(11 -63 51 -32 -6 44 -59 55 -67 -24 0 -85 29))
8
3
2
(29 -85 -67 55 -59 51 -63 11)
(-24 -6 -32)
(0 44)

(defun task (lst)
  (let ((odd 0) (even-neg 0) (other 0))
    (iter (for i in lst) (if (oddp i) (counting i into odd) 
                             (if (and (minusp i) (evenp i)) (counting i into even-neg)
                                 (counting i into other))))
    (list odd even-neg other))) 
 
==> task
 
(task '(1 2 3 -1 -2 -3))
 
==> (4 1 1)

(defun count-all (w)
  (loop for a in w
        if (oddp a) count a into o
        else
        if (and (minusp a) (evenp a))
        count a into me
        else count a into r
        finally (return (values o me r))))
 
> (count-all '(11 -63 51 -32 -6 44 -59 55 -67 -24 0 -85 29))
8
3
2

(defun count-all (w &optional (o 0) (me 0) (r 0)
                  &aux (a (car w)) (d (cdr w)))
  (cond ((null w) `(,o ,me ,r))
        ((oddp a) (count-all d (1+ o) me r))
        ((and (minusp a) (evenp a)) (count-all d o (1+ me) r))
        ((count-all d o me (1+ r)))))
 
> (count-all '(11 -63 51 -32 -6 44 -59 55 -67 -24 0 -85 29))
(8 3 2)