Определить количество столбцов с нулевыми элементами и номер строки с самой длинной серией одинаковых элементов

program Project1;
 
uses
  CRT;
const
  maxelem = 20;
 
type
  TMatrint = array[1..maxelem+1,1..maxelem+1] of integer;
 
 
procedure InfInMatr(var arr: TMatrint; var nn: integer);
{Процедура для ввода информации в матрицу}
var
  i,j: integer;
begin
  write('Введите значение размерности матрицы (не более ',maxelem,'): ');
  repeat
    Readln(nn);
    if (nn < 1) or (nn > maxelem) then
      writeln('Ошибка ввода! Повторите попытку.')
    else
      break;
  until false;
  for i:= 1 to nn do
    for j:= 1 to nn do
    begin
      write('Введите значение элемента [',i,',',j,']: ');
      Read(arr[i,j]);     { Ввод значений в двумерный массив.}
    end;
  Readln;
end;
 
procedure InfOutMatr(arr: TMatrint; nn: integer);
{Процедура для вывода матрицы в консоль}
var
  i,j: integer;
begin
  for i:= 1 to nn do
    begin
      for j:= 1 to nn do
        write(' ',arr[i,j]:5);    { Вывод двумерного массива в консоль.}
      Writeln;
    end;
end;
 
 
function NumberColNullElement(arr: TMatrint; nn: integer): integer;
{ Функция, которая подсчитывает количество столбцов матрицы в которых
  содержатся элементы с нулевым значением.}
var
   i,j,k: integer;
begin
  k:= 0;
  for j:= 1 to nn do          {Перебор индексов столбцов}
    for i:= 1 to nn do        {Перебор индексов строк}
        if arr[i,j] = 0 then  {Условие для поиска элементов с нулевым значением}
          begin
            inc(k);         {Подсчет количества совпадений}
            break;          {Прерывание работы второго цикла.
                             Если прерывания не будет, то программа будет подсчитывать
                             все нулевые элементы в массиве}
          end;
  NumberColNullElement:= k;
end;
 
 
procedure NumRowMaxSeriesElement(arr: TMatrint; nn: integer; var NumberRow: integer);
{ Процедура, которая находит номер строки с самой длинная
  серией одинаковых элементов}
var
   i,j,k: integer;  { Вспомогательные переменные для организации циклов.}
   maxseries: integer; { Переменная для хранения значения максимального количества обнаруженных серий в строках массива }
   maxrow: integer; { Переменная для хранения значения максимального количества обнаруженных серий в одной строке }
   st: integer; { Вспомогательная переменная для хранения значения начального адреса серии одинаковых элементов}
begin
  maxrow:= 0;
  for i:= 1 to nn do    { Цикл для перебора номеров  строк}
    begin
      st:= -1;  {Начальные значения флага и наибольшей длины}
      maxseries:= 0;
      for j:= 2 to nn+1 do   {Цикл для перебора номеров  столбцов с учетом выхода за диапазон}
        begin
          if arr[i,j-1] = arr[i,j] then {пока подряд одинаковые}
            begin
              if st < 0 then
                st:= j-1;   {запоминаем начало интервала}
            end
          else
            if st > 0 then {если элемента не равен, запоминаем номер этого элемента}
              begin
                k:= j-st;{считаем длину пройденного интервала}
                if k > maxseries then  {если она больше всех}
                  maxseries:= k; {то она макс}
                st:= -1; {ищем новый интервал}
              end;
        end;
      if maxseries > maxrow then  {Условие для поиска наибольшего количества серий одинаковых элементов среди строк}
        begin
          maxrow:= maxseries;
          NumberRow:= i;      {Нахождение номера строки с наибольшим количеством найденных серий}
        end
  end;
end;
 
 
var
  a: TMatrint; { Переменная для хранения матрицы}
  n: integer; { Переменная для хранения значения размерности матрицы}
  number: integer; {Переменная для хранения значения номера строки с наибольшим количеством серий элементов}
begin
  InfInMatr(a,n);          { Ввод информации в матрицу}
  clrscr;
  writeln('Исходная матрица: ');
  InfOutMatr(a,n);         { Вывод элементов матрицы в консоль}
  writeln('Количество столбцов, в которых содержатся нулевые элементы: ',NumberColNullElement(a,n));
  NumRowMaxSeriesElement(a,n,number); {Поиск номера строки в которой наибольшее количество серий}
  writeln('Номер строки, в которой наибольшее количество серий из элементов: ',number);
  Readln;
end.

const
  m = 20; //максимальный ранг матрицы
 
type
  matrix = array[1..m, 1..m] of integer; //тип для матрицы
 
function z(const x: matrix; p: integer): integer; //копия NumberColNullElement от ValentinNemo
var
  i, j, k: integer;
begin
  k := 0;
  for j := 1 to p do
    for i := 1 to p do
      if x[i, j] = 0 then
        begin
          inc(k);
          break
        end;
  z := k
end;
 
procedure s(const x: matrix; p: integer; var im: integer); //матрица, её ранг, строка с макс. длиной серии
var
  i, j, q, qm: integer; //счётчики, текущая длина серии, максимальная длина серии
begin
  im := 1; //пока считаем, что первая строка - с макс. серией
  qm := 1; //пока максимальная длина серии = 1
  for i := 1 to p do //цикл по строкам
    begin
      q := 1; //пока текущая длина серии = 1
      for j := 2 to p do //цикл по элементам строки
        if x[i, j - 1] = x[i, j] then //если одинаковые элементы подряд (серия), то
          begin
            inc(q); //увеличиваем текущую длину серии
            if q > qm then //если размер текущей длины серии больше максимальной длины серии, то
              begin
                qm := q; //запминаем новую максимальную длину серии
                im := i //и запоминаем новый номер строки с макс. серией
              end
          end
        else q := 1 //иначе текущая длина серии = 1
    end
end;
 
var
  a: matrix; //матрица
  i, j, n, imax: integer; //счётчики, ранг матрицы, номер строки с максимальной серией
begin
  repeat //ввод ранга матрицы с проверкой диапазона
    write('n в диапазоне [1..', m, ']; n = ');
    readln(n)
  until n in [1..m];
  writeln('Введите матрицу ', n, 'x', n, '.');
  writeln('Числа в строке разделяйте прбелами, строки разделяйте нажатием <Enter>.');
  for i := 1 to n do //ввод матрицы
    for j := 1 to n do
      read(a[i, j]);
  readln;
  writeln('Количество столбцов с нулями: ', z(a, n)); //пункт A
  s(a, n, imax); //пункт B
  writeln('Строка с длиннейшей серией одинаковых элементов: ', imax);
  readln
end.

            if q >= qm then

const
  n = 10; // ранг матрицы
 
type
  matrix = array[1..n, 1..n] of integer; //тип для матрицы
 
function z(const x: matrix): integer; //копия NumberColNullElement от ValentinNemo
var
  i, j, k: integer;
begin
  k := 0;
  for j := 1 to n do
    for i := 1 to n do
      if x[i, j] = 0 then
        begin
          inc(k);
          break
        end;
  z := k
end;
 
procedure s(const x: matrix; var im: integer); //матрица, её ранг, строка с макс. длиной серии
var
  i, j, q, qm: integer; //счётчики, текущая длина серии, максимальная длина серии
begin
  im := 1; //пока считаем, что первая строка - с макс. серией
  qm := 1; //пока максимальная длина серии = 1
  for i := 1 to n do //цикл по строкам
    begin
      q := 1; //пока текущая длина серии = 1
      for j := 2 to n do //цикл по элементам строки
        if x[i, j - 1] = x[i, j] then //если одинаковые элементы подряд (серия), то
          begin
            inc(q); //увеличиваем текущую длину серии
            if q > qm then //если размер текущей длины серии больше максимальной длины серии, то
              begin
                qm := q; //запминаем новую максимальную длину серии
                im := i //и запоминаем новый номер строки с макс. серией
              end
          end
        else q := 1 //иначе текущая длина серии = 1
    end
end;
 
var
  a: matrix; //матрица
  i, j, imax: integer; //счётчики, ранг матрицы, номер строки с максимальной серией
begin
  randomize;
  for i := 1 to n do //генерация и печать матрицы
    begin
      for j := 1 to n do
        begin
          a[i, j] := -9 + random(19);
          write(a[i, j]:3)
        end;
      writeln
    end;
  writeln('Количество столбцов с нулями: ', z(a)); //пункт A
  s(a, imax); //пункт B
  writeln('Строка с длиннейшей серией одинаковых элементов: ', imax);
  readln
end.