Ввести два массива и обработать их заданным образом

type
  matrix = array[1..4, 1..5] of real; {тип для матрицы}
  arr = array[1..20] of real; {тип для массива элементов, бОльших r}
 
{процедура для вода матрицы}
procedure m_in(var m: matrix; k: integer);
var
  i, j: integer;
begin
  writeln('Введите вещественную матрицу 4x', k, ' чисел,');
  writeln('отделяя числа друг от друга пробелом или переходом на новую строку,');
  writeln('после последнего числа перейдите на новую строку');
  for i := 1 to 4 do
    for j := 1 to k do
      read(m[i,j]);
  readln
end;
 
{процедура для вывода матрицы}
procedure m_out(const m: matrix; k: integer);
var
  i, j: integer;
begin
  writeln('Матрица 4x', k, ' чисел:');
  for i := 1 to 4 do
    begin
      for j := 1 to k do write(m[i,j]:14, ' ');
      writeln
    end
end;
 
{функция нахождения элементов, бОльших r, и их количества}
function gr_r(const m: matrix; k: integer; r: real; var d: arr): integer;
var
  i, j, n: integer;
begin
  n := 0;
  for i := 1 to 4 do
    for j := 1 to k do
      if m[i,j] > r then
        begin
          inc(n);
          d[n] := m[i,j]
        end;
  gr_r := n
end;
 
{функция нахождения произведения элементов из заштрихованной области}
function prod(const m: matrix; k: integer): real;
var
  i: integer;
  p: real;
begin
  p := 1;
  for i := 1 to 4 do p := p * m[i,1] * m[i,k];
  for i := 2 to k - 1 do p := p * m[1,i] * m[4,i];
  prod := p
end;
 
{процедура вызова процедур и функций}
procedure do_it(var m: matrix; k: integer; r: real; var d: arr; var n: integer; var p: real);
begin
  m_in(m, k);
  m_out(m, k);
  n := gr_r(m, k, r, d);
  p := prod(m, k);
end;
 
{процедура вывода результатов}
procedure res_out(const m: matrix; k: integer; const d: arr; n: integer; p: real);
var
  i: integer;
begin
  writeln('Элементы матрицы, большие r:');
  for i := 1 to n do write(d[i]:14, '  ');
  writeln;
  writeln('Их количество: ', n);
  writeln('Произведение элементов из заштрихованной области = ', p:14);
  writeln
end;
 
var
  a, b: matrix;
  d: arr;
  n: integer;
  r, p: real;
begin
  write('r = ');
  readln(r);
  do_it(a, 3, r, d, n, p);
  res_out(a, 3, d, n, p);
  do_it(b, 5, r, d, n, p);
  res_out(b, 5, d, n, p);
  readln
end.