Матрица со спиралью из простых чисел

readln(n);
sered:= (n div 2)+1;

for i:=1 to sered do
m[(sered-1)+i,i):=p[i];

for i:=1 to n do
 begin
  for J:=1 to n do
   write(m[i,j],' ');
 writeln;
 end;

uses crt;
{определение простого числа}
function Prost(a:longint):boolean;
var i:longint;
    f:boolean;
begin
if a<2 then f:=false
else
 begin
  f:=true;{считаем что простое}
  i:=2;
  while (i*i<=a) and f do{пока счетчик меньше корня из числа и нет делителей}
  if a mod i=0 then f:=false{если делитель, не постое}
  else i:=i+1;{иначе дальше}
 end;
 Prost:=f;{результат true или false}
end;
const nmax=11;
var a:array[1..nmax,1..nmax] of longint;
    n,i,j,p,r:byte;
    k:longint;
begin
clrscr;
repeat
write('Размер матрицы от 3 до ',nmax,' нечетное число n=');
readln(n);
until(n in [3..11]) and odd(n);
for i:=1 to n do
for j:=1 to n do
a[i,j]:=0;{заполним матрицу нолями}
k:=1;{первое число}
p:=n div 2+1;{номер первой строки}
i:=p;
j:=1;
r:=1;{первый виток спирали}
a[i,j]:=k;{пишем 1}
repeat{накручиваем витки}
 while i>r do{идем вправо и вверх}
  begin
   repeat
   if k<3 then inc(k) else inc(k,2);{если 1 и 2, то добавим 1,
                                     иначе +2, только нечетные}
   until Prost(k);{следующее простое}
   dec(i);
   inc(j);
   a[i,j]:=k;
  end;
while j<=n-r do{вправо и вниз}
 begin
  inc(i);
  inc(j);
  repeat
  inc(k,2);
  until Prost(k);
  a[i,j]:=k;
 end;
while i<=n-r do{влево и вниз}
 begin
  inc(i);
  dec(j);
  repeat
  inc(k,2);
  until Prost(k);
  a[i,j]:=k;
 end;
while j>r+1 do{влево и вверх}
 begin
  dec(i);
  dec(j);
  repeat
  inc(k,2);
  until Prost(k);
  a[i,j]:=k;
 end;
dec(i); {конец вика, перейдем на следующий ввер}
repeat
 inc(k);
until Prost(k);{следующее простое}
a[i,j]:=k;
inc(r);{номер следующего витка}
until r>p-1;
for i:=1 to n do
 begin
  for j:=1 to n do
  write(a[i,j]:4);
  writeln;
 end;
readln
end.