Сложение в двоично-десятичной системе

type binType = array [0..255] of Byte;
 
function binShort(a : binType) : binType;
var i : Integer; r : binType;
begin
  while (a[0] > 1) and (a[a[0]] = 0) do Dec(a[0]);
  for i := 0 to a[0] do r[i] := a[i];
  binShort := r;
end;
 
function binRead(msg : String) : binType;
var i : Integer; s : String; r : binType; error : Boolean;
begin
  repeat
    Write(msg, ' '); ReadLn(s);
    r[0] := Length(s); error := False;
    for i := 1 to r[0] do
      case s[i] of
        '0' : r[r[0]+1-i] := 0;
        '1' : r[r[0]+1-i] := 1;
      else
        error := True;
      end;
    if error then WriteLn('Ошибка ввода!');
  until not error;
  binRead := binShort(r);
end;
 
function binAdd(a, b : binType) : binType;
var i, d : Integer; r : binType;
begin
  while a[0] < b[0] do begin Inc(a[0]); a[a[0]] := 0; end;
  while a[0] > b[0] do begin Inc(b[0]); b[b[0]] := 0; end;
  r[0] := a[0]; d := 0;
  for i := 1 to a[0] do
    begin
      d := d + a[i] + b[i];
      r[i] := d mod 2; d := d div 2;
    end;
  if d > 0 then
    begin
      Inc(r[0]); r[r[0]] := 1;
    end;
  binAdd := r;
end;
 
function binToStr(a : binType) : String;
const c : array [0..1] of Char = ('0', '1');
var i : Integer; s : String;
begin
  for i := a[0] downto 1 do
    s := s + c[a[i]];
  binToStr := s;
end;
 
var a, b, c : binType;
begin
  a := binRead('Введите a:');
  b := binRead('Введите b:');
  c := binAdd(a, b);
  WriteLn(binToStr(a), ' + ', binToStr(b), ' = ', binToStr(c));
end.