Криптографическая атака на шифр Виженера

const alphabet = 'АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ';
var f: text;
    g: file of char;
    s: string;
    c: char;
    i: longword;
    n, k: byte;
    m: set of byte;
begin
  assign(f, 'c:\vigener.txt');
  reset(f);
  assign(g, 'c:\vigener.dat');
  rewrite(g);
  m := [];
  k := 0;
  while not eof(f) do
    begin
      readln(f, s);
      writeln(s);
      for i := 1 to length(s) do
        begin
          n := pos(s[i], alphabet);
          if n > 0
            then begin
              write(g, s[i]);
              if not (n in m)
                then begin
                  inc(k);
                  include(m, k)
                end
            end
        end
    end;
  close(f);
  reset(g);
  writeln;
  for i := 1 to filesize(g) do
    begin
      read(g, c);
      write(c)
    end;
  writeln;
  writeln;
  write('length = ', filesize(g), ' letters: ', k);
  close(g);
  readln
end.

var g: file of char;
    c, s: char;
    i, n, k, p, len: longword;
begin
  assign(g, 'c:\vigener.dat');
  reset(g);
  len := filesize(g);
  p := 0;
  repeat
    for n := 0 to len - 1 do
      begin
        k := 0;
        for i := 0 to len - 1 do
          begin
            seek(g, i);
            read(g, c);
            seek(g, (i + n) mod len);
            read(g, s);
            if c = s then inc(k)
          end;
        if k >= p
          then write(k:4)
          else write('.':4)
      end;
    writeln;
    write('p = ');
    readln(p);
  until p = 1000;
  close(g)
end.

const n = 10;
      freq = 'АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ';
      perc: array [0..32] of byte =
        (43,  7, 20,  7, 13, 40,  0,  4,  9, 37,  6,
         17, 21, 16, 32, 46, 17, 27, 27, 31, 14,  2,
          4,  2,  6,  4,  2,  0, 10,  9,  1,  5, 11);
var g, h: file of char;
    f, y: text;
    c, q: char;
    a: array [0..n-1, 0..32] of integer;
    b: array [0..n-1] of integer;
    i, j, len: longword;
    p, k, t: integer;
    s: string;
begin
  for i := 0 to n - 1 do
    begin
      for j := 0 to 32 do a[i, j] := 0;
      b[i] := 0;
    end;
  assign(f, 'd:\vigener.txt');
  assign(g, 'd:\vigener.dat');
  assign(h, 'd:\solution.dat');
  assign(y, 'd:\solution.txt');
  reset(g);
  len := filesize(g);
  for i := 0 to len - 1 do
    begin
      read(g, c);
      inc(a[i mod n, pos(c, freq) - 1]);
    end;
  for i := 0 to n do for j := 0 to 32 do a[i, j] := a[i, j] * 4;
  repeat
    t := 0;
    for i := 0 to n - 1 do write(freq[(33 - b[i]) mod 33 + 1]);
    writeln;
    reset(g);
    rewrite(h);
    for i := 0 to len - 1 do
      begin
        read(g, c);
        if (i > 0) and (i mod n = 0)
          then begin
            write(' ');
            t := t + n + 1;
            if 80 - t < n + 2
              then begin
                writeln;
                t := 0;
              end;
          end;
        q := freq[(pos(c, freq) + b[i mod n] - 1) mod 33 + 1];
        write(q);
        write(h, q)
      end;
    writeln;
    write(' ':4);
    for i := 0 to 32 do write(i mod 10:2);
    writeln;
    write(' ':4);
    for i := 1 to 33 do write(freq[i]:2);
    writeln;
    write(' ':4);
    for i := 0 to 32 do write(perc[i]:2);
    writeln;
    for i := 0 to n - 1 do
      begin
        write(i + 1:2, b[i]:2);
        for j := 0 to 32 do write(a[i, (j + b[i]) mod 33]:2);
        writeln
      end;
    readln(p, k);
    if p > 0 then b[p - 1] := (b[p - 1] + k) mod 33
  until p <= 0;
  close(g);
  reset(f);
  reset(h);
  rewrite(y);
  write(y, 'Ключевое слово: ');
  for i := 0 to n - 1 do write(y, freq[(33 - b[i]) mod 33 + 1]);
  writeln(y);
  writeln(y);
  write('Ключевое слово: ');
  for i := 0 to n - 1 do write(freq[(33 - b[i]) mod 33 + 1]);
  writeln;
  writeln;
  writeln(y, 'Расшифрованное сообщение:');
  writeln(y);
  writeln('Расшифрованное сообщение:');
  writeln;
  while not eof(f) do
    begin
      readln(f, s);
      for i := 1 to length(s) do
        if pos(s[i], freq) > 0
          then begin
            read(h, c);
            s[i] := c
          end;
      writeln(y, s);
      writeln(s)
    end;
  close(f);
  close(h);
  close(y);
  readln
end.