Вывести на экран изображение циферблата механических часов

{$N+}
Program Watch;
 
Uses
  Graph, Crt, Dos;
 
Type
  Real = Extended;
 
Const
  {Константы, определяющие графический режим}
  GraphDriver : Integer = Vga;
  GraphMode   : Integer = VgaHi;
 
  {Координаты центра экрана}
  XCenter = 320;
  YCenter = 240;
 
  {Длина часовой, минутной и секундной стрелок}
  HourLength   = 120;
  MinuteLength = 150;
  SecondLength = 170;
 
  {Цвета стрелок}
  clBackground  = LightGray;  {Фон}
  clHourArrow   = Blue;       {Часовая стрелка}
  clMinuteArrow = Blue;       {Минутная стрелка}
  clSecondArrow = Red;        {Секундная стрелка}
  clDigits      = White;      {Цвет делений}
  clDigital     = LightGreen; {Цвет индикатора}
  cl3_6_9_12    = Blue;
  clNumbers     = White;
  clCenterColor = LightBlue;
 
function DegToRad(Degrees: Extended): Extended;  { Radians := Degrees * PI / 180 }
begin
  DegToRad := Degrees * (PI / 180);
end;
 
Function IntToStr(I: LongInt): String;
{ Convert any integer type to a string }
Var
  S: String[11];
Begin
  Str(I, S);
  IntToStr := S;
end;
 
Type
  TwoDigitNumber = 0..99;
 
Function LeadingZero(I: TwoDigitNumber): String;
{ Преобразовывает положительное число из двух цифр в строку. }
{ Если число меньше 10, перед ним подставляется 0 }
Var
  S: string[2];
Begin
  Str(I, S);
  If I < 10 then S := '0' + S;
  LeadingZero := S;
end;
 
Procedure DrawClockFace;
Var
  I, X, Y: Word;
  Angle: Real;
Begin
  SetBkColor(clBackground);
  ClearDevice;
  SetTextStyle(TriplexFont, HorizDir, 4);
  SetTextJustify(CenterText, CenterText);
  For I := 1 to 12 do
  Begin
    If I in [3,6,9,12] then
      SetColor(cl3_6_9_12)
    else
      SetColor(clNumbers);
    Angle := DegToRad(I * 30);
    X := XCenter + Trunc(190 * Sin(Angle));
    Y := YCenter - Trunc(190 * Cos(Angle)) - 5;
    OuttextXY(X, Y, IntToStr(I));
  end;
  SetColor(clDigits);
  For I := 0 to 59 do
  Begin
    Angle := DegToRad(I * 6);
    If I mod 5 = 0 then
      Line(Trunc(XCenter+Sin(Angle)*160),Trunc(YCenter-Cos(Angle)*160),
           Trunc(XCenter+Sin(Angle)*170),Trunc(YCenter-Cos(Angle)*170))
    else
      Line(Trunc(XCenter+Sin(Angle)*160),Trunc(YCenter-Cos(Angle)*160),
           Trunc(XCenter+Sin(Angle)*165),Trunc(YCenter-Cos(Angle)*165));
  end;
end;
 
Procedure DrawHourArrow(Const Hour, Minute, Second: Word);
Var
  Angle: Real;
  X, Y: Word;
Begin
  SetLineStyle(SolidLn, 0, ThickWidth);
  SetColor(clHourArrow);
  Angle := DegToRad(Hour * 30 + Minute / 2 + Second / 120);
  X := Trunc(XCenter + Sin(Angle) * HourLength);
  Y := Trunc(YCenter - Cos(Angle) * HourLength);
  Line(XCenter, YCenter, X, Y);
end;
 
Procedure DrawMinuteArrow(Const Minute, Second: Word);
Var
  Angle: Real;
  X, Y: Word;
Begin
  SetLineStyle(SolidLn, 0, ThickWidth);
  SetColor(clMinuteArrow);
  Angle := DegToRad(Minute * 6 + Second / 10);
  X := Trunc(XCenter + Sin(Angle) * MinuteLength);
  Y := Trunc(YCenter - Cos(Angle) * MinuteLength);
  Line(XCenter, YCenter, X, Y);
end;
 
Procedure DrawSecondArrow(Const Second: Word);
Var
  Angle: Real;
  X, Y: Word;
Begin
  SetLineStyle(SolidLn, 0, NormWidth);
  SetColor(clSecondArrow);
  Angle := DegToRad(Second * 6);
  X := Trunc(XCenter + Sin(Angle) * SecondLength);
  Y := Trunc(YCenter - Cos(Angle) * SecondLength);
  Line(XCenter, YCenter, X, Y);
end;
 
Procedure DrawDigital(Const Hour, Minute, Second: Word);
Var
  S: String;
Begin
  SetWriteMode(NormalPut);
  SetColor(clDigital);
  SetTextStyle(SmallFont, HorizDir, 8);
  S := IntToStr(Hour) + ':' + LeadingZero(Minute) + ':' + LeadingZero(Second);
  OutTextXY(XCenter, 455, S);
  SetColor(White);
  SetWriteMode(XORPut);
end;
 
Procedure ClearDigital(Const Hour, Minute, Second: Word);
Var
  S: String;
Begin
  SetWriteMode(NormalPut);
  SetColor(clBackground);
  SetTextStyle(SmallFont, HorizDir, 8);
  S := IntToStr(Hour) + ':' + LeadingZero(Minute) + ':' + LeadingZero(Second);
  OutTextXY(XCenter, 455, S);
  SetColor(White);
  SetWriteMode(XORPut);
end;
 
Procedure DrawCenter;
Begin
  SetColor(clCenterColor);
  Circle(XCenter, YCenter, 2);
  SetFillStyle(SolidFill, clCenterColor);
  FloodFill(XCenter, YCenter, clCenterColor);
end;
 
Var
  Hour, Minute, Second, Sec100: Word;
  OldHourValue, OldMinuteValue, OldSecondValue: Word;
  ClockStarted: Boolean;
 
Begin
  ClockStarted := False;
  GraphDriver := Detect;
  InitGraph(GraphDriver, GraphMode, 'E:\BP\BGI');
  DrawClockFace;
  SetWriteMode(XORPut);
  Repeat
    GetTime(Hour, Minute, Second, Sec100);
    If Second <> OldSecondValue then
    Begin
      If ClockStarted then
      Begin
        ClearDigital(OldHourValue,OldMinuteValue,OldSecondValue);
        if OldHourValue = 0 then OldHourValue := 12;
        if OldHourValue > 12 then Dec(OldHourValue, 12);
        DrawHourArrow(OldHourValue, OldMinuteValue, OldSecondValue);
        DrawMinuteArrow(OldMinuteValue, OldSecondValue);
        DrawSecondArrow(OldSecondValue);
        DrawCenter;
      end else ClockStarted := True;
      OldHourValue := Hour;
      OldMinuteValue := Minute;
      OldSecondValue := Second;
      DrawDigital(Hour, Minute, Second);
      If Hour = 0 then Hour := 12;
      If Hour > 12 then Dec(Hour, 12);
      DrawHourArrow(Hour, Minute, Second);
      DrawMinuteArrow(Minute, Second);
      DrawSecondArrow(Second);
      DrawCenter;
    end;
  until KeyPressed;
  CloseGraph;
end.