Работа со множествами

 Отдельные слова в ней разделены запятыми (<= 70 символов).

uses crt;
const gl=['а','е','ё','и','о','у','ы','э','ю','я'];{множество строчных русских гласных букв, как пишут старшие товарищи, их 10}
      ds=['а'..'п','р'..'ё',',','.'];{множество допустимых символов}
type mn=set of char;{тип множеств}
var s,s1:string;{вводимый текст-строка, вспомогательная строка для выделения слов}
    c:char;{символ}
    ch,nch:array[1..35] of string;{массивы четных и нечетных слов}
    mnch,mres:mn;{множество гласных из нечетных слов и результирующее из четных слов}
    mch:array[1..35] of mn;{массив множеств из гласных букв четных слов}
    i,j,nc,nn:byte;{счетчики циклов, фактические размеры массивов}
begin
clrscr;{очищаем экран}
writeln('Введите строку из русских строчных букв,');
writeln('образующую слова, разделенные запятыми. Окончание ввода точка:');
s:='';{сначала текст=пустая строка}
i:=0;
repeat
 repeat
  c:=readkey;{читаем код нажатой клавиши}
 until c in ds;{если допустимый символ}
write(c);{выводим символ с этим кодом на экран}
i:=i+1;{считаем символы}
s:=s+c;{заносим его в строку}
if i=69 then s:=s+'.';{если осталось ввести один, то его не вводим, а присваиваем точку}
until (c='.')or (i=70);{если нажали точку или уже 70 символов-конец ввода}
writeln;
s[length(s)]:=',';{для удобства заменим точку на запятую}
i:=0;nc:=0;nn:=0;{обнуляем счетчик слов и размеры массивов}
while pos(',',s)>0 do{пока в строке есть запятые}
 begin
  inc(i);{считаем их(т.е. слова)}
  s1:=copy(s,1,pos(',',s)-1);{берем слово до запятой}
  if odd(i) then{собираем массив нечетных слов}
   begin
    inc(nn);
    nch[nn]:=s1;
   end
  else {собираем массив четных слов}
   begin
    inc(nc);
    ch[nc]:=s1;
   end;
  delete(s,1,pos(',',s));{удаляем просмотренное слово с запятой}
 end;
mnch:=[];{множество гласных в нечетных пока пустое}
for i:=1 to nn do
for j:=1 to length(nch[i])do
if nch[i][j] in gl then include(mnch,nch[i][j]);{выбираем из всех нечетных слов гласные буквы}
for i:=1 to nc do{создаем массив множеств гласных букв четных слов}
 begin
  mch[i]:=[];
  for j:=1 to length(ch[i]) do
  if (ch[i][j] in gl)and not(ch[i][j] in mnch)then include(mch[i],ch[i][j]);{из каждого слова создаем множество}
 end;
mres:=gl;{результирующее множество пока включает все гласные буквы}
for i:=1 to nc do
mres:=mres*mch[i];{перемножаем(получаем пересечение всех множеств гласных букв четных слов)}
if mres=[] then{если ни одной буквы нет}
write('Гласных букв, входящих во все четные слова и не входящих в нечетные слова, нет!')
else {иначе выводим все буквы по алфавиту.}
 for i:=160 to 241 do{диапазон кодов, в который попадают нужные нам символы}
 if chr(i) in mres then write(chr(i),' ');
{если символ есть в во всех четных словах выводим ее на экран через пробел}
readln
end.