Удалить из файла все слова чётной длинны

const fname = 'test.txt'; {имя файла}
var f: file of char; {файловая переменная}
    sw, ew, p: longword; {позиция начала слова, позиция конца слова, текущая позиция в файле}
    c: char; {буферная переменная}
begin
  assign(f, fname); {связываем файловую переменную с файлом}
  reset(f); {открываем файл}
  seek(f, filesize(f)); {устанавливаем указатель за последнюю позицию файла...}
  write(f, ' '); {...и дописываем в конец файла пробел (для упрощения алгоритма)}
  sw := 0; {начало первого слова в первой позиции файла}
  ew := sw; {пока считаем, что конец слова совпадает с его началом}
  for p := 0 to filesize(f) - 1 do {цикл по всем позициям в файле}
    begin
      seek(f, p); {устанавливаем указатель в текущую позицию файла}
      read(f, c); {читаем символ}
      seek(f, ew); {устанавливаем указатель на текущий конец слова}
      write(f, c); {записываем символ}
      inc(ew); {символ скопирован, увеличиваем позицию конца слова на единицу}
      if c = ' ' {если конец слова,}
        then if odd(ew - sw) {то если слово чётной длины}
          then ew := sw {то удаляем его последующей перезаписью}
          else sw := ew {иначе считаем началом следующего слова конец текущего слова}
    end;
  seek(f, ew - 1); {устанавливаем указатель в конец последнего слова перед добавленным ранее пробелом}
  truncate(f); {усекаем файл}
  close(f) {закрываем файл}
end.