Оптимизировать программу возведения больших чисел в степень

program project1;
 
uses
  SysUtils;
 
const
  MaxLen = 1000;
  BASE = 10000;
  BASE_DIG = 4;
 
type
  TLong = record
    Length: integer;
    Coef: array[0..MaxLen] of integer;
  end;
 
  procedure Zero(var A: TLong);
  begin
    FillChar(A.Coef, SizeOf(A.Coef), 0);
    A.Length := 1;
  end;
 
  procedure Print(const A: TLong);
  var
    g:text;
    I: integer;
    d: integer;
  begin
    assign(g,'output.txt');
    rewrite(g);
    for I := A.Length - 1 downto 0 do
    begin
      if I <> A.Length - 1 then
      begin
        d := Length(IntToStr(A.Coef[I]));
        if d < BASE_DIG then
          while d <> BASE_DIG do
          begin
            Write(g,'0');
            Inc(d);
          end;
      end;
      Write(g,A.Coef[I]);
    end;
    close(g);
    WriteLn;
  end;
 
  function Convert(S: string): TLong;
  var
    I, K, d: integer;
    _S: string;
    C: TLong;
  begin
    Zero(C);
    d := Length(S);
    while d mod BASE_DIG <> 0 do  // добавляем нули слева
    begin
      S := '0' + S;
      Inc(d);
    end;
    K := 0;
    _S := '';
    for I := d downto 1 do
    begin
      _S := Concat(S[I], _S);
      if (I - 1) mod BASE_DIG = 0 then
      begin
        C.Coef[K] := StrToInt(_S);
        Inc(K);
        _S := '';
      end;
    end;
    C.Length := K;
    Convert := C;
  end;
 
  function Mul(const A, B: TLong): TLong;
  overload;
  var
    C: TLong;
    I, J: integer;
    temp, carry: integer;
  begin
    Zero(C);
    for I := 0 to A.Length - 1 do
    begin
      carry := 0;
      for J := 0 to B.Length - 1 do
      begin
        temp := A.Coef[I] * B.Coef[J] + C.Coef[I + J] + carry;
        carry := temp div BASE;
        C.Coef[I + J] := temp - carry * BASE;
      end;
      C.Coef[I + B.Length] := carry;
    end;
    I := A.Length + B.Length - 1;
    while (I > 0) and (C.Coef[I] = 0) do
      Dec(I);
    C.Length := I + 1;
    Mul := C;
  end;
 
var
  f: Text;
  s: string;
  a,r: tlong;
  n: integer;
 
 
begin
  Assign(f, 'input.txt');
  reset(f);
  Read(f, s);
  readln(f);
  read(f,n);
  a := Convert(s);
  s:='1';
  r:=convert(s);
  while n<>1 do
  begin
  if odd(n) then  r:=mul(r,a);
  a:=mul(a,a);
  n:=n div 2;
  end;
  a:=mul(r,a);
  print(a);
  Close(f);
end.