При движении объекта непосредственно по тексту, если дать команду cls, то объект оставит след

program lab5;
 
{$M $1000, 0, 0}
{$R-}
 
uses
  Crt, Dos;
 
const
  Color = Yellow + Blue shl 4;
  Symbol = '*';
  SW = Color shl 8 + Ord(Symbol);
type
  TScrPlace = packed record
  case Integer of
  0: (c: Char; a: Byte);
  1: (w: Word);
  end;
var
  Scr: array [1..25, 1..80] of TScrPlace absolute $B800:$0000;
  OldHandler, OldHandler2: Procedure;
  Speed, t, t1, t2: Word;
  X, Y, dx, dy: Integer;
 
{$F+}
procedure Handler; Interrupt;
  function Rnd: Integer;
  begin
    case Random(4) of
      0: Rnd := -1;
      1: Rnd := 1;
      2: Rnd := 2;
      3: Rnd := -2;
    end;
  end;
begin
  Inc(t);
  if t > 20 div Speed then begin
    t := 0;
    if Scr[y,x  ].w=SW then Scr[y,x  ].w:=t1;
    if Scr[y,x+1].w=SW then Scr[y,x+1].w:=t2;
    while (X + dx > 79) or (X + dx < 1) or (Y + dy > 25) or (Y + dy < 1) do begin
      dx:=Rnd; dy:=Rnd;
    end;
    Inc(x,dx); Inc(y,dy);
    t1:=Scr[y,x].w; t2:=Scr[y,x+1].w;
    Scr[y,x].w:=SW; Scr[y,x+1].w:=SW;
  end;
  Inline($9C); OldHandler;
end;
 
procedure Handler2; Interrupt;
begin
  if (Port[$60] = $1C) and (WhereY = 25) then begin
    Dec(Y);
    t := High(t);
  end;
  Inline($9C); OldHandler2;
end;
{$F-}
 
var
  i, C1, C2: Integer;
begin
  Val(ParamStr(1), Speed, C1);
  if ParamCount = 0 then
    Speed := 7
  else if (C1<>0) or not (Speed in [1..20]) then begin
    WriteLn('Неправильно заданы параметры.');
    WriteLn('Должен быть один параметр - скорость движения объекта (1..20)');
    ReadKey;
    Halt;
  end;
  t:=0;
  dy:=1; dx:=0;
  y:=15; x:=30;
  t1:=Scr[y,x].w; t2:=Scr[y,x+1].w;
  if WhereY=25 then Dec(Y);
  Randomize;
  GetIntVec($9, @OldHandler2);
  SetIntVec($9, Addr(Handler2));
  GetIntVec($8, @OldHandler);
  SetIntVec($8, Addr(Handler));
  Keep(0);
end.