Задача из раздела "С++ для начинающих" (шифр Цезаря)

(defun decoder (text denom)
  (let ((res "") (l (strLen text)))
    (dotimes (i l res)
        (setq res (strCat res (strChr (% (abs (- denom (strAsc (strMid text (1+ i) 1)))) 256)))))))
 
(defun task (text word)
  (dotimes (i 32 nil)
    (let ((dec-text (decoder text i)))
      (when (<> 0 (strInd dec-text word)) (return (list i dec-text))))))
 
==> task
 
(task "й*ТОЭ*вКНКи*ЩШ*ЦШЫФМП" "ШАГАЮ")
 
==> (10 "Я ИДУ ШАГАЮ ПО МОСКВЕ")
 
(task "ю?згт?чЯвЯэ?он?лнрйбд" "ШАГАЮ")
 
==> (31 "Я ИДУ ШАГАЮ ПО МОСКВЕ")
 
(task "ю?згт?чЯвЯэ?он?лнрйбд" "БУХ")
 
==> NIL ;; не расшифровывается...

(defgeneric caesar-decode (source key))
 
(defmethod caesar-decode ((c character) (key integer))
  (let* ((x (char-code c))
         (d (mod (- x key) char-code-limit)))
    (code-char d)))
 
(defmethod caesar-decode ((s string) (key integer))
  (with-output-to-string (out)
    (loop :for char :across s
          :do (write-char (caesar-decode char key) out))))
 
(defun guess-caesar-decode (text word &key (min-key 0) (max-key 32))
  (loop :for key :from min-key :to max-key
        :for decoded-text := (caesar-decode text key)
        :when (search (string-upcase word) (string-upcase decoded-text))
        :do (return (values decoded-text key))))
 
(defun test-one (text word &key (min-key 0) (max-key 32))
  (multiple-value-bind (decoded-text key)
      (guess-caesar-decode text word :min-key min-key :max-key max-key)
    (if key
        (format t "~&~s -> ~s (key = ~d).~%" text decoded-text key)
        (format t "~&~s - can not decode with key in [~d..~d] and word ~s.~%"
                text min-key max-key word))))
 
(defun test ()
  (test-one "й*ТОЭ*вКНКи*ЩШ*ЦШЫФМП" "ШАГАЮ")
  (test-one "ю?згт?чЯвЯэ?он?лнрйбд" "ШАГАЮ")
  (test-one "ю?згт?чЯвЯэ?он?лнрйбд" "БУХ"))

CL-USER 15 > (test)
"й*ТОЭ*вКНКи*ЩШ*ЦШЫФМП" -> "Я ИДУ ШАГАЮ ПО МОСКВЕ" (key = 10).
"ю?згт?чЯвЯэ?он?лнрйбд" -> "Я ИДУ ШАГАЮ ПО МОСКВЕ" (key = 31).
"ю?згт?чЯвЯэ?он?лнрйбд" - can not decode with key in [0..32] and word "БУХ".
NIL