Определить, чередуются ли числа в массиве

program Project1;
 
const
  maxelem = 20;
type
  TArr = array [1..maxelem] of integer;
 
procedure InfInArr(var arr: TArr; var narr: integer);
{Процедура для ввода пользователем информации в одномерный массив}
var
  i: integer;
begin
  write('Введите значение количества элементов (не более ',maxelem,'): ');
  repeat
    Readln(narr);
    if (narr < 1) or (narr > maxelem) then
      writeln('Ошибка ввода! Повторите попытку.')
  until (narr > 0) and (narr < maxelem);
  for i:= 1 to narr do
    begin
      write('Введите значение элемента [',i,']: ');
      Read(arr[i]);     { Ввод значений в двумерный массив.}
    end;
  Readln;
end;
 
 
procedure InfOutArr(arr: TArr; narr: integer);
{Процедура для вывода одномерного массива в консоль}
var
  i: integer;
begin
  for i:= 1 to narr do
    write(' ',arr[i]:5);
  Writeln;
end;
 
 
function CheckAlternationOdd(arr: TArr; narr: integer): integer;
{Функция, которая проверяет чередование четных и нечетных элементов в массиве и возвращает
 0, если элементы чередуются или выводит индекс первого элемента, нарушающего
 закономерность.}
var
  i: integer;
begin
  CheckAlternationOdd:= 0;
  for i:= 2 to narr do
    if (arr[i] mod 2 = 0) and (arr[i-1] mod 2 = 0) or
       (arr[i] mod 2 <> 0) and (arr[i-1] mod 2 <> 0) then
      {если чередование нарушено}
      begin
        CheckAlternationOdd:= i;
        break;
      end;
end;
 
 
function CheckAlternationPosNeg(arr: TArr; narr: integer): integer;
{Функция, которая проверяет чередование положительных и отрицательных элементов в массиве и возвращает
 0, если элементы чередуются или выводит индекс первого элемента, нарушающего
 закономерность.}
var
  i: integer;
begin
  CheckAlternationPosNeg:= 0;
  for i:= 2 to narr do
    if (arr[i] > 0) and (arr[i-1] > 0) or
       (arr[i] < 0) and (arr[i-1] < 0) then
      {если чередование нарушено}
      begin
        CheckAlternationPosNeg:= i;
        break;
      end;
end;
 
var
  a: TArr;  { Переменная для хранения массива}
  n: integer; { Переменная для хранения значения количества элементов}
  v: byte; { Вспомогательная переменная для организации выбора режима вычислений}
begin
  InfInArr(a,n);
  writeln('Исходный массив:');
  InfOutArr(a,n);
  writeln('Введите цифру, чтобы выбрать режим проверки:');
  writeln(' 1- чтобы проверять на чередование четные и нечетные элементы.');
  writeln(' 2- чтобы проверять на чередование положительные и отрицательные элементы.');
  Readln(v);
  if v = 1 then
    writeln(CheckAlternationOdd(a,n)) { Проверка на чередование четных и нечетных элементов}
  else
    if v = 2 then
      writeln(CheckAlternationPosNeg(a,n)); { Проверка на чередование положительных и отрицательных элементов}
  readln;
end.