Удалить одну запись из дублирующих

Private Sub УдалитьДубли()
'
'----------------------------------------------------------------
Dim s$
Dim l&
On Error GoTo УдалитьДубли_Err
    
    
    CreateTempTable
    
    DoCmd.Hourglass True 'Показать часики
    s = "INSERT INTO tmpДубли ( Max_ID ) SELECT Max(дубли.Код) AS Max_ID FROM дубли GROUP BY дубли.T1_Номер HAVING Count(дубли.T1_Номер)>1"
    CurrentDb.Execute s
    DoCmd.Hourglass False 'Вернуть нормальный курсор
 
    l = DCount("*", "tmpДубли")
    If l > 0 Then
        'Запрос поддтверждения удаления записи при ответе НЕТ - остановка
        If MsgBox("Действительно удалить:" & vbCrLf & l & " записей из таблицы [Дубли] ???", _
            vbYesNo + vbExclamation + vbDefaultButton1, _
            "Удаление данных") = vbNo Then Exit Sub
    Else
        MsgBox "Данных подлежащих удалению не обнаружено!", vbExclamation, "Нет данных!"
        Exit Sub
    End If
 
 
    DoCmd.Hourglass True 'Показать часики
    s = "DELETE дубли.* FROM дубли INNER JOIN tmpДубли ON дубли.Код = tmpДубли.Max_ID;"
    CurrentDb.Execute s
    DoCmd.Hourglass False 'Вернуть нормальный курсор
 
    MsgBox "Готово!", vbInformation, "OK!"
 
УдалитьДубли_End:
    On Error Resume Next
    DoCmd.Hourglass False 'Вернуть нормальный курсор
    Err.Clear
    Exit Sub
 
УдалитьДубли_Err:
    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in Sub УдалитьДубли.", _
        vbCritical, "Произошла ошибка!"
    Debug.Print "УдалитьДубли_Line: " & Erl & "."
    Err.Clear
    Resume УдалитьДубли_End
 
End Sub
 
Private Sub CreateTempTable()
'Создание временной Таблицы с кодами подлежащими удалению
'--------------------------------------------------------------------
Const strTableName As String = "tmpДубли" 'Название таблицы
Dim tbl As TableDef       'объект таблица
Dim idx As Index          'объект индекс
Dim fld As Field          'объект поле
Dim rst As Recordset      'объект набор записей
Dim i As Integer          'счетчик дней
 
'Удаяем прошлое
    On Error Resume Next
    CurrentDb.TableDefs.Delete strTableName
    Err.Clear
    
On Error GoTo CreateTempTableErr
 
'создание объектной переменной таблицы, полей и индекса в ней
    Set tbl = CurrentDb.CreateTableDef(strTableName)
    With tbl
        .Fields.Append tbl.CreateField("Max_ID", dbLong)
            'создание уникального индекса
            Set idx = .CreateIndex("Primary Key")
                With idx
                    'добавление поля в индекс
                    .Fields.Append .CreateField("Max_ID")
                    'Установка свойств индекса
                    .Unique = True   'Уникальный
                    .Primary = True  'Первичный
                End With
            .Indexes.Append idx
           'индекс создан
    End With
'Фактическое добавление таблицы из объектной переменной описанной выше
    CurrentDb.TableDefs.Append tbl
 
 
CreateTempTableBye:
    On Error Resume Next
    Set idx = Nothing
    Set tbl = Nothing
    rst.Close
    Set rst = Nothing
    Exit Sub
 
CreateTempTableErr:
    MsgBox "Произошла ошибка при выполнении процедуры " & _
    "[CreateTempTable] :" & vbCrLf & _
    Err.Description & vbCrLf & _
    "Номер ошибки = " & Err.Number, vbCritical
    Resume CreateTempTableBye
End Sub