Списки и указатели. Вставить новый элемент перед каждым вхождением заданного элемента

type
  TItem = integer;
 
  L = ^node;
  node =
  record
     data : TItem;
     next : L;
  end;
 
procedure AddList(var head, tail : L; value : TItem);
var new_node : L;
begin
   new(new_node);
   new_node^.next := nil;
   new_node^.data := value;
   if head = nil then
      head := new_node
   else
      tail^.next := new_node;
   tail := new_node;
end;
 
procedure AppendBefore(what, where : TItem; var head : L);
var
   prev, new_node : L;
   pt : L;
   count : integer;
begin
   prev := nil; count := 0;
   pt := head;
   while pt <> nil do
   begin
      if pt^.data = where then
      begin
         inc(count);
         new(new_node);
         new_node^.data := what;
         new_node^.next := pt;
         if prev = nil then
            head := new_node
         else
            prev^.next := new_node;
      end;
      prev := pt;
      pt := pt^.next;
   end;
   if count = 0 then writeln('no elements <', where, '> found');
end;
 
procedure Print(head : L);
begin
   while head <> nil do
   begin
      write(head^.data:4);
      head := head^.next;
   end;
   writeln;
end;
 
var
   head, tail : L;
begin
   head := nil; tail := nil;
   AddList(head, tail, 24);
   AddList(head, tail, 44);
   AddList(head, tail, 44);
   AddList(head, tail, 64);
   AddList(head, tail, 12);
   AddList(head, tail, 324);
   AddList(head, tail, 44);
   Print(head);
 
   AppendBefore(77, 44, head);
   Print(head);
 
   { Добавляй удаление списка }
 
end.