Написать драйвер для мышки

; проверено под 'FreeDOS'(без драйвера мыши) на виртуальной машине 'VirtualBox'
; работает нормально, но может виснуть при выключении [Esc]
org 100h
;-----------------------------------
; включение мыши
     call PR_1
     mov al, 0d4h
     out 64h, al
     call PR_1
     mov al, 0f4h
     out 60h, al
;-----------------------------------
; обработка информации от мыши
krug_1:
     in al, 64h
     and al, 21h
     cmp al, 21h
     jnz krug_1     ; если от мыши нет новостей, то на krug_1
     in al, 60h
     mov [per_1], al ; кнопки мыши
     call PR_2
     jnz krug_1     ; если слишком долго ждём байт с данными, то это сбой синхронизации идём на krug_1
     in al, 60h
     mov [per_2], al ; перемещение по горизонтали
     call PR_2
     jnz krug_1     ; если слишком долго ждём байт с данными, то это сбой синхронизации идём на krug_1
     in al, 60h
     mov [per_3], al ; перемещение по вертикали
     
;-------------------
     
     mov ah, 2h
     mov dl, ' '
     mov bl, [per_1]
     
     call PR_PEHAT_BAITA
     int 21h
     mov bl, [per_2]
     call PR_PEHAT_BAITA
     int 21h
     mov bl, [per_3]
     call PR_PEHAT_BAITA
     mov dl, 0dh
     int 21h
     mov dl, 0ah
     int 21h
     mov ah, 1h
     int 16h
     jz krug_1
     mov ah, 10h
     int 16h
     cmp ax, 11b
     jnz krug_1
     int 20h
     
     
     
     
     
;----------------------------------------
; печать байта
     
     
PR_PEHAT_BAITA:
     push ax
     push dx
     mov ah, 2h
     mov dl, bl
     shr dl, 4h
     call .pr_1
     mov dl, bl
     and dl, 0fh
     call .pr_1
     pop dx
     pop ax
     ret
     
.pr_1:
     or dl, '0'
     cmp dl, '9'
     jna .m_1
     add dl, 7h
.m_1:
     int 21h
     ret
     
     
;----------------------------------------
; процедура ожидания готовности
; принятия байта в процессе включения мыши
     
     
PR_1:
     in al, 64h
     test al, 2h
     jnz PR_1
     ret
     
;----------------------------------------
; процедура ожидания байта информации
; от мыши
     
PR_2:
     mov cx, 0ffffh
.krug_1:
     in al, 64h
     and al, 21h
     cmp al, 21h
     loopnz .krug_1
     ret
     
;================================================================================
 
per_1: db 0h
per_2: db 0h
per_3: db 0h