Найти количество таких групп букв, которые начинаются и кончаются одной и той же буквой

var s:array[1..50] of string;
..............................
write('Сколько строк в тексте? n=');
readln(n);
writeln('Введите текст построчно:');
for i:=1 to n do
readln(s[i]);

program simbol;
uses crt;
var b:array[1..50] of string;
 i,j,k,p,l,n:integer;
begin
     clrscr;
     writeln('Kolichestvo strok:');
     readln(n);
     writeln('Vvedite simvoli:');
     for i:=1 to n do
     readln(b[i]);
     k:=0;
     for k:=1 to n do begin
     p:=length(b[i]);
     for i:=1 to p-1 do begin
     for j:=i+1 to p do begin
         if (b[i]>='A') and (b[i]<='Z') OR (b[i]>='a') and (b[i]<='z') then
          if (b[j]>='A') and (b[j]<='Z') OR (b[j]>='a') and (b[j]<='z') then
         if b[i]=b[j] then k:=k+1;  i:=j+1;
                  end;    end;
         end;
         writeln(k);
         readln;
         end.

program simbol;
uses crt;
const z=['A'..'Z','a'..'z'];
var b:array[1..100] of string;
c:string;
 i,j,k,p,n:integer;
begin
     clrscr;
     writeln('Kolichestvo strok:');
     readln(n);
          writeln('Vvedite simvoli:');
     for i:=1 to n do
     readln(b[i]);
     p:=0;
     for i:=1 to n do begin
     c:=b[i];
     j:=1; k:=2;
    while j<length(c)-1 do begin
     if (c[j] in z) and (c[j]=c[k]) then begin
     p:=p+1;
     j:=k+1;
     k:=j+1;
     end
     else
     k:=k+1;
     end;  end;
     writeln(p);
         readln;
         end.

program Project1;
 
const
  //Все символы.
  Ds = [#0..#255];
  //Буквы.
  Da = [
    'А'..'П', 'Р'..'Я', 'Ё', 'а'..'п', 'р'..'я', 'ё',
    'A'..'Z', 'a'..'z'
  ];
  //Не буквы.
  D = Ds - Da;
var
  S : String;
  i, Pos1, Len, Cnt : Integer;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    Writeln('Перечень слов, с одинаковой буквой в начале и в конце:');
    Len := Length(S);
    Pos1 := 0;
    Cnt := 0;
    for i := 1 to Len do begin
      //Пропускаем не буквы.
      if S[i] in D then Continue;
      //Отслеживаем начало слова.
      if (i = 1) or (S[i - 1] in D) then Pos1 := i;
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        //Проверка начальной и конечной буквы.
        if S[Pos1] = S[i] then begin
          Cnt := Cnt + 1;
          Writeln( Copy(S, Pos1, i - Pos1 + 1) );
        end;
      end;
    end;
 
    Writeln('Всего слов с одинаковой буквой в начале и в конце: ', Cnt);
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

program Project1;
 
(*Функция подсчитывает количество слов с одинаковой буквой в начале и в конце.*)
function GetCount(const aStr : String) : Integer;
const
  //Все символы.
  Ds = [#0..#255];
  //Буквы.
  Da = [
    'А'..'П', 'Р'..'Я', 'Ё', 'а'..'п', 'р'..'я', 'ё',
    'A'..'Z', 'a'..'z'
  ];
  //Не буквы.
  D = Ds - Da;
var
  i, Pos1, Len, Cnt : Integer;
begin
  Len := Length(aStr);
  Pos1 := 0;
  Cnt := 0;
  for i := 1 to Len do begin
    //Пропускаем не буквы.
    if aStr[i] in D then Continue;
    //Отслеживаем начало слова.
    if (i = 1) or (aStr[i - 1] in D) then Pos1 := i;
    //Отслеживаем конец слова.
    if (i = Len) or (aStr[i + 1] in D) then begin
      //Проверка начальной и конечной буквы.
      if aStr[Pos1] = aStr[i] then begin
        Cnt := Cnt + 1;
      end;
    end;
  end;
 
  GetCount := Cnt;
end;
 
const
  N = 100;
var
  Arr : array[1..N] of String;
  S : String;
  i, Len, Cnt : Integer;
begin
  repeat
    Writeln('Задайте перечень строк. Конец ввода: "." + Enter.');
    Len := 0;
    repeat
      Readln(S);
      if S = '.' then Continue;
      Len := Len + 1;
      Arr[Len] := S;
    until (S = '.') or (Len = N);
 
    Writeln('Количество слов с одинаковой буквой в начале и в конце');
    Writeln('для каждой введённой строки:');
    for i := 1 to Len do begin
      Cnt := GetCount(Arr[i]);
      Writeln('Строка N', i:2, ', количество: ', Cnt);
    end;
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.