Произвести заданные действия с одномерным массивом

@Terfor · Регистрация: 03.05.2023

Студворк — интернет-сервис помощи студентам

Указание. Заполните одномерный числовой массив D(15) случайными целыми числами в интервале [-20; 18]. Выведите значения элементов массива сначала в столбик, а затем в строку, причём на каждый элемент отведите 4 позиции. Ответ каждой задачи следует выводить с новой строки и с пояснительным текстом. Кроме того, следует каждый раз производить вывод массива на экран, если в нём произошли изменения: перестановка, замена, изменение значения элементов и т.д.

Для первых трёх задач создайте алгоритм и программу, используя CASE для выбора каждой задачи по номеру. Для остальных задач: для каждой задачи создайте свой алгоритм и код программы

Задача 10.1. Найдите отдельно количество отрицательных и положительных элементов массива.

Задача 10.2. Найдите произведение элементов, имеющих значение меньше -2 (минус два).

Задача 10.3. Найдите максимальный элемент массива из элементов, стоящих на местах, номера которых кратны пяти.

Задача 10.4. Замените отрицательные элементы, стоящие на нечётных местах на последний элемент массива.

Задача 10.5. Если в массиве имеются нулевые элементы, то найдите сумму элементов массива, имеющих значение, кратное трём, иначе выведите на экран положительные элементы массива

Задача 10.6. Найдите в массиве элементы, кратные 12, и вывести на экран их номера. Если таких элементов нет, то выведите сообщение об этом на экран

Задача 10.7. Выведите на экран одномерный массив, раскрасив в нем красным цветом кратные 12 элементы

@Cyborg Drone · 04.05.2023, 19:09

Вообще, один вопрос - одна тема. Ну да ладно, не будем придираться, а будем считать, что всё это пункты одного и того же вопроса.

10.1 - 10.3

Произвести заданные действия с одномерным массивом

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
const
  n = 15;
  a = -20;
  b = 18;
var
  d: array[1..n] of integer;
  i, c, ko, kp, p, m: integer;
begin
  randomize;
  for i := 1 to n do d[i] := b - random(b - a + 1);
  writeln('Массив в столбик:');
  for i := 1 to n do writeln(d[i]:4);
  writeln('Массив в строку:');
  for i := 1 to n do write(d[i]:4);
  writeln;
  repeat
    writeln;
    writeln('Задачи 10.1 - 10.3. Выберите действие:');
    writeln('1. Найти отдельно количество отрицательных и положительных элементов массива.');
    writeln('2. Найти произведение элементов, имеющих значение, меньшее -2.');
    writeln('3. Найти максимальный элемент массива из элементов,');
    writeln('   стоящих на местах, номера которых кратны пяти.');
    writeln('Любое другое число - выход из программы.');
    write('Ваш выбор? ');
    readln(c);
    case c of
      1:
        begin
          ko := 0;
          kp := 0;
          for i := 1 to n do
            if d[i] < 0 then inc(ko)
            else
              if d[i] > 0 then inc(kp);
          writeln('Количество отрицательных = ', ko, ', количество положительных = ', kp)
        end;
      2:
        begin
          p := 1;
          for i := 1 to n do
            if d[i] < -2 then p := p * d[i];
          if p <> 1 then writeln('Произведение элементов со значением < -2, равно ', p)
          else writeln('Элементов со значением < -2 не найдено')
        end;
      3:
        begin
          i := 5;
          repeat
            if (i = 5) or (d[i] > m) then m := d[i];
            inc(i, 5)
          until i > n;
          writeln('Максимальный элемент из элементов с номером, кратным 5, равен ', m)
        end
    end
  until not (c in [1..3])
end.

10.4

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
const
  n = 15;
  a = -20;
  b = 18;
var
  d: array[1..n] of integer;
  i: integer;
  found: boolean;
begin
  randomize;
  for i := 1 to n do d[i] := b - random(b - a + 1);
  writeln('Массив в столбик:');
  for i := 1 to n do writeln(d[i]:4);
  writeln('Массив в строку:');
  for i := 1 to n do write(d[i]:4);
  writeln;
  writeln('Задача 10.4');
  writeln('Отрицательные элементы с нечётным индексом заменить на последний элемент');
  found := false;
  for i := 1 to n - 1 do
    if odd(i) and (d[i] < 0) then
      begin
        found := true;
        d[i] := d[n]
      end;
  if found then
    begin
      writeln('Изменённый массив:');
      for i := 1 to n do write(d[i]:4);
      writeln
    end
  else writeln('Массив не изменился');
  readln
end.

10.5

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
const
  n = 15;
  a = -20;
  b = 18;
var
  d: array[1..n] of integer;
  i, s: integer;
  found: boolean;
begin
  randomize;
  for i := 1 to n do d[i] := b - random(b - a + 1);
  writeln('Массив в столбик:');
  for i := 1 to n do writeln(d[i]:4);
  writeln('Массив в строку:');
  for i := 1 to n do write(d[i]:4);
  writeln;
  writeln('Задача 10.5');
  writeln('Если в массиве имеются нулевые элементы,');
  writeln('то найдите сумму элементов массива, имеющих значение, кратное трём,');
  writeln('иначе выведите на экран положительные элементы массива');
  found := false;
  for i := 1 to n do
    if d[i] = 0 then found := true;
  if found then
    begin
      writeln('Найдены нулевые элементы');
      s := 0;
      for i := 1 to n do
        if d[i] mod 3 = 0 then inc(s, d[i]);
      writeln('Сумма элементов, кратных 3, равна ', s)
    end
  else
    begin
      writeln('Нулевые элементы не найдены');
      found := false;
      writeln('Положительные элементы массива: ');
      for i := 1 to n do
        if d[i] > 0 then
          begin
            write(d[i]:4);
            found := true
          end;
      if not found then writeln('не найдены') else writeln
    end;
  readln
end.

10.6

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
const
  n = 15;
  a = -20;
  b = 18;
var
  d: array[1..n] of integer;
  i: integer;
  found: boolean;
begin
  randomize;
  for i := 1 to n do d[i] := b - random(b - a + 1);
  writeln('Массив в столбик:');
  for i := 1 to n do writeln(d[i]:4);
  writeln('Массив в строку:');
  for i := 1 to n do write(d[i]:4);
  writeln;
  writeln('Задача 10.6');
  writeln('Найдите в массиве элементы, кратные 12, и вывести на экран их номера');
  writeln('Если таких элементов нет, то выведите сообщение об этом на экран');
  found := false;
  writeln('Номера элементов массива, кратных 12: ');
  for i := 1 to n do
    if d[i] mod 12 = 0 then
      begin
        write(i:3);
        found := true
      end;
  if not found then writeln('не найдены');
  readln
end.

10.7

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
uses
  crt;
const
  n = 15;
  a = -20;
  b = 18;
var
  d: array[1..n] of integer;
  i: integer;
begin
  randomize;
  for i := 1 to n do d[i] := b - random(b - a + 1);
  writeln('Массив в столбик:');
  for i := 1 to n do writeln(d[i]:4);
  writeln('Массив в строку:');
  for i := 1 to n do write(d[i]:4);
  writeln;
  writeln('Задача 10.7');
  writeln('Выведите на экран одномерный массив,');
  writeln('раскрасив в нем красным цветом кратные 12 элементы');
  for i := 1 to n do
    begin
      if d[i] mod 12 = 0 then TextColor(4);
      write(d[i]:4);
      TextColor(7)
    end;
  readln
end.

Новые блоги и статьи Все статьи Все блоги /
Воспроизведение звукового файла с помощью SDL3_mixer при касании экрана Android 8Observer8 26.01.2026 Содержание блога SDL3_mixer - это библиотека я для воспроизведения аудио. В отличие от инструкции по добавлению текста код по проигрыванию звука уже содержится в шаблоне примера. Нужно только. . .	Установка Android SDK, NDK, JDK, CMake и т.д. 8Observer8 25.01.2026 Содержание блога Перейдите по ссылке: https:/ / developer. android. com/ studio и в самом низу страницы кликните по архиву "commandlinetools-win-xxxxxx_latest. zip" Извлеките архив и вы увидите. . .	Вывод текста со шрифтом TTF на Android с помощью библиотеки SDL3_ttf 8Observer8 25.01.2026 Содержание блога Если у вас не установлены Android SDK, NDK, JDK, и т. д. то сделайте это по следующей инструкции: Установка Android SDK, NDK, JDK, CMake и т. д. Сборка примера Скачайте. . .	Использование SDL3-callbacks вместо функции main() на Android, Desktop и WebAssembly 8Observer8 24.01.2026 Содержание блога Если вы откроете примеры для начинающих на официальном репозитории SDL3 в папке: examples, то вы увидите, что все примеры используют следующие четыре обязательные функции, а. . .
моя боль iceja 24.01.2026 Выложила интерполяцию кубическими сплайнами www. iceja. net REST сервисы временно не работают, только через Web. Написала за 56 рабочих часов этот сайт с нуля. При помощи perplexity. ai PRO , при. . .	Модель сукцессии микоризы anaschu 24.01.2026 Решили писать научную статью с неким РОманом	http://iceja.net/ математические сервисы iceja 20.01.2026 Обновила свой сайт http:/ / iceja. net/ , приделала Fast Fourier Transform экстраполяцию сигналов. Однако предсказывает далеко не каждый сигнал (см ограничения http:/ / iceja. net/ fourier/ docs ). Также. . .	http://iceja.net/ сервер решения полиномов iceja 18.01.2026 Выкатила http:/ / iceja. net/ сервер решения полиномов (находит действительные корни полиномов методом Штурма). На сайте документация по API, но скажу прямо VPS слабенький и 200 000 полиномов. . .

@Terfor 0 / 0 / 0 Регистрация: 03.05.2023 Сообщений: 3

	Произвести заданные действия с одномерным массивом 03.05.2023, 16:21. Показов 466. Ответов 1 Метки паскаль (Все метки) Указание. Заполните одномерный числовой массив D(15) случайными целыми числами в интервале [-20; 18]. Выведите значения элементов массива сначала в столбик, а затем в строку, причём на каждый элемент отведите 4 позиции. Ответ каждой задачи следует выводить с новой строки и с пояснительным текстом. Кроме того, следует каждый раз производить вывод массива на экран, если в нём произошли изменения: перестановка, замена, изменение значения элементов и т.д. Для первых трёх задач создайте алгоритм и программу, используя CASE для выбора каждой задачи по номеру. Для остальных задач: для каждой задачи создайте свой алгоритм и код программы Задача 10.1. Найдите отдельно количество отрицательных и положительных элементов массива. Задача 10.2. Найдите произведение элементов, имеющих значение меньше -2 (минус два). Задача 10.3. Найдите максимальный элемент массива из элементов, стоящих на местах, номера которых кратны пяти. Задача 10.4. Замените отрицательные элементы, стоящие на нечётных местах на последний элемент массива. Задача 10.5. Если в массиве имеются нулевые элементы, то найдите сумму элементов массива, имеющих значение, кратное трём, иначе выведите на экран положительные элементы массива Задача 10.6. Найдите в массиве элементы, кратные 12, и вывести на экран их номера. Если таких элементов нет, то выведите сообщение об этом на экран Задача 10.7. Выведите на экран одномерный массив, раскрасив в нем красным цветом кратные 12 элементы 0