Двумерный массив змейкой

@Aiwendil · Регистрация: 05.01.2015

Студворк — интернет-сервис помощи студентам

Напишите программу, которая заполняется двумерный массив размерностью n × n (n <10) змейкой. Например, при
n = 4 результат должен быть следующим:

1 8 9 16

2 7 10 15

3 6 11 14

4 5 12 13

@CodeR · 07.01.2015, 15:01

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Const nmax=9;
Var A:array[1..nmax,1..nmax] of integer;
    i,j,n,k:integer;
Begin
    Repeat
      write('N: ');
      readln(n);
    Until (n>0)and(n<=nmax);
    For j:=1 to n do
     if j mod 2 <> 0 then
      For i:=1 to n do
      Begin
        inc(k);
        A[i,j]:=k;
      End
     else
      For i:=n downto 1 do
      Begin
        inc(k);
        A[i,j]:=k;
      End;
    For i:=1 to n do
    Begin
      For j:=1 to n do
       write(A[i,j]:5);
      writeln;
    End;
End.

Добавлено через 1 минуту
Или так

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Const nmax=9;
Var A:array[1..nmax,1..nmax] of integer;
    i,j,n,k:integer;
Begin
    Repeat
      write('N: ');
      readln(n);
    Until (n>0)and(n<=nmax);
    For j:=1 to n do
      For i:=1 to n do
      Begin
        inc(k);
        if j mod 2 <> 0 then A[i,j]:=k else A[n-i+1,j]:=k;
      End;
    For i:=1 to n do
    Begin
      For j:=1 to n do
       write(A[i,j]:5);
      writeln;
    End;
End.

@Cyborg Drone · 07.01.2015, 15:53

Или так.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
const m = 19;
var i, j, n: integer;
    a: array [1..m, 1..m] of integer;
begin
  repeat
    write('n = ');
    readln(n);
    if (n < 1) or (n > m) then writeln('n out of range 1..', m, ', reenter.')
  until (n >= 1) and (n <= m);
  for i := 1 to n do
    begin
      for j := 1 to n do
        begin
          a[i, j] := (j - 1) * n + i + (j and 1 - 1) * (2 * i - n - 1);
          write(a[i, j]:4);
        end;
      writeln
    end;
  readln
end.

@Aiwendil · 07.01.2015, 16:44 **[ТС]**

Не могли бы Вы объяснить действия в 14 строке ?

Сообщение от Cyborg Drone

Pascal
14
          a[i, j] := (j - 1) * n + i + (j and 1 - 1) * (2 * i - n - 1);

@Cyborg Drone · 07.01.2015, 17:47

Числа в нечётных столбцах определяются как

(j - 1) * n + i.

В чётных как

(j - 1) * n + n - i + 1.

Для простоты рассуждений, вычтем и прибавим i:

(j - 1) * n + i + n - 2i + 1,

или

(j - 1) * n + i - (2i - n - 1).

Выяснили, что формула для нечётных столбцов отличается от формулы для чётных столбцов "лишним" вычитаемым

(2i - n - 1).

Чтобы получить общую формулу для любых столбцов, осталось сделать так, чтобы для нечётных столбцов это вычитаемое не учитывалось. В моей программе +(2i - n - 1) умножается на 0, если j нечётное , и на -1, если j чётное. Как?

Известно, что младший разряд двоичного представления числа равен 1, если число нечётное, ну и, само собой, 0, если число чётное. Значение младшего разряда выделить просто, с помощью поразрядной операции and (не путать с логической операцией and):

j and 1.

Получится 1, если нечётное, и 0, если чётное. А нам требуется 0, если нечётное, и -1, если чётное. Ну и вычесть 1, и дело в шляпе:

j and 1 - 1.

Вот и вся недолга. Ещё вариант, можно заменить, если оператор and не нравится:

j and 1 = j mod 2,

здесь всё ясно. Только вот and побыстрее mod будет, и поэтому я использую для степеней двойки эквивалентную конструкцию с and:

x mod 2ⁿ = x and (2ⁿ - 1).

Можно ещё и так заменить:

j and 1 - 1 = - ord(not odd(j)).

Пояснение: ord(TRUE) = 1, ord(FALSE) = 0, not odd(j) = TRUE, если чётное, и FALSE, если нечётное, оно ж просто инверсия функции odd(j).

Новые блоги и статьи Все статьи Все блоги /
Первый деплой lagorue 16.01.2026 Не спеша развернул своё 1ое приложение в kubernetes. А дальше мне интересно создать 1фронтэнд приложения и 2 бэкэнд приложения развернуть 2 деплоя в кубере получится 2 сервиса и что-бы они. . .	Расчёт переходных процессов в цепи постоянного тока igorrr37 16.01.2026 / * Дана цепь постоянного тока с R, L, C, k(ключ), U, E, J. Программа составляет систему уравнений по 1 и 2 законам Кирхгофа, решает её и находит токи на L и напряжения на C в установ. режимах до и. . .	Восстановить юзерскрипты Greasemonkey из бэкапа браузера damix 15.01.2026 Если восстановить из бэкапа профиль Firefox после переустановки винды, то список юзерскриптов в Greasemonkey будет пустым. Но восстановить их можно так. Для этого понадобится консольная утилита. . .	Изучаю kubernetes lagorue 13.01.2026 А пригодятся-ли мне знания kubernetes в России?
Сукцессия микоризы: основная теория в виде двух уравнений. anaschu 11.01.2026 https:/ / rutube. ru/ video/ 7a537f578d808e67a3c6fd818a44a5c4/	WordPad для Windows 11 Jel 10.01.2026 WordPad для Windows 11 — это приложение, которое восстанавливает классический текстовый редактор WordPad в операционной системе Windows 11. После того как Microsoft исключила WordPad из. . .	Classic Notepad for Windows 11 Jel 10.01.2026 Old Classic Notepad for Windows 11 Приложение для Windows 11, позволяющее пользователям вернуть классическую версию текстового редактора «Блокнот» из Windows 10. Программа предоставляет более. . .	Почему дизайн решает? Neotwalker 09.01.2026 В современном мире, где конкуренция за внимание потребителя достигла пика, дизайн становится мощным инструментом для успеха бренда. Это не просто красивый внешний вид продукта или сайта — это. . .

Двумерный массив змейкой

Решение

Решение

@Aiwendil 0 / 0 / 0 Регистрация: 05.01.2015 Сообщений: 10

	Двумерный массив змейкой 07.01.2015, 14:38. Показов 7364. Ответов 4 Метки нет (Все метки) Напишите программу, которая заполняется двумерный массив размерностью n × n (n <10) змейкой. Например, при n = 4 результат должен быть следующим: 1 8 9 16 2 7 10 15 3 6 11 14 4 5 12 13 0

@Cyborg Drone Модератор 10401 / 5689 / 3399 Регистрация: 17.08.2012 Сообщений: 17,336
	07.01.2015, 17:47
	Числа в нечётных столбцах определяются как (j - 1) * n + i. В чётных как (j - 1) * n + n - i + 1. Для простоты рассуждений, вычтем и прибавим i: (j - 1) * n + i + n - 2i + 1, или (j - 1) * n + i - (2i - n - 1). Выяснили, что формула для нечётных столбцов отличается от формулы для чётных столбцов "лишним" вычитаемым (2i - n - 1). Чтобы получить общую формулу для любых столбцов, осталось сделать так, чтобы для нечётных столбцов это вычитаемое не учитывалось. В моей программе +(2i - n - 1) умножается на 0, если j нечётное , и на -1, если j чётное. Как? Известно, что младший разряд двоичного представления числа равен 1, если число нечётное, ну и, само собой, 0, если число чётное. Значение младшего разряда выделить просто, с помощью поразрядной операции and (не путать с логической операцией and): j and 1. Получится 1, если нечётное, и 0, если чётное. А нам требуется 0, если нечётное, и -1, если чётное. Ну и вычесть 1, и дело в шляпе: j and 1 - 1. Вот и вся недолга. Ещё вариант, можно заменить, если оператор and не нравится: j and 1 = j mod 2, здесь всё ясно. Только вот and побыстрее mod будет, и поэтому я использую для степеней двойки эквивалентную конструкцию с and: x mod 2ⁿ = x and (2ⁿ - 1). Можно ещё и так заменить: j and 1 - 1 = - ord(not odd(j)). Пояснение: ord(TRUE) = 1, ord(FALSE) = 0, not odd(j) = TRUE, если чётное, и FALSE, если нечётное, оно ж просто инверсия функции odd(j). 1