Pascal: массивы

uses crt;
const
trd:array[0..7] of string[3]=('000','001','010','011','100','101','110','111');{все трехразрядные двоичные числа}
n=45;{количество двоичных цифр в массиве(кратно трем)}
m=10;{количество строк в матрице}
type
mChar=array[1..n] of char;{массив двоичных цифр}
mCifr=array[1..n div 3] of byte;{массив десятичных цифр(в 3 раза меньше)}
procedure BinToDec(ch:mChar;var cf:mCifr);{процедура преобразования}
var i,j,k,l:byte;
    s:string;
begin
l:=0;{счетчик десятичного массива}
for i:=1 to n do{идем по двоичному массиву}
if i mod 3=1 then{если индекс=1,4,7.....}
 begin
  s:='';{начало строки}
  l:=l+1;{очередное десятичное число}
  for j:=i to i+2 do{из трех символов}
  s:=s+ch[j];{собираем строку}
  for k:=0 to 7 do{смотрим наши триады(константа)}
  if s=trd[k] then cf[l]:=k;{с каким номером в константе совпадает, та и десятичная цифра}
 end;
end;
 
var a:array[1..m] of mChar;{матрица- массив  двоичных строк}
    b:array[1..m] of mCifr;{матрица десятичных цифр}
    i,j:byte;
begin
clrscr;
randomize;
writeln('Двоичный массив:');
for i:=1 to m do
 begin
  for j:=1 to n do
   begin
    a[i,j]:=chr(random(2)+48);{случайно назначаем символ  '0' или '1'}
    if j mod 3=0 then write(a[i,j],' '){если конец триады, ставим пробел}
    else write(a[i,j]);{если нет, подряд}
   end;
  writeln;
 end;
writeln;
writeln('Десятичный массив:');
for i:=1 to m do{идем по строкам матрицы символов}
BinToDec(a[i],b[i]);{преобразуем массивы двоичных символов в массивы десятичных цифр}
for i:=1 to m do{выводим результат на экран}
 begin
  for j:=1 to n div 3 do
  write(b[i,j],' ');
  writeln;
 end;
readln
end.