Открытие PDF в Access

'возможно требуется передекларировать API
Private Declare Function FindExecutable Lib "shell32" Alias "FindExecutableA" ( _
        ByVal lpFile As String, _
        ByVal lpDirectory As String, _
        ByVal lpResult As String) As Long
        
Private Declare Function GetShortPathName Lib "kernel32" Alias "GetShortPathNameA" ( _
        ByVal lpszLongPath As String, _
        ByVal lpszShortPath As String, _
        ByVal lBuffer As Long) As Long
             
 
Public Sub NewFollowHyperlink(Address As String)'<-путь и имя файла
Dim strAppName As String
Dim lngRetVal As Long
 
On Error Resume Next
strAppName = String$(255, 32)
lngRetVal = FindExecutable(Address, vbNullString, strAppName)
    If lngRetVal > 32 Then
        strAppName = Left$(strAppName, InStr(strAppName, Chr$(0)) - 1)
    Else '<-тут можешь предложить установку своей программы.
        MsgBox "Не найдена ассоциированная с файлом " & Chr$(34) & Address & Chr$(34) & " программа!"
        Exit Sub
    End If
lngRetVal = VBA.Shell(Chr$(34) & GetShortPath(strAppName) & Chr$(34) & " " & Chr$(34) & GetShortPath(Address) & Chr$(34), vbNormalFocus)
    If lngRetVal = 0 Then MsgBox "Не могу открыть файл!"
End Sub
 
'Получение имени файла в формате 8.3
Public Function GetShortPath(strFileName As String) As String
Dim lngRes As Long, strPath As String
 
    strPath = Space(255)
1:
    lngRes = GetShortPathName(strFileName, strPath, Len(strPath))
        If lngRes > 0 And lngRes <= Len(strPath) Then
            GetShortPath = Left$(strPath, lngRes)
        ElseIf lngRes > Len(strPath) Then 'не хватило буфера, хотя это маловероятно
            strPath = Space(lngRes)
            GoTo 1
        Else
            GetShortPath = strFileName
        End If
End Function