Вычислить значение суммы

@Zolotoy12 · Регистрация: 23.06.2020

Студворк — интернет-сервис помощи студентам

Здравствуйте.Нужно вычислить значение суммы (значение n вводится с клавиатуры):

$https://www.cyberforum.ru/cgi-bin/latex.cgi?<br /> x+\frac{x^3}{3}+\frac{x^5}{5}+\frac{x^7}{7}+...+\frac{x^{2n-1}}{2n-1}\ \ \ \ \<br />$ (x задано)

Я написал код, но преподаватель говорит, что "В программе не должен фигурировать ни логарифм, ни экспонента"
Код ниже :

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
program Vych_8;
var n,x:integer;
function sum(k:integer):extended;
begin
if k=1 then sum:=x
else
begin
sum:=sum(k-1);
sum:=sum+exp((2*k-1)*ln(x))/(2*k-1);
end;
end;
begin
repeat
writeln('x= '); readln(x);
writeln('n= '); readln(n);
until (x>=-100) and (x<=10000) and (n>0) and (n<=100);
writeln('x = ',x,' n = ',n);
writeln('s=',sum(n):0:3);
readln;
end.

И если можно, то нужно сделать как рекурсивная функция и как рекурсивная процедура. Спасибо

@JuriiMW · 24.06.2020, 14:01

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
function p(x : Real; n : Integer) : Real;
begin
  if n = 0 then
    p := 1
  else if odd(n) then
    p := x * p(x, n - 1)
  else
    p := sqr(p(x, n shr 1))
end;
 
function s(x : Real; n : Integer) : Real;
begin
  if n = 1 then
    s := x
  else
    s := ( s(x, n-1) * (2*n-1) + p(x, 2*n-1) ) / (2*n-1)
end;
 
var
  x : Real;
  n : Integer;
begin
  Read(x, n);
  WriteLn(s(x, n):0:7);
end.

@Puporev · 24.06.2020, 14:01

Сообщение от Zolotoy12

В программе не должен фигурировать ни логарифм, ни экспонента"

Это разложение в ряд Тейлора функции arth(x) при |x|<1.
С использованием рекурретного отношения.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
var n,i:integer;
    x,t,s:real;
begin
repeat
write('Введите |x|<1 x= ');
readln(x);
until abs(x)<1;
repeat
write('Введите n>0 n= ');
readln(n);
until n>0;
t:=x;
s:=t;
for i:=2 to n do
 begin
  t:=t*x*x;
  s:=s+t/(2*i-1);
 end;
writeln('S=',s:0:4);
write('arth(x)=',0.5*ln((1+x)/(1-x)):0:4)
end.

@Zolotoy12 · 24.06.2020, 15:22 **[ТС]**

Прошу прощения, не знаю, как ответить определенному человеку.
Puporev, когда пытаюсь ввести "x" , то делается это бесконечно. Только когда введу х=0, разрешает ввести "n".
JuriiMW, у вас это идет как функция? (не процедура)

@Puporev · 24.06.2020, 15:36

Zolotoy12, Вводите любое вещественное х -1<x<1.

Добавлено через 40 секунд
типа -0.85, 0.6

@Zolotoy12 · 24.06.2020, 15:40 **[ТС]**

Работает, спасибо большое) А Вы сделали это как функцию?

@Puporev · 24.06.2020, 15:43

Если Вы ко мне, то конечно нет, я просто показал как можно обойтись без логарифма и экспоненты.

@Zolotoy12 · 24.06.2020, 15:45 **[ТС]**

Puporev, понял) Спасибо большое за помощь. Может, если не заняты и есть желание, не могли бы Вы посмотреть другие мои темы? Зачёт горит(

@Zolotoy12 · 26.06.2020, 14:40 **[ТС]**

Может, кто-то знает, как сделать так:

*программа должна быть одна:

ввод заданного числа
расчет с помощью рекурсии
вывод ответа после рекурсии
расчет без рекурсии
вывод ответа без рекурсии* ?

@Cyborg Drone · 29.06.2020, 19:14

JuriiMW... Есть вариант получше, чем на каждой рекурсии заново вычислять степень.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
function sum_recursive(x, xk: real; k, n: integer): real;
begin
  if k = 2 * n - 1 then sum_recursive := xk / k
  else sum_recursive := sum_recursive(x, xk * x * x, k + 2, n) + xk / k
end;
 
var
  x: real;
  n: integer;
begin
  x := 0.7;
  n := 10;
  writeln('    S(x) = ', sum_recursive(x, x, 1, n) :0:15);
  writeln('arcth(x) = ', ln((1 + x) / (1 - x)) / 2 :0:15);
  readln
end.

Нехорошо смотрится и запутывает программу куча "лишних" формальных параметров? Можно сделать их глобальными по отношению к рекурсивной функции, например, 'обернуть' рекурсивную функцию дополнительной функцией, формальные параметры и локальные переменные которой будут глобальными по отношению к рекурсивной функции:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
function sum_recursive(x: real; n: integer): real;
  function recursive(xk: real; k, kmax: integer): real;
  begin
    if k = kmax then recursive := xk / k
    else recursive := recursive(xk * x * x, k + 2, kmax) + xk / k
  end;
begin
  sum_recursive := recursive(x, 1, 2 * n - 1)
end;
 
var
  x: real;
  n: integer;
begin
  x := 0.7;
  n := 10;
  writeln('    S(x) = ', sum_recursive(x, n) :0:15);
  writeln('arcth(x) = ', ln((1 + x) / (1 - x)) / 2 :0:15);
  readln
end.

Я всегда повторял и буду повторять: размещать глобальные переменные до подпрограмм нужно только тогда, когда это действительно необходимо, потому что это порождает трудно локализуемые ошибки, связанные с перекрытием областей видимости глобальных и локальных переменных. Эта функция - редкий пример того, когда действительно необходимо перекрытие областей видимости переменных из разных уровней иерархической структуры программы. Заметьте, что во вложенной подпрограмме значение глобальных по отношению к ней переменных не изменяется. Если будете использовать приведённый здесь способ создания подпрограмм, возьмите за правило не изменять значения переменных из более высоких уровней иерархии, чтобы не наделать ошибок из-за перекрытия областей видимости. Но, если очень нужно, то, конечно же, можно.

Zolotoy12, Вам для сдачи, чтобы не путаться во вложенных подпрограммах, подойдёт вот такой вариант:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
function sum_recursive(x, xk: real; k, n: integer): real;
begin
  if k = 2 * n - 1 then sum_recursive := xk / k
  else sum_recursive := sum_recursive(x, xk * x * x, k + 2, n) + xk / k
end;
 
function sum_iterative(x: real; n: integer): real;
var
  s, xk: real;
  k, kmax: integer;
begin
  xk := x;
  s := 0;
  k := 1;
  kmax := 2 * n - 1;
  while k <= kmax do
    begin
      s := s + xk / k;
      xk := xk * x * x;
      inc(k, 2)
    end;
  sum_iterative := s
end;
 
var
  x: real;
  n: integer;
begin
  repeat
    write('|x| < 1; x = ');
    readln(x)
  until abs(x) < 1;
  repeat
    write('n > 0; n= ');
    readln(n)
  until n > 0;
  writeln('     Сумма рекурсивно: ', sum_recursive(x, x, 1, n) :0:15);
  writeln('     Сумма итеративно: ', sum_iterative(x, n) :0:15);
  writeln('arcth(x) аналитически: ', ln((1 + x) / (1 - x)) / 2 :0:15);
  readln
end.

Но, если чувствуете уверенность в Ваших знаниях, используйте мой второй вариант рекурсивной функции. Не забудьте ещё вызов подправить.

Добавлено через 53 минуты
Для полноты картины.

Вариант с промежуточной функцией, простой и понятный, тоже для сдачи подойдёт:

Pascal
1
2
3
4
5
6
7
8
9
10
function recursive(x, xk: real; k, kmax: integer): real;
begin
  if k = kmax then recursive := xk / k
  else recursive := recursive(x, xk * x * x, k + 2, kmax) + xk / k
end;
 
function sum_recursive(x: real; n: integer): real;
begin
  sum_recursive := recursive(x, x, 1, 2 * n - 1)
end;

Более быстрый вариант с вложенной функцией (меньшее число формальных параметров у вложенной рекурсивной функции):

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
function sum_recursive(x: real; n: integer): real;
var
  kmax: integer;
  function recursive(xk: real; k: integer): real;
  begin
    if k = kmax then recursive := xk / k
    else recursive := recursive(xk * x * x, k + 2) + xk / k
  end;
begin
  kmax := 2 * n - 1;
  sum_recursive := recursive(x, 1)
end;

Новые блоги и статьи Все статьи Все блоги /
Валидация и контроль данных табличной части документа перед записью Maks 22.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа, разработанного в КА2. Задача: контроль и валидация данных табличной части документа перед записью с учетом регламента компании. . .	Отчёт о затраченных материалах за определенный период с макетом печатной формы Maks 21.04.2026 Отчёт из решения ниже размещён в конфигурации КА2. Задача: разработка отчёта по затраченным материалам за определённый период, с возможностью вывода печатной формы отчёта с шапкой и подвалом. В. . .	Отчёт о спецтехнике находящейся в ремонте Maks 20.04.2026 Отчёт из решения ниже размещен в конфигурации КА2. Задача: отобразить спецтехнику, которая на данный момент находится в ремонте. Есть нетиповой документ "Заявка на ремонт спецтехники" который. . .	Памятка для бота и "визитка" для читателей "Semantic Universe Layer (Слой семантической вселенной)" Hrethgir 19.04.2026 Сгенерировано для краткого описания по случаю сборки и компиляции скелета серверного приложения. И пусть после этого скажут, что статьи сгенерированные AI - туфта и не интересно. И это не реклама -. . .
Запрет удаления строк ТЧ документа при определённом условии Maks 19.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа "Аккумуляторы", разработанного в конфигурации КА2. У данного документа есть ТЧ, в которой в зависимости от прав доступа. . .	Модель заражения группы наркоманов alhaos 17.04.2026 Условия задачи сформулированы тут Суть: - Группа наркоманов из 10 человек. - Только один инфицирован ВИЧ. - Колются одной иглой. - Колются раз в день. - Колются последовательно через. . .	Мысли в слух. Про "навсегда". kumehtar 16.04.2026 Подумалось тут, что наверное очень глупо использовать во всяких своих установках понятие "навсегда". Это очень сильное понятие, и я только начинаю понимать край его смысла, не смотря на то что давно. . .	My Business CRM MaGz GoLd 16.04.2026 Всем привет, недавно возникла потребность создать CRM, для личных нужд. Собственно программа предоставляет из себя базу данных клиентов, в которой можно фиксировать звонки, стадии сделки, а также. . .

@Zolotoy12 0 / 0 / 0 Регистрация: 23.06.2020 Сообщений: 35
	24.06.2020, 15:22 [ТС]
	Прошу прощения, не знаю, как ответить определенному человеку. Puporev, когда пытаюсь ввести "x" , то делается это бесконечно. Только когда введу х=0, разрешает ввести "n". JuriiMW, у вас это идет как функция? (не процедура) 0

@Puporev Почетный модератор 64319 / 47615 / 32743 Регистрация: 18.05.2008 Сообщений: 115,167
	24.06.2020, 15:36
	Zolotoy12, Вводите любое вещественное х -1<x<1. Добавлено через 40 секунд типа -0.85, 0.6 0

@Zolotoy12 0 / 0 / 0 Регистрация: 23.06.2020 Сообщений: 35
	24.06.2020, 15:40 [ТС]
	Работает, спасибо большое) А Вы сделали это как функцию? 0

@Puporev Почетный модератор 64319 / 47615 / 32743 Регистрация: 18.05.2008 Сообщений: 115,167
	24.06.2020, 15:43
	Если Вы ко мне, то конечно нет, я просто показал как можно обойтись без логарифма и экспоненты. 0

@Zolotoy12 0 / 0 / 0 Регистрация: 23.06.2020 Сообщений: 35
	24.06.2020, 15:45 [ТС]
	Puporev, понял) Спасибо большое за помощь. Может, если не заняты и есть желание, не могли бы Вы посмотреть другие мои темы? Зачёт горит( 0

@Zolotoy12 0 / 0 / 0 Регистрация: 23.06.2020 Сообщений: 35
	26.06.2020, 14:40 [ТС]
	Может, кто-то знает, как сделать так: программа должна быть одна: ввод заданного числа расчет с помощью рекурсии вывод ответа после рекурсии расчет без рекурсии вывод ответа без рекурсии ? 0

Вычислить значение суммы

Решение