Возвести матрицу А в 15 степень

@Paul fawkes · Регистрация: 11.11.2016

Студворк — интернет-сервис помощи студентам

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
const
 Count = 3;
var
 Mat1,
 ResMat1 : array[1..Count, 1..Count] of integer;
 u,e, i, j, R : integer;
begin
for i:=1 to count do
  for j:=1 to count do
    read(resmat1[i,j]);
writeln('Mat A:');
for i:=1 to count do
begin
  for j:=1 to count do
    write(resmat1[i,j],'  ');
    writeln
    end;
readln(e);
  begin
  end;
   for i := 1 to count do
  for j := 1 to Count do
  begin
   R := 0;
   for u := 1 to Count do
    r := R + mat1[j, u]*Mat1[u, j];
 end;
 Writeln('AxA=');
 for j := 1 to Count do
 begin
  for i := 1 to Count do
   Write(ResMat1[i, j]:4);
  Writeln;
  readln(e);
 end;
END.

@bormant · 11.11.2016, 13:41

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
const n=3; m=15; W=7;
var
  a, b, t: array [1..n,1..n] of Longint;
  s: Longint;
  i, j, k, p: Integer;
begin
  for i:=1 to n do for j:=1 to n do Read(a[i,j]); ReadLn;
  WriteLn('A =');
  for i:=1 to n do begin
    for j:=1 to n do Write(' ',a[i,j]:W); WriteLn;
  end;
  k:=m; {FillChar(t,SizeOf(t),#0);}; for i:=1 to n do t[i,i]:=1;
  while k>0 do begin
    if Odd(k) then begin
      for i:=1 to n do for j:=1 to n do begin
        s:=0; for p:=1 to n do s:=s+a[i,p]*t[p,j]; b[i,j]:=s;
      end; t:=b;
    end;
    for i:=1 to n do for j:=1 to n do begin
      s:=0; for p:=1 to n do s:=s+a[i,p]*a[p,j]; b[i,j]:=s;
    end; a:=b;
    k:=k div 2;
  end; a:=t;
  WriteLn('A^',m,' =');
  for i:=1 to n do begin
    for j:=1 to n do Write(' ',a[i,j]:W); WriteLn;
  end;
  Write('Нажмите Enter...'); ReadLn;
end.

Но я б переписал так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
const n=3; m=15; W=7;
type TMatrix = array [1..n,1..n] of Longint;
procedure mMul(const a, b: TMatrix; var r: TMatrix);
var i, j, p: Integer; t: TMatrix; s: Longint;
begin
  for i:=1 to n do for j:=1 to n do begin
    s:=0; for p:=1 to n do s:=s+a[i,p]*b[p,j]; t[i,j]:=s;
  end; r:=t;
end;
var
  a, t: TMatrix;
  i, j, k: Integer;
begin
  for i:=1 to n do for j:=1 to n do Read(a[i,j]); ReadLn;
  WriteLn('A =');
  for i:=1 to n do begin
    for j:=1 to n do Write(' ',a[i,j]:W); WriteLn;
  end;
  k:=m; for i:=1 to n do t[i,i]:=1;
  while k>0 do begin
    if Odd(k) then mMul(t,a,t);
    mMul(a,a,a); k:=k div 2;
  end;
  WriteLn('A^',m,' =');
  for i:=1 to n do begin
    for j:=1 to n do Write(' ',t[i,j]:W); WriteLn;
  end;
  Write('Нажмите Enter...'); ReadLn;
end.

Добавлено через 11 минут
Или даже так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
const n=3; m=15; W=7;
type TMatrix = array [1..n,1..n] of Longint;
 
procedure mMul(const a, b: TMatrix; var r: TMatrix);
var i, j, p: Integer; t: TMatrix; s: Longint;
begin
  for i:=1 to n do for j:=1 to n do begin
    s:=0; for p:=1 to n do s:=s+a[i,p]*b[p,j]; t[i,j]:=s;
  end; r:=t;
end;
 
procedure mPwr(a: TMatrix; k: Integer; var r: TMatrix);
var i: Integer;
begin
  FillChar(r,SizeOf(r),#0); for i:=1 to n do r[i,i]:=1;
  while k>0 do begin
    if Odd(k) then mMul(a,r,r); mMul(a,a,a); k:=k div 2;
  end;
end;
 
procedure mWrite(const a: TMatrix); var i, j: Integer;
begin for i:=1 to n do begin for j:=1 to n do Write(' ',a[i,j]:W); WriteLn; end; end;
procedure mRead(var a: TMatrix); var i, j: Integer;
begin for i:=1 to n do for j:=1 to n do Read(a[i,j]); ReadLn; end;
 
var a: TMatrix;
begin
  mRead(a); WriteLn('A ='); mWrite(a);
  mPwr(a,m,a); WriteLn('A^',m,' ='); mWrite(a);
  Write('Нажмите Enter...'); ReadLn;
end.

Новые блоги и статьи Все статьи Все блоги /
http://iceja.net/ математические сервисы iceja 20.01.2026 Обновила свой сайт http:/ / iceja. net/ , приделала Fast Fourier Transform экстраполяцию сигналов. Однако предсказывает далеко не каждый сигнал (см ограничения http:/ / iceja. net/ fourier/ docs ). Также. . .	http://iceja.net/ сервер решения полиномов iceja 18.01.2026 Выкатила http:/ / iceja. net/ сервер решения полиномов (находит действительные корни полиномов методом Штурма). На сайте документация по API, но скажу прямо VPS слабенький и 200 000 полиномов. . .	Расчёт переходных процессов в цепи постоянного тока igorrr37 16.01.2026 / * Дана цепь постоянного тока с R, L, C, k(ключ), U, E, J. Программа составляет систему уравнений по 1 и 2 законам Кирхгофа, решает её и находит переходные токи и напряжения на элементах схемы. . . .	Восстановить юзерскрипты Greasemonkey из бэкапа браузера damix 15.01.2026 Если восстановить из бэкапа профиль Firefox после переустановки винды, то список юзерскриптов в Greasemonkey будет пустым. Но восстановить их можно так. Для этого понадобится консольная утилита. . .
Сукцессия микоризы: основная теория в виде двух уравнений. anaschu 11.01.2026 https:/ / rutube. ru/ video/ 7a537f578d808e67a3c6fd818a44a5c4/	WordPad для Windows 11 Jel 10.01.2026 WordPad для Windows 11 — это приложение, которое восстанавливает классический текстовый редактор WordPad в операционной системе Windows 11. После того как Microsoft исключила WordPad из. . .	Classic Notepad for Windows 11 Jel 10.01.2026 Old Classic Notepad for Windows 11 Приложение для Windows 11, позволяющее пользователям вернуть классическую версию текстового редактора «Блокнот» из Windows 10. Программа предоставляет более. . .	Почему дизайн решает? Neotwalker 09.01.2026 В современном мире, где конкуренция за внимание потребителя достигла пика, дизайн становится мощным инструментом для успеха бренда. Это не просто красивый внешний вид продукта или сайта — это. . .