Решение обратного гиперболического тангенса

@Agata_Kristi_ · Регистрация: 09.10.2020

Студворк — интернет-сервис помощи студентам

Помогите решить задачу, пожалуйста

$https://www.cyberforum.ru/cgi-bin/latex.cgi?arth(x)=\sum_{n=0 }^{\infty }{x}^{2n+1}/2n+1=x+{x}^{3}/3+{x}^{5}/5+{x}^{7}+..., |x|\leq 1$

@Cyborg Drone · 13.10.2020, 03:17

В формуле ошибка, должно быть -1 <= x < 1, поскольку при x = 1 получается гармонический ряд, который расходится.

Задачка простая только на первый взгляд. Стандартный подсчёт суммы ряда до тех пор, пока модуль очередного члена ряда не станет меньше наперёд заданной точности, не получится, поскольку ряд знакопостоянный.

Единственное, что приходит на ум, это применить признак сравнения. Модуль любого член ряда не более соответствующего члена ряда для геометрической прогрессии с первым членом |x| и знаменателем прогрессии x². Формула суммы для членов бесконечной геометрической прогрессии известна. Вычисления можно прекратить, когда будет

$https://www.cyberforum.ru/cgi-bin/latex.cgi?<br /> \frac{|x|^{2n+1}}{1-|x|}\,<\,\varepsilon<br />$

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
var
  x, xn, qq, at, arth, eps, z: real;
  n: integer;
begin
  write('              x = ');
  readln(x);
  at := ln((1 + x) / (1 - x)) / 2;
  if x < 0 then
    begin
      z := -1;
      x := -x;
    end
  else z := 1;
  write('            eps = ');
  readln(eps);
  n := 1;
  xn := x;
  arth := xn;
  qq := 1 - x;
  while xn / qq > eps do
    begin
      inc(n, 2);
      xn := xn * x * x;
      arth := arth + xn / n
    end;
  writeln('        arth(x) = ', z * arth:0:12);
  writeln('Точное значение = ', at:0:12);
  readln
end.

@Agata_Kristi_ · 13.10.2020, 18:24 **[ТС]**

Уже большое спасибо!
Однако, прошу прощения, но я не до конца записала условия, если это что-то изменит!

"Вычислить и вывести на экран в виде таблицы значения функции, заданной с помощью ряда, на интервале Xнач. до Xкон. с шагом dX и точностью E.
Таблицу снабдить заголовком и названием. Строка таблицы должна содержать значение аргумента, значение функции и количество просуммированных членов."

@Cyborg Drone · 13.10.2020, 20:22

Agata_Kristi_, плохая новость: телепатии не существует. Конечно, приведённая выше программа - это часть решения, но... Рекомендую Вам ознакомиться с правилами форума, ссылка на правила есть наверху любой страницы форума. Среди прочего там написано:

4.7. Как можно более полно описывайте суть проблемы или вопроса, что было сделано для ее решения и какие результаты получены.

Если бы Вы сразу написали то, что Вам нужно, я бы не стал делать ненужную работу, и мог бы помочь ещё кому-нибудь.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
const
  hor = '+---------------+---------------+-----+';
var
  x, xn, xk, xx, dx, qq, arth, e, z: real;
  n: integer;
begin
  writeln('Табуляция функции y = arth(x), заданной в виде ряда Тейлора');
  writeln('с точностью е на интервале от xn до xk с шагом dx');
  writeln;
  write('e = ');
  readln(e);
  write('xn = ');
  readln(xn);
  write('xk = ');
  readln(xk);
  write('dx = ');
  readln(dx);
  writeln;
  x := xn;
  writeln(hor);
  writeln('|       x       |    arth(x)    | Nmax|');
  writeln(hor);
  while x < xk + dx / 2 do
    begin
      write('|', x:14:10, ' |');
      if abs(x) >= 1 then writeln('Не определено':14, ' |', '--':4, ' |')
      else
        begin
          if x < 0 then z := -1
          else z := 1;
          n := 1;
          xx := abs(x);
          arth := xx;
          qq := 1 - x;
          while xx / qq > e do
            begin
              inc(n, 2);
              xx := xx * x * x;
              arth := arth + xx / n
            end;
          writeln(z * arth:14:10, ' |', n div 2 + 1:4, ' |');
        end;
      x := x + dx
    end;
  writeln(hor);
  readln
end.

Протокол работы программы

Code
Табуляция функции y = arth(x), заданной в виде ряда Тейлора
с точностью е на интервале от xn до xk с шагом dx
 
e = 0.00001
xn = -1.2
xk = 0.8
dx = 0.2
 
+---------------+---------------+-----+
|       x       |    arth(x)    | Nmax|
+---------------+---------------+-----+
| -1.2000000000 | Не определено |  -- |
| -1.0000000000 | Не определено |  -- |
| -0.8000000000 | -1.0986117039 |  25 |
| -0.6000000000 | -0.6931470098 |  12 |
| -0.4000000000 | -0.4236488468 |   7 |
| -0.2000000000 | -0.2027325521 |   5 |
| -0.0000000000 | -0.0000000000 |   1 |
|  0.2000000000 |  0.2027325521 |   5 |
|  0.4000000000 |  0.4236489184 |   8 |
|  0.6000000000 |  0.6931471235 |  13 |
|  0.8000000000 |  1.0986122357 |  30 |
+---------------+---------------+-----+

Новые блоги и статьи Все статьи Все блоги /
1С: Контроль уникальности заводского номера Maks 23.03.2026 Алгоритм контроля уникальности заводского (или серийного) номера на примере документа выдачи шин для спецтехники с табличной частью. Данные берутся из регистра сведений, по которому настроено. . .	Хочу заставить корпорации вкладываться в здоровье сотрудников: делаю мат модель здравосохранения anaschu 22.03.2026 e7EYtONaj8Y Z4Tv2zpXVVo https:/ / github. com/ shumilovas/ med2. git	1С: Программный отбор элементов справочника по группе Maks 22.03.2026 Установка программного отбора элементов справочника "Номенклатура" из модуля формы документа. В качестве фильтра для отбора справочника служит группа номенклатуры. Отбор по наименованию группы. . .	Как я обхитрил таблицу Word Alexander-7 21.03.2026 Когда мигает курсор у внешнего края таблицы, и нам надо перейти на новую строку, а при нажатии Enter создается новый ряд таблицы с ячейками, то мы вместо нервных нажатий Энтеров мы пишем любые буквы. . .
Krabik - рыболовный бот для WoW 3.3.5a AmbA 21.03.2026 без регистрации и смс. Это не торговля, приложение не содержит рекламы. Выполняет свою непосредственную задачу - автоматизацию рыбалки в WoW - и ничего более. Однако если админы будут против -. . .	1С: Программный отбор элементов справочника по значению перечисления Maks 21.03.2026 Установка программного отбора элементов справочника "Сотрудники" из модуля формы документа. В качестве фильтра для отбора служит значение перечислений. / / Событие "НачалоВыбора" реквизита на форме. . .	Переходник USB-CAN-GPIO Eddy_Em 20.03.2026 Достаточно давно на работе возникла необходимость в переходнике CAN-USB с гальваноразвязкой, оный и был разработан. Однако, все меня терзала совесть, что аж 48-ногий МК используется так тупо: просто. . .	Оттенки серого Argus19 18.03.2026 Оттенки серого Нашёл в интернете 3 прекрасных модуля: Модуль класса открытия диалога открытия/ сохранения файла на Win32 API; Модуль класса быстрого перекодирования цветного изображения в оттенки. . .

@Agata_Kristi_ 0 / 0 / 0 Регистрация: 09.10.2020 Сообщений: 4

	Решение обратного гиперболического тангенса 12.10.2020, 19:55. Показов 1288. Ответов 3 Метки нет (Все метки) Помогите решить задачу, пожалуйста $https://www.cyberforum.ru/cgi-bin/latex.cgi?arth(x)=\sum_{n=0 }^{\infty }{x}^{2n+1}/2n+1=x+{x}^{3}/3+{x}^{5}/5+{x}^{7}+..., \|x\|\leq 1$ 0

@Agata_Kristi_ 0 / 0 / 0 Регистрация: 09.10.2020 Сообщений: 4
	13.10.2020, 18:24 [ТС]
	Уже большое спасибо! Однако, прошу прощения, но я не до конца записала условия, если это что-то изменит! "Вычислить и вывести на экран в виде таблицы значения функции, заданной с помощью ряда, на интервале Xнач. до Xкон. с шагом dX и точностью E. Таблицу снабдить заголовком и названием. Строка таблицы должна содержать значение аргумента, значение функции и количество просуммированных членов." 0