Задача по SQL:транзакции клиентов (могут быть как в рублях, так и в евро и долларах)

Sub BeginTransX()
 
    Dim strName As String
    Dim strMessage As String
    Dim wrkDefault As Workspace
    Dim dbsNorthwind As Database
    Dim rstEmployees As Recordset
 
    ' Определяет стандартный объект Workspace.
    Set wrkDefault = DBEngine.Workspaces(0)
    Set dbsNorthwind = OpenDatabase("Борей.mdb")
    Set rstEmployees = dbsNorthwind.OpenRecordset("Сотрудники")
    ' Запускает внешнюю транзакцию.
    wrkDefault.BeginTrans
    ' Запускает главную транзакцию.
 
wrkDefault.BeginTrans
 
    With rstEmployees
 
        ' Выполняет цикл по набору записей и спрашивает пользователя,
        ' следует ли изменять должность конкретного сотрудника.
        Do Until .EOF
            If !Должность = "Коммерческий представитель" Then
                strName = !Фамилия & ", " & !Имя
                strMessage = "Сотрудник: " & strName & vbCr &  "Изменение должности"
                ' Изменяет должность указанного сотрудника.
                If MsgBox(strMessage, vbYesNo) = vbYes Then
                    .Edit
                    !Должность = "Счетовод"
                    .Update
                End If
            End If
            .MoveNext
        Loop
        ' Запрашивает пользователя, следует ли занести
        ' все ранее сделанные изменения.
        If MsgBox("Сохранить все изменения?", vbYesNo) = vbYes Then
            wrkDefault.CommitTrans
        Else
            wrkDefault.Rollback
        End If
        ' Печатает текущие данные из набора записей.
        .MoveFirst
        Do While Not .EOF
            Debug.Print !Фамилия & ", " & !Имя & " - " & !Должность
            .MoveNext
        Loop
        ' Отменяет все изменения, внесенные пользователем,
        ' поскольку программа предназначена только для демонстрации.
        wrkDefault.Rollback
        .Close
    End With
    dbsNorthwind.Close
End Sub