Использование матриц в качестве параметров в функциях

const m = 15;
 
type mas = array [1..m, 1..m] of integer;
     el = record
            i: integer;
            j:integer
          end;
     
procedure entr(var x: mas; n: integer); //генерация массива, можно заменить на ввод
var i, j: integer;
begin
  for j := 1 to n do for i := 1 to n do x[i, j] := random(198) - 99
end;
 
procedure prnt(var x: mas; n: integer); //печать массива
var i, j: integer;
begin
  for j := 1 to n do
    begin
      for i := 1 to n do write(x[i, j]:4);
      writeln
    end
end;
 
function md(var x: mas; n: integer): el; //поиск максимума на диагоналях
var i, j, k: integer;
begin
  i := 1; //пока максимум x[1, 1]
  j := 1;
  for k := 1 to n do
    begin
      if x[k, k] > x[i, j] //ищем на главной
      then begin
        i := k;
        j := k
      end;
      if x[n - k + 1, k] > x[i, j] //ищем на побочной
      then begin
        i := n - k + 1;
        j := k
      end;
    end;
  md.i := i; //нашли, присвоили возвращаемому занчению функции
  md.j := j
end;
 
function am(var x: mas; n: integer): el; //поиск минимума вокруг перекрестья диагоналей
var i, j, im, jm: integer;
begin
  im := n div 2; //пока минимум левый верхний
  jm := n div 2; //можно jm := im; для оптимизации
  for i := n div 2 to n div 2 + 1 + n mod 2 do //с левого угла до правого
    for j := n div 2 to n div 2 + 1 + n mod 2 do //с верхнего угла до нижнего
      begin
        if not((n mod 2 = 1) and (i = n div 2 + 1) and (j = n div 2 + 1)) //центр пропускаем
          and ((x[i, j] < x[im, jm])) //ищем максимум
            then begin
              im := i;
              jm := j
            end
      end;
  am.i := im; //нашли, присвоили возвращаемому занчению функции
  am.j := jm
end;
 
var a: mas;
    n, i, j, t: integer;
    max, min: el;
 
begin
  randomize;
  repeat //ввод размерности массива
    write('n = ');
    readln(n);
    if (n < 2) or (n > m) then writeln('n out of range 2..', m, ', reenter.')
  until (n >= 2) and (n <= m);
  entr(a, n); //генерация (или ввод, если нужно) массива
  writeln('Source array:');
  prnt(a, n); //печать исходного массива
  max := md(a, n); //поиск максимума на диагоналях
  writeln('Max of diagonals: a[', max.i, ', ', max.j, '] = ', a[max.i, max.j]);
  min := am(a, n); //поиск минимума вокруг перекрестья диагоналей
  writeln('Min around diagonal crossing: a[', min.i, ', ', min.j, '] = ', a[min.i, min.j]);
  t := a[max.i, max.j]; //обмен
  a[max.i, max.j] := a[min.i, min.j];
  a[min.i, min.j] := t;
  writeln('Result:');
  prnt(a, n); //печать полученного массива
  readln //ждём-с...
end.