Как прочитать из файла цифры и погрузить в двоичное дерево

Program Derevo_Dvoich;
uses crt;
Type BT=LongInt; 
U = ^BinTree; 
BinTree = Record 
  Inf : BT; 
  L, R: U;
End;
var Num:LongInt; DEREVO:U; t:text;
 
{Рекурсивный вариант добавления элемента в дерево}
Procedure InsRec(Var Tree : U; x : BT);
Begin
   If Tree = Nil
   Then Begin 
        New(Tree);
        Tree^.L := Nil;
        Tree^.R := Nil;
        Tree^.Inf := x;
    End
   Else If (x < Tree^.inf) Then InsRec(Tree^.L, x)
    Else InsRec(Tree^.R, x);
End;
{ печати элементов дерева с использованием обхода двоичного дерева поиска в обратном порядке}
Procedure PrintTree(T : U);
begin
     if T <> Nil then 
     begin 
     PrintTree(T^.L); 
     writeln(T^.inf : 6); 
     PrintTree(T^.R);
     end;
end;
 
function find(Tree : U; x : BT) : boolean;
begin
    if Tree=nil then 
                    begin
                     find := false;            
                    writeln('False');
                    end
                else if Tree^.inf=x then 
                    begin
                    Find := True;
                    writeln('True');
                    end
                                    else if x < Tree^.inf
                                         then Find := Find(Tree^.L, x)
                                         else Find := Find(Tree^.R, x);
end;
{процедура создания двоичного дерева поиска, содержащего n элементов}
procedure sozd(f:text; var Tree: U);
var i, n,k: integer; a: bt; b:array[1..100] of LongInt;
begin
assign(f,'C:\PABCWork.NET\Files\nums.txt'); { в файле цифры от 1-9 через пробел записаны}
reset(f);
k:=0;
      Tree := nil;
      while not (eof(f)) do 
      begin
      k:=k+1;
      readln(f,b[k]);
      writeln(b[k]);
      end;
      
      for i:=1 to k do
      begin
      Insrec(Tree, b[k]);
      end;
end;
begin
DEREVO:=nil;
assign(t,'C:\PABCWork.NET\Files\nums.txt');
sozd(t,DEREVO);
writeln('ПЕчать:');
PrintTree(DEREVO);
writeln('Какое число вы хотите найти:');
readln(Num);
find(DEREVO,Num);
close(t);
writeln('END');
end.

program Derevo_Dvoich;
 
type
  BT = LongInt;
  U = ^BinTree;
  BinTree = Record
    Inf: BT;
    L, R: U;
  End;
 
{Рекурсивный вариант добавления элемента в дерево}
procedure InsRec(var Tree: U; x: BT);
begin
  if Tree = nil
  Then begin
    New(Tree);
    Tree^.L := nil;
    Tree^.R := nil;
    Tree^.Inf := x;
  end
  Else if (x < Tree^.inf) Then InsRec(Tree^.L, x)
  Else InsRec(Tree^.R, x);
end;
{ печати элементов дерева с использованием обхода двоичного дерева поиска в обратном порядке}
procedure PrintTree(T: U);
begin
  if T <> nil then
  begin
    PrintTree(T^.L);
    writeln(T^.inf:6);
    PrintTree(T^.R);
  end;
end;
 
function find(Tree: U; x: BT): boolean;
begin
  if Tree = nil then
  begin
    find := false;
    writeln('False');
  end
  else if Tree^.inf = x then
  begin
    Find := True;
    writeln('True');
  end
  else if x < Tree^.inf
    then Find := Find(Tree^.L, x)
  else Find := Find(Tree^.R, x);
end;
 
{процедура создания двоичного дерева поиска, содержащего n элементов}
procedure sozd(var Tree: U);
const
  txtFileName = 'nums1.txt';{'C:\PABCWork.NET\Files\nums.txt';}
var
  f: text;
  a: bt;
begin
  assign(f, txtFileName); { в файле цифры от 1-9 через пробел записаны}
  reset(f);
  Tree := nil;
  WriteLn('Читаем из файла ' + txtFileName);
  while not (eof(f)) do
  begin
    readln(f, a);
    write(a, ' ');
    Insrec(Tree, a);
  end;
  close(f);
end;
 
var
  Num: LongInt;
  DEREVO: U;
 
begin
  
  sozd(DEREVO);
  
  writeln('Печать дерева:');
  PrintTree(DEREVO);
  
  writeln('Какое число вы хотите найти:');
  readln(Num);
  find(DEREVO, Num);
  
  writeln('END');
end.