Как создать таблицу со всеми допустимыми типами полей?

' *** Создать таблицу ***
' *** *** *** *** *** ***
Private Sub CreateTable()
        
        Dim strTableName As String ' Название таблицы
        Dim tbl As TableDef                 ' объект таблица
        Dim fld As Field                        ' объект поле
        
        Dim rst As Recordset               ' объект набор записей
        
        
        strTableName = "Table_Test"
        
     
        ' Удаляем прошлое
            On Error Resume Next
                    CurrentDb.TableDefs.Delete strTableName
                Err.Clear
        
        ' Создать таблицу дней недели
        On Error GoTo CreateTableErr
        
        'создание объектной переменной таблицы, полей и индекса в ней
            Set tbl = CurrentDb.CreateTableDef(strTableName)
            With tbl
                .Fields.Append tbl.CreateField("dbBigInt", dbBigInt, 250)
                .Fields.Append tbl.CreateField("dbBinary", dbBinary, 250)
                .Fields.Append tbl.CreateField("dbBoolean", dbBoolean, 250)
                .Fields.Append tbl.CreateField("dbByte", dbByte, 250)
                .Fields.Append tbl.CreateField("dbChar", dbChar, 250)
                .Fields.Append tbl.CreateField("dbCurrency", dbCurrency, 250)
                .Fields.Append tbl.CreateField("dbDate", dbDate, 250)
                .Fields.Append tbl.CreateField("dbDecimal", dbDecimal, 250)
                .Fields.Append tbl.CreateField("dbDouble", dbDouble, 250)
                ' .Fields.Append tbl.CreateField("dbFloat", dbFloat, 250) ' Ошикба !"
                .Fields.Append tbl.CreateField("dbGUID", dbGUID, 250)
                .Fields.Append tbl.CreateField("dbInteger", dbInteger, 250)
                .Fields.Append tbl.CreateField("dbLong", dbLong, 250)
                .Fields.Append tbl.CreateField("dbLongBinary", dbLongBinary, 250)
                .Fields.Append tbl.CreateField("dbMemo", dbMemo, 250)
                .Fields.Append tbl.CreateField("dbNumeric", dbNumeric, 250)
                .Fields.Append tbl.CreateField("dbSingle", dbSingle, 250)
                .Fields.Append tbl.CreateField("dbText", dbText, 250)
              '   .Fields.Append tbl.CreateField("dbTime", dbTime, 250)  ' Ошикба !"
               ' .Fields.Append tbl.CreateField("dbTimeStamp", dbTimeStamp, 250) ' Ошикба !"
                 .Fields.Append tbl.CreateField("dbVarBinary", dbVarBinary, 250)
            End With
        
        ' Фактическое добавление таблицы из объектной переменной описанной выше
         CurrentDb.TableDefs.Append tbl
        
        
CreateTableBye:
            On Error Resume Next
            Set tbl = Nothing
            rst.Close
            Set rst = Nothing
            Exit Sub
        
CreateTableErr:
            MsgBox "Произошла ошибка при выполнении процедуры " & _
            "[CreateTable] :" & vbCrLf & _
            Err.Description & vbCrLf & _
            "Номер ошибки = " & Err.Number, vbCritical
            Resume CreateTableBye
End Sub

Private Sub CreateTableAndFields()
'Создадание таблицы с различными типами полей
Dim strTableName As String ' Название таблицы
Dim tbl As DAO.TableDef    ' объект таблица
Dim fld As DAO.Field
        
        strTableName = "Table_Test"
        
     
' Удаляем прошлое
    On Error Resume Next
    CurrentDb.TableDefs.Delete strTableName
    Err.Clear
 
        '
On Error GoTo CreateTableAndFields_Err
 
        
'создание объектной переменной таблицы, полей и индекса в ней
    Set tbl = CurrentDb.CreateTableDef(strTableName)
    With tbl
        .Fields.Append tbl.CreateField("fldText", dbText, 255)    'короткий текст
        .Fields.Append tbl.CreateField("fldMemo", dbMemo)         'Memo (длинный текст)
        .Fields.Append tbl.CreateField("fldDouble", dbDouble)     'числовой Double
        .Fields.Append tbl.CreateField("fldLong", dbLong)         'BigInt = Long Integer
        .Fields.Append tbl.CreateField("fldDate", dbDate)         'Дата время
        .Fields.Append tbl.CreateField("fldCurrency", dbCurrency) 'Денежный
        
 
        'Long Integer - счётчик
        Set fld = tbl.CreateField("fldAutoKey", dbLong)
        With fld 'Определение свойств поля
            .Attributes = dbAutoIncrField
        End With
        .Fields.Append fld 'Добавление
        
        .Fields.Append tbl.CreateField("fldBoolean", dbBoolean) 'Логический
    
        'OLE = 11
        .Fields.Append tbl.CreateField("fldOLE", 11)
 
        'Гиперссылка
        Set fld = tbl.CreateField("fldHyperlink", 12)
         With fld 'Определение свойств поля
            .Attributes = dbHyperlinkField
        End With
        .Fields.Append fld 'Добавление
               
 
 
        'Attachment = 101
        .Fields.Append tbl.CreateField("fldAttachment", 101) 'Вложение
    End With
 
 
' Фактическое добавление таблицы из объектной переменной описанной выше
    CurrentDb.TableDefs.Append tbl
    CurrentDb.TableDefs.Refresh
 
 
CreateTableAndFields_Bye:
    On Error Resume Next
    Set tbl = Nothing
    Set fld = Nothing
    Exit Sub
        
CreateTableAndFields_Err:
    MsgBox "Произошла ошибка при выполнении процедуры " & _
            "[CreateTable01] :" & vbCrLf & _
            Err.Description & vbCrLf & _
            "Номер ошибки = " & Err.Number, vbCritical
    Err.Clear
    Resume CreateTableAndFields_Bye
End Sub