Разреженная вещественная матрица

program Project1;
 
const
  (*Имя файла с исходными данными.*)
  SrcFN = 'data_src.txt';
  (*Имя файла с результирующими данными.*)
  TrgFN = 'data_trg.txt';
  (*Имя файла с проверочными данными.*)
  TestFN = 'data_test.txt';
 
  //Размерность разреженной матрицы.
  //Количество строк.
  M = 100;
  //Количество столбцов.
  N = 1000;
 
type
  (*Тип, задающий сведения о ненулевом элементе разреженной матрицы.*)
  TElem = record
    (*Координаты элемента матрицы: индекс строки и столбца.*)
    i, j : Integer;
    (*Значение элемента матрицы.*)
    Value : Extended;
  end;
 
(*Создание разреженной матрицы и запись её в файл.*)
procedure CreateMatrix;
var
  (*Файловая переменная.*)
  F : Text;
  (*Индексы строки с столбца в разреженной матрице.*)
  i, j : Integer;
  (*Счётчик ненулевых элементов в строке матрицы.*)
  Cnt : Integer;
  (*Значение элемента разреженной матрицы.*)
  Value : Extended;
begin
  (*Связываем файловую переменную с именем файла.*)
  Assign(F, SrcFN);
  (*Создаём/пересоздаём файл и открываем его в режиме "только запись".*)
  Rewrite(F);
  (*Запись сведений о размерах матрицы.*)
  Write(F, N, ' ', M);
  (*Запись знака конца строки: #13#10.*)
  Writeln(F);
  (*Запись сведений о ненулевых элементах матрицы.*)
  Randomize;
  for i := 1 to M do begin
    (*Пускай вероятность того, что в строке есть хотябы один элемент, равна 1/10*)
    if Random(10) <> 0 then begin
      (*Запись знака конца строки: #13#10.*)
      Writeln(F);
      (*Пропуск итерации цикла.*)
      Continue;
    end;
    Cnt := 0;
    for j := 1 to M do begin
      (*Пускай вероятность того, что в данной строке в столбце j имеется ненулевой
      элемент, равна 1/200*)
      if Random(50) <> 0 then Continue;
      Inc(Cnt);
      Value := Random(1000) * Random(100) + 1 / (1 + Random(100)); (* [0..(10e5 - 1)] + [(0.01..1)] = 0.01..10e5.00 *)
 
      (*Длина записи по одному компоненту равна: 4 + 1 + 4 + 1 + 8 + 1 = 19-и символам.
      Поэтому, чтобы соблюсти правило, по которому каждая строка файла не должна
      превышать 80 символов, нам следует в каждую строку записывать не более
      80 div 19 = 4-ёх элементов.*)
      if Cnt < 4 then begin
        (*Между элементами в строке файла ставим пробелы.*)
        Write(F, ' ');
      end else if Cnt > 4 then begin
        Writeln(F);
        (*Т. к. в новую строку файла теперь записан 1 элемент, переустанавливаем счётчик.*)
        Cnt := 1;
      end;
      Write(F, i:4, ' ', j:4, ' ', Value:8:2);
    end;
    Writeln(F);
  end;
  (*Закрываем файл.*)
  Close(F);
end;
 
(*Чтение данных о разряженной матрице из текстового файла и запись
полученных данных в типизированный файл.*)
procedure MoveMatrix;
var
  FSrc : Text;
  FTrg : File of TElem;
  Elem : TElem;
begin
  (*Открываем входной файл для чтения данных.*)
  Assign(FSrc, SrcFN);
  Reset(FSrc);
  (*Создаём/пересоздаём целевой файл и открываем его в режиме "только запись".*)
  Assign(FTrg, TrgFN);
  Rewrite(FTrg);
 
  (*Переписываем сведения о размерах матрицы.*)
  if not Eof(FSrc) then begin
    Readln(FSrc, Elem.i, Elem.j);
    Elem.Value := 0;
    Write(FTrg, Elem);
  end;
 
  while not Eof(FSrc) do begin
    (*Пропускаем знаки перевода строк #13#10.*)
    while Eoln(FSrc) and (not Eof(FSrc)) do begin
      Readln(FSrc);
    end;
    (*Если после пропусков достигнут конец файла - выходим из цикла.*)
    if Eof(FSrc) then Break;
 
    (*Читаем очередной ненулевой элемент матрицы из исходного текстового файла.*)
    Read(FSrc, Elem.i, Elem.j, Elem.Value);
    (*Записываем очередной прочитанный элемент матрицы в целевой типизированный файл.*)
    Write(FTrg, Elem);
  end;
 
  (*Закрываем файлы.*)
  Close(FSrc);
  Close(FTrg);
end;
 
(*Выполняем проверку: на основе данных в целевом типизированном файле
создаём копию исходного текстового файла.*)
procedure TestData;
var
  FTrg : File of TElem;
  FTest : Text;
  i : Integer;
  Elem : TElem;
begin
  Assign(FTrg, TrgFN);
  Reset(FTrg);
  Assign(FTest, TestFN);
  Rewrite(FTest);
 
  (*Читаем сведения о размерах матрицы и записываем их в проверочный файл.*)
  if not Eof(FTrg) then begin
    Read(FTrg, Elem);
    Write(FTest, Elem.i, ' ', Elem.j);
  end;
 
  (*Читаем сведения о ненулевых элементах матрицы и записываем сведения о
  них в проверочный файл.*)
  i := 0;
  while not Eof(FTrg) do begin
    (*Читаем сведения об очередном ненулевом элементе из целевого файла.*)
    Read(FTrg, Elem);
    (*Если номер строки матрицы, в которой расположен текущий прочитанный элемент отличается
    от номера строки, в которой расположен предыдущий элемент,
    то вставляем разделитель строк.*)
    if i <> Elem.i then begin
      i := Elem.i;
      Writeln(FTest);
      Writeln(FTest, '--------------------------------------------------');
    end;
    Write(FTest, Elem.i:4, ' ', Elem.j:4, ' ', Elem.Value:8:2, ' ');
  end;
 
  (*Закрываем файлы.*)
  Close(FTrg);
  Close(FTest);
end;
 
begin
  (*Формируем разреженную матрицу и записываем её в текстовый файл.
  Этот текстовый файл считаем исходным файлом.*)
  CreateMatrix;
  (*Читаем ненулевые элементы матрицы из исходного текстового файла
  и записываем их в целевой типизированный файл.*)
  MoveMatrix;
  (*Выполняем проверку: на основе данных в целевом типизированном файле
  создаём проверочный текстовый файл.*)
  TestData;
 
  Writeln('Задача выполнена.');
  Writeln('Исходный текстовый файл: ', SrcFN);
  Writeln('Целевой типизированный файл: ', TrgFN);
  Writeln('Проверочный текстовый файл: ', TestFN);
 
  Readln;
end.

Value := Random(1000) * Random(100) + 1 / (1 + Random(100));