Сортировка рандомно введенного массива в виде спирали

program HelixMatrix_Sort;
 
const
  N = 5;
type
  TMatrix = array[0..N - 1, 0..N - 1] of integer;
 
  procedure ShowMatrix(const AMatrix: TMatrix; ARows, ACols: integer);
  var
    i, j: integer;
  begin
    for i := 0 to ARows - 1 do
    begin
      for j := 0 to ACols - 1 do
        Write(AMatrix[i, j]: 4);
      writeln;
    end;
  end;
 
var
  A: TMatrix;
  i, j: integer;
  Count: integer;
  ColPrev, RowPrev: integer;
  ColCurr, RowCurr: integer;
  dCol, dRow, dirChanges, visits: integer;
  temp: integer;
begin
  Count := 0;
  for i := 0 to N - 1 do
    for j := 0 to N - 1 do
    begin
      A[i, j] := Count;
      Inc(Count);
    end;
  ShowMatrix(A, N, N);
  writeln;
 
  for i := 1 to sqr(N) - 1 do
  begin
    RowCurr := 0;
    ColCurr := 0;
 
    dRow := 1;
    dCol := 0;
    dirChanges := 0;
    visits := N;
    for j := 1 to sqr(N) - i do
    begin
      ColPrev := ColCurr;
      RowPrev := RowCurr;
      {получение следующих координат}
      Dec(visits);
      if visits = 0 then
      begin
        visits := N - ((dirChanges div 2) - 1) - 2;
        temp := dRow;
        dRow := -dCol;
        dCol := temp;
        Inc(dirChanges);
      end;
      Inc(ColCurr, dCol);
      Inc(RowCurr, dRow);
      {а теперь обычное сравнение соседних элементов}
      if A[RowCurr, ColCurr] > A[RowPrev, ColPrev] then
      begin
        temp := A[RowCurr, ColCurr];
        A[RowCurr, ColCurr] := A[RowPrev, ColPrev];
        A[RowPrev, ColPrev] := temp;
      end;
    end;
  end;
  ShowMatrix(A, N, N);
  writeln;
end.