Выполнить сортировку одномерного массива 4 методами.

const
  max = 100;
 
type
  itp = integer;
  mas = array[1..max] of integer;
 
 
  { Сортировка выбором }
procedure SelectSort2(var A: mas; var c: integer);
var
  i, j, m: Integer;
  x: itp;
begin
      { Ищем элементы для позиций с 1 по max - 1 }
  for i := 1 to max - 1 do
  begin
    m := i;
    x := A[i];
          { Просматриваем все еще не выбранные элементы }
    for j := i + 1 to max do
            { Если встречается элемент, меньший того, что сейчас
              стоит на позиции m, запоминаем в m его позицию,
              а в x - его значение }
      if x > A[j] then
      begin
        m := j;
        x := A[j];
      end;
            { Меняем местами i-ый элемент, и минимальный из оставшихся -
              m-ый элемент, сохраненный в x }
    A[m] := A[i];
    A[i] := x;
    inc(c);
  end;
end;
 
  { Сортировка "пузырьком" }
procedure BubbleSort(var A: mas; var c: integer );
var
  i, j: Integer;
  x: itp;
begin
  for i := max downto 2 do
    for j := 2 to i do
      if A[j] < A[j - 1] then
      begin
        x := A[j];
        A[j] := A[j - 1];
        A[j - 1] := x;
        inc(c);
      end;
end;
 
  { Сортировка "шейкером" }
procedure ShakerSort(var A: mas; var c: integer);
var
  l, r, j: Integer;
  x: itp;
begin
  l := 2;
  r := max;
  while l <= r do
  begin
          { "Пузырек" слева направо }
    for j := l to r do
      if A[j] < A[j - 1] then
      begin
        x := A[j];
        A[j] := A[j - 1];
        A[j - 1] := x;
        inc(c);
      end;
    r := r - 1;
          { "Пузырек" справа налево }
    for j := r downto l do
      if A[j] < A[j - 1] then
      begin
        x := A[j];
        A[j] := A[j - 1];
        A[j - 1] := x;
        inc(c);
      end;
    l := l + 1;
  end;
end;
 
  { Сортировка Шелла }
procedure ShellSort(var A: mas; var c: integer);
const
  steps = 12;
var
  i, j, l, k, p, n: Integer;
  x: itp;
  s: array [1..steps] of Integer;
begin
  c := 0;
  k := 1;
      { Формируем последовательность чисел -
        шаги, с которыми выбираем сортируемые подмассивы }
  for i := steps downto 1 do
  begin
    s[i] := k;
    k := k * 2 + 1;
  end;
  
      { Сортировки подмассивов вплоть до шага 1 -
        обычной сортировки пузырьком }
  for k := 1 to steps do
  begin
    l := s[k];
          { Для каждого шага l нужно отсортировать l подмассивов }
    for p := 1 to l do
    begin
      i := max - l;
      n := 1;
              { Сортировка подмассива пузырьком с остановкой }
              { Подмассив - это (A[p], A[p+l], A[p+2*l], ...) }
      while n > 0 do
      begin
        n := 0;
        j := p;
        while j <= i do
        begin
          if A[j] > A[j + l] then
          begin
            x := A[j];
            A[j] := A[j + l];
            A[j + l] := x;
            n := 1;
            inc(c);
          end;
          j := j + l;
        end;
        i := i - l;
      end;
    end;
  end;
end;
 
var
  a: mas;
  i, k, count: integer;
 
begin
  writeln('Исходный массив:');
  for i := 1 to max do
  begin
    a[i] := -150 + random(301);
    write(a[i]:5);
  end;
  writeln;
  writeln('Для сортировки выбором нажмите 1');
  writeln('Для сортировки "пузырьком" нажмите 2');
  writeln('Для сортировки "шейкером" нажмите 3');
  writeln('Для сортировки методом Шелла нажмите 4');
  readln(k);
  case k of
    1: SelectSort2(a, count);
    2: BubbleSort(a, count);
    3: ShakerSort(a, count);
    4: ShellSort(a, count)
  else begin
      writeln('Вы ввели неверное число');
      exit;
    end;
  end;
  writeln('Отсортированный массив:');
  for i := 1 to max do write(a[i]:5);
  writeln;
  writeln('Количество перестановок = ', count);
  readln;
end.