Выбрать 3 разные точки A,B,C так, чтобы внутри треугольника ABC содержалось макс. количество точек

uses crt;
const e=0.01;{точность сравнения вещественных чисел}
type Point=record{тип точка}
           x,y:real;
           end;
{площадь треугольника}
function Strg(a,b,c:Point):real;
begin
Strg:=abs((a.x-c.x)*(b.y-c.y)-(b.x-c.x)*(a.y-c.y))/2;
end;
{принадлежит ли точка треугольнику}
function Prin(a,b,c,t:Point):boolean;
var s,s1,s2,s3:real;
begin
{площади 3х маленьких треугольников, образованных
двумя вершинами и точкой}
s1:=Strg(a,b,t);
s2:=Strg(a,c,t);
s3:=Strg(b,c,t);
{площадь самого треугольника}
s:=Strg(a,b,c);
Prin:=(s1>e)and(s2>e)and(s3>e){если все площади маленьких > заданной точности
                              (точки не лежат на сторонах)}
and(abs(s-s1-s2-s3)<=e);{и если площиди маленьких=большому
                         с заданой точностью, то точка внутри треугольника}
end;
 
const nmax=15;{чтобы вошли в строку по щирине экрана}
var m:array[1..nmax] of Point;{множество точек}
    n:integer;{его размер}
    kt,mx:integer;{кол. точек в треугольнике и их максимум}
    imx,jmx,kmx:integer;{номера вершин треугольника с макс. кол. точек}
    i,j,k,p:integer;{счетчики циклов}
begin
randomize;
repeat
write('Количество точек множества от 3 до ',nmax,' n=');
readln(n);
until n in [3..nmax];
writeln('Множество:');
for i:=1 to n do
 begin
  m[i].x:=10*random;
  m[i].y:=10*random;
 end;
write(' ':2);
for i:=1 to n do
write(i:5);
writeln;
write('X:');
for i:=1 to n do
write(m[i].x:5:2);
writeln;
write('Y:');
for i:=1 to n do
write(m[i].y:5:2);
writeln;
mx:=0;
{перебираем треугольники из множества и ищем в каком больше точек}
for i:=1 to n-2 do
for j:=i+1 to n-1 do
for k:=j+1 to n do
 begin
  kt:=0;
  for p:=1 to n do
  if Prin(m[i],m[j],m[k],m[p]) then kt:=kt+1;
  if kt>mx then
   begin
    mx:=kt;
    imx:=i;
    jmx:=j;
    kmx:=k;
   end;
 end;
writeln('Максимальное количество точек в треугольнике');
writeln(imx,'(',m[imx].x:0:2,';',m[imx].y:0:2,')');
writeln(jmx,'(',m[jmx].x:0:2,';',m[jmx].y:0:2,')');
writeln(kmx,'(',m[kmx].x:0:2,';',m[kmx].y:0:2,')');
writeln('Количество точек=',mx);
end.