Организовать поиск заданного числа с заменой его на заданный в односвязном списке

program Project1;
 
type
  {Тип основных данных.}
  TData = Integer;
  {Тип указателя на элемент очереди.}
  TPElem = ^TElem;
  {Тип элемента очереди.}
  TElem = record
    Data : TData;   {Основные данные.}
    PNext : TPElem; {Указатель на следующий элемент очереди.}
  end;
  {Тип, определяющий очередь.}
  TQueue = record
    PFirst, PLast : TPElem; {Указатели на первый и на последний элементы очереди.}
  end;
 
{Начальная инициализация очереди. Внимание! Эту процедуру можно выполнять
только в отношении пустой очереди. Иначе будут утечки памяти.
Если очередь непуста, то следует применить вызов QFree().}
procedure Init(var aQ : TQueue);
begin
  aQ.PFirst := nil;
  aQ.PLast := nil;
end;
 
{Добавление элемента в конец очереди.}
procedure Push(var aQ : TQueue; const aData : TData);
var
  PElem : TPElem;
begin
  New(PElem);           {Выделение памяти для элемента.}
  PElem^.Data := aData; {Записываем основные данные.}
  PElem^.PNext := nil;  {Т. к., элемент добавляется в конец очереди, то указатель на следующий элемент = NIL.}
  if aQ.PFirst = nil then {Если очередь пуста, то новый элемент становится первым элементом очереди.}
    aQ.PFirst := PElem
  else                    {Если очередь непустая, то новый элемент прикрепляем к последнему элементу очереди.}
    aQ.PLast^.PNext := PElem;
  aQ.PLast := PElem; {Добавленный элемент становится последним элементом очереди.}
end;
 
{Изъятие элемента из начала очереди. Если очередь не пуста, то
из начала очереди извлекается элемент и его значение возвращается
через параметр aData. В этом случае функция возвращает True.
Если очередь пуста, то операция отменяется и функция возвращает False.}
function Pop(var aQ : TQueue; var aData : TData) : Boolean;
var
  PElem : TPElem;
begin
  Result := False;
  PElem := aQ.PFirst;
  if PElem <> nil then
  begin
    aData := PElem^.Data;      {Читаем данные первого элемента очереди.}
    aQ.PFirst := PElem^.PNext; {Первым элементом очереди становится тот элемент, который раньше был вторым.}
    if aQ.PFirst = nil then    {Если очередь оказалась пустой, то инициализируем её.}
      Init(aQ);
    Dispose(PElem); {Освобождаем память, занятую для элемента.}
    Result := True;
  end;
end;
 
//Освобождение памяти, выделенной для элементов очереди (очистка очереди).
procedure QFree(var aQ : TQueue);
var
  Data : TData;
begin
  while Pop(aQ, Data) do;
end;
 
//Распечатка очереди в направлении: начало - конец.
procedure QWriteln(const aQ : TQueue);
var
  PElem : TPElem;
begin
  PElem := aQ.PFirst;
  if PElem <> nil then
  repeat
    if PElem <> aQ.PFirst then {Если это не первый элемент очереди, то ставим перед ним запятую.}
      Write(', ');
    Write(PElem^.Data);    {Распечатка основных данных элемента.}
    PElem := PElem^.PNext; {Указатель на следующий элемент.}
  until PElem = nil
  else
    Write('Очередь пуста.');
  Writeln;
end;
 
const
  M = 15; {Количество элементов, которые мы добавим в очередь.}
var
  Q1, Q2 : TQueue;
  Data, DFind, DNew : TData;
  i : Integer;
  S : String;
begin
  {Начальная инициализация очередей.}
  Init(Q1);
  Init(Q2);
 
  repeat
    {Добавление элементов в первую очередь.}
    Randomize;
    for i := 1 to M do
      Push(Q1, Random(10)); {Целые числа из диапазона 0..9.}
    Writeln('Составлена исходная очередь (начало - конец):');
    QWriteln(Q1);
 
    Writeln('Задайте искомое значение:');
    Readln(DFind);
    Writeln('Задайте новое значение:');
    Readln(DNew);
 
    {Решение.}
    {Переливаем элементы из первой очереди - во вторую и при этом
    заменяем значения, равные DFind, на значение DNew.}
    while Pop(Q1, Data) do
    begin
      if Data = DFind then
        Data := DNew;
      Push(Q2, Data);
    end;
    {После переливания первая очередь стала пустой.
    Теперь переливаем элементы обратно: из второй очереди - в первую.}
    while Pop(Q2, Data) do
      Push(Q1, Data);
    {
    Исходя из реализации очереди, в данном случае, это действие можно выполнить
    так:
    Q1 := Q2;
    Init(Q2);
    }
 
    {Ответ.}
    Writeln('Очередь после обработки (начало - конец):');
    QWriteln(Q1);
 
    {Освобождение памяти, выделенной для элементов очередей.}
    QFree(Q1);
    QFree(Q2);
    Writeln('Память, выделенная для очередей, освобождена.');
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.