Отсортировать записи в порядке возрастания даты последнего платежа

type
    TMyDate = record
        d : 1..31;
        m : 1..12;
        y : Word;
    end;
    TAbon = record
        numb : String; //или что там за номер
        fam : String[20];
        adres : String[20];
        dolg : LongWord;
        lastPrice : TMyDate;
    end;
    TFile = File Of TAbon;
    TMass = Array[0..255] Of TAbon;
 
function CompDate(const a, b : TMyDate) : Boolean; //возвращает сравнение a > b
var
    Result : Boolean;
begin
    if (a.y > b.y)
    then
        Result := True
    else
        if (a.y < b.y)
        then
            Result := False
        else
            if (a.m > b.m)
            then
                Result := True
            else
                if (a.m < b.m)
                then
                    Result := False
                else
                    if (a.d > b.d)
                    then
                        Result := True
                    else
                        Result := False;
    CompDate := Result;
end;
 
procedure ShowMenu(); //просто вывод на экран менюшки
begin
    WriteLn;
    WriteLn('1. Add abon.');
    WriteLn('2. Search for.');
    WriteLn('3. Sort');
    WriteLn('4. Exit');
end;
 
procedure AddAbon(var f : TFile; const n : Byte); //добавление абонентов
var
    i : Byte;
    abon : TAbon;
begin
    Reset(f); Seek(f, FileSize(f));
    for i := 1 to n do
    begin
        with abon do
        begin
            {запрашиваем данные}
            WriteLn(i, ': ');
            Write('   Abon nomer: '); ReadLn(numb);
            Write('   Familia: '); ReadLn(fam);
            Write('   Adres: '); ReadLn(adres);
            Write('   Dolg: '); ReadLn(dolg);
            with lastPrice do
            begin
                {$R+}
                Write('   Platezh (dd mm yyyy): '); ReadLn(d, m, y);
                {$R-}
            end;
        end;
        Write(f, abon); //и записываем в файл
    end;
    Close(f);
end;
 
procedure PrintAbons(var f : TFile; const pr : TMyDate);
var
    abon : TAbon;
    i, k : Byte;
begin
    Reset(f); Seek(f, 0); k := 0;
    for i := 1 to FileSize(f) do
    begin
        Read(f, abon); //считываем
        with abon do
            if Not(CompDate(lastPrice, pr)) //сравниваем даты
            then
            begin
                {выводим}
                Inc(k);
                WriteLn(k, ':');
                WriteLn('   Abon nomer: ', numb);
                WriteLn('   Familia: ', fam);
                WriteLn('   Adres: ', adres);
                WriteLn('   Dolg: ', dolg);
                with lastPrice do
                    WriteLn('   Platezh: ', d, '.', m, '.', y);
            end;
    end;
    Close(f);
end;
 
procedure Swap(var a, b : TAbon); //процедура обмена двух переменных
var
    t : TAbon;
begin
    t := a;
    a := b;
    b := t;
end;
 
procedure SortFile(var f : TFile); //процедура сортировки и вывода сортированного файла
var
    ar : TMass;
    i, j, n : Byte;
begin
    Reset(f); Seek(f, 0);
    n := FileSize(f) - 1; //находим количество записей в файле
    for i := 0 to n do
        Read(f, ar[i]); //считываем в массив
    for i := 1 to n do
        for j := n downto i do
            if CompDate(ar[j - 1].lastPrice, ar[j].lastPrice) //сортируем пузырьковым методом
            then
                Swap(ar[j - 1], ar[j]);
    Close(f); ReWrite(f); //открываем на перезапись
    WriteLn('Sorted file: ');
    for i := 0 to n do
    begin
        Write(f, ar[i]); //выводим в файл
        with ar[i] do 
        begin
            {и на экран}
            WriteLn(i + 1, ':');
            WriteLn('   Abon nomer: ', numb);
            WriteLn('   Familia: ', fam);
            WriteLn('   Adres: ', adres);
            WriteLn('   Dolg: ', dolg);
            with lastPrice do
                WriteLn('   Platezh: ', d, '.', m, '.', y);
        end;
    end;
    Close(f);
end;
 
var
    f : TFile;
    k, t : Byte;
    date : TMyDate;
begin
    Assign(f, 'f.dat');
    repeat
        ShowMenu;
        ReadLn(k);
        case k of
            1:
            begin
                Write('n='); ReadLn(t);
                AddAbon(f, t);
            end;
            2:
            begin
                Write('dd mm yyyy: ');
                with date do
                    {$R+}
                    ReadLn(d, m, y);
                    {$R-}
                PrintAbons(f, date);
            end;
            3:
                SortFile(f);
            4:
                Exit;
            else
                WriteLn('ERROR!');
        end;
    until (false);
end.