Автоматическое заполнение поля таблицы/формы при вводе значения в другое поле

Private Sub РС_АББ_AfterUpdate()
'
'--------------------------------------------------------------------------
Dim s$
Dim rst As DAO.Recordset
Dim sРСАББ As String
 
On Error GoTo РС_АББ_AfterUpdate_Err
    
    'Me.Карта_АББ_№ = Me.ЗП_проект.Column(2) 'что это было ??? :)
    
    Me!Дебит = Null
    Me!Кредит = Null
    Me!Сальдо = Null
    Me![Карта_АББ_№] = Null
    Me!ПИН = Null
    Me!ЛК_АББ_код = Null
    Me![Карта_лич_№] = Null
    Me!Sim_АББ = 0
    Me![Р/С_лич] = Null
    Me!Банк_лич = Null
    Me!Примечание = Null
    '... возможно ещё поля ...
 
    If IsNull(Me!РС_АББ) = True Then GoTo РС_АББ_AfterUpdate_End
    If Len(Me!РС_АББ) <> 20 Then GoTo РС_АББ_AfterUpdate_End
 
    sРСАББ = Me!РС_АББ
    s = "SELECT * FROM Кадры WHERE РС_АББ='" & sРСАББ & "'"
 
    Set rst = CurrentDb.OpenRecordset(s, dbOpenSnapshot)
    If rst.RecordCount = 0 Then GoTo РС_АББ_AfterUpdate_End
    
    With rst
        'Me!Дебит = ???
        'Me!Кредит = ???
        'Me!Сальдо = ???
        Me![Карта_АББ_№] = ![Карта_АББ_№]
        Me!ПИН = !ПИН
        Me!ЛК_АББ_код = !ЛК_АББ_код
        Me![Карта_лич_№] = ![Карта_лич_№]
        'Me!Sim_АББ = ???
        Me![Р/С_лич] = ![Р/С_лич]
        'Me!Банк_лич
        'Me!Примечание = ???
        If IsNull(Me!Дата) Then Me!Дата = Date
    End With
 
 
РС_АББ_AfterUpdate_End:
    On Error Resume Next
    rst.Close
    Set rst = Nothing
    Err.Clear
    Exit Sub
 
РС_АББ_AfterUpdate_Err:
    MsgBox "Error: " & Err.Number & vbCrLf & Err.Description & vbCrLf & _
    "in Sub: РС_АББ_AfterUpdate in module: Form_ЗП_проект", vbCritical, "Error in Application"
    Err.Clear
    Resume РС_АББ_AfterUpdate_End
 
End Sub

Public Function GetFIO(vFamilia As Variant, vImja As Variant, vOtchestvo As Variant, _
    Optional bInLongFormat As Boolean) As Variant
'es 19.04.2018
'Возвращает ФИО (Или ничего) по аргументам:
'   vFamilia      = Фамилия
'   vImja         = Имя
'   vOtchestvo    = Отчество
'   bInLongFormat = Краткий или длинный формат = По умолчанию краткий
'       Краткий формат = Пушкин А.С.
'       Длинный формат = Пушкин Александр Сергеевич
'--------------------------------------------------------------------------
On Error GoTo GetFIO_Err
    If Len(vFamilia & "") > 1 Then 'Фамилия указана
        'Простое составление с нормализацией строки
        GetFIO = UCase(Mid(vFamilia, 1, 1)) & LCase(Mid(vFamilia, 2))
    Else
        If bInLongFormat = False Then Exit Function 'Фамилии нет и формат краткий- на выход!
    End If
 
    If Len(vImja & "") > 1 Then 'Имя указано
        If bInLongFormat = False Then
            GetFIO = GetFIO & " " & UCase(Mid(vImja, 1, 1)) & "."
        Else
            'Простое составление с нормализацией строки
            GetFIO = GetFIO & " " & UCase(Mid(vImja, 1, 1)) & LCase(Mid(vImja, 2))
        End If
    Else
        If bInLongFormat = False Then Exit Function
    End If
 
    If Len(vOtchestvo & "") > 1 Then 'Отчество указано
        If bInLongFormat = False Then
            GetFIO = GetFIO & UCase(Mid(vOtchestvo, 1, 1)) & "."
        Else
            'Простое составление с нормализацией строки
            GetFIO = GetFIO & " " & UCase(Mid(vOtchestvo, 1, 1)) & LCase(Mid(vOtchestvo, 2))
 
        End If
    
    End If
 
GetFIO_Bye:
    Exit Function
 
GetFIO_Err:
    Err.Clear
    Resume GetFIO_Bye
End Function