Найти самое короткое слово начинающееся на букву "а", и поменять его с первым словом в строке

program Project1;
 
type
  //Сведения о координатах слова.
  TWInfo = record
    Start, Len : Integer;
  end;
 
const
  //Множество разделителей слов.
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
  //Множество русских и английских букв "а".
  Da = ['А', 'а', 'A', 'a'];
var
  S, Sw : String;
  i, Cnt, Len, LenW, P1 : Integer;
  W1, W2 : TWInfo;
begin
  repeat
    //Исходный текст.
    Writeln('Задайте текст:');
    Readln(S);
    Len := Length(S);
 
    LenW := 0;
    Cnt := 0;
    //Начальное задание координат первого слова.
    W1.Start := 0;
    W1.Len := 0;
    //Начальное задание координат самого короткого слова из тех,
    //которые начинаются на букву "А".
    W2.Start := 0;
    W2.Len := Len + 1;
    for i := 1 to Len do begin
      //Пропуск разделителей.
      if S[i] in D then Continue;
      //Уточнение длины текущего слова.
      Inc(LenW);
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        Inc(Cnt); //Порядковый номер слова.
        P1 := i - LenW + 1;
        if Cnt = 1 then begin
          W1.Len := LenW;
          W1.Start := P1;
        end;
        if (LenW < W2.Len) and (S[P1] in Da) then begin
          W2.Len := LenW;
          W2.Start := P1;
        end;
        LenW := 0; //Обнуляем длину слова.
      end;
    end;
 
    if W1.Start = 0 then
      Writeln('В тексте нет слов.')
    else if W1.Start = W2.Start then
      Writeln('Первое слово является самым коротким, среди начинающихся на букву "А".')
    else begin //Меняем слова местами.
      //Запоминаем самое короткое слово.
      Sw := Copy(S, W2.Start, W2.Len);
      //Удаляем самое короткое слово.
      Delete(S, W2.Start, W2.Len);
      //На место самого короткого слова вставляем первое слово.
      Insert(Copy(S, W1.Start, W1.Len), S, W2.Start);
      //Удаляем первое слово.
      Delete(S, W1.Start, W1.Len);
      //На место первого слова записываем самое короткое слово.
      Insert(Sw, S, W1.Start);
      //Вывод результатов.
      Writeln('Изменённый текст:');
      Writeln(S);
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.