сортировка Бэтчера

const
  SortAsc = True;
  SortDesc = False;
  N = 16;
 
var
  A : array[0 .. Pred(N)] of integer =
  (503,  87, 512,  61, 908, 170, 897, 275,
   653, 426, 154, 509, 612, 677, 765, 703);
 
procedure Comparator(i, j : Integer; Dir : Boolean);
var T : Integer;
begin
   if (a[i] > a[j]) = Dir then
   begin
      T := a[i]; a[i] := a[j]; a[j] := T;
   end;
end;
 
 
procedure BitonicMerge(lo, cnt : Integer; Dir : Boolean);
var i, k : Integer;
begin
   if cnt > 1 then
   begin
      k := cnt div 2;
      for i := lo to pred(lo + k) do
         Comparator(i, i+k, dir);
      BitonicMerge(lo, k, dir);
      BitonicMerge(lo+k, k, dir);
   end;
end;
 
procedure BitonicSort(lo, cnt : Integer; Dir : Boolean);
var k : Integer;
begin
   if cnt > 1 then
   begin
      k := cnt div 2;
      BitonicSort(lo, k, SortAsc);
      BitonicSort(lo+k, k, SortDesc);
      BitonicMerge(lo, cnt, Dir);
   end;
end;
 
procedure BatcherSort;
begin
   BitonicSort(0, N, SortAsc);
end;
 
procedure Print;
var i : Integer;
begin
   for i := 0 to Pred(N) do
      write(A[i]:4);
   writeln;
end;
 
begin
   Print;
   BatcherSort;
   Print;
end.