Составить программу, которая вставляет в список L новый элемент F

program Project1;
 
type
  {Тип основных данных.}
  TData = Integer;
  {Тип указателя на элемент списка.}
  TPElem = ^TElem;
  {Тип элемента списка.}
  TElem = record
    Data : TData; {Основные данные.}
    PNext : TPElem; {Указатель на следующий элемент списка.}
  end;
  {Тип, описывающий однонаправленный список.}
  TDList = record
    PFirst, PLast : TPElem; {Указатели на первый и на последний элементы списка.}
  end;
 
{Начальная инициализация списка. Внимание! Эту процедуру можно выполнять
только в отношении пустого списка! Иначе - будут утечки памяти.}
procedure Init(var aList : TDList);
begin
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
{Добавление элемента в конец однонаправленного списка.}
procedure Add(var aList : TDList; const aData : TData);
var
  PElem : TPElem;
begin
  New(PElem);
  PElem^.Data := aData;
  PElem^.PNext := nil;
  if aList.PFirst = nil then
    aList.PFirst := PElem
  else
    aList.PLast^.PNext := PElem;
  aList.PLast := PElem;
end;
 
{Особождение памяти, занятой под список.}
procedure Free(var aList : TDList);
var
  PNext, PDel : TPElem;
begin
  PNext := aList.PFirst;
  while PNext <> nil do begin
    PDel := PNext;
    PNext := PNext^.PNext;
    Dispose(PDel);
  end;
  Init(aList);
end;
 
{Распечатка однонаправленного списка.}
procedure WriteList(const aList : TDList);
var
  PElem : TPElem;
begin
  if aList.PFirst = nil then begin
    Write('Список пуст.');
    Exit;
  end;
 
  PElem := aList.PFirst;
  while PElem <> nil do begin
    if PElem <> aList.PFirst then Write(', ');
    Write(PElem^.Data);
    PElem := PElem^.PNext;
  end;
end;
 
var
  L : TDList;
  PElem, PPrev, PNew : TPElem;
  Data, E, F : TData;
  i, Code : Integer;
  S : String;
begin
  {Начальная инициализация списка.}
  Init(L);
 
  repeat
    //Создание списока.
    Writeln('Создание списка.');
    Writeln('Прекратить ввод - пустая строка + Enter.');
    i := 0;
    repeat
      Write('Элемент ', i + 1, ': ');
      Readln(S);
      if S <> '' then begin
        Val(S, Data, Code);
        if Code = 0 then begin
          Inc(i);
          Add(L, Data);
        end else
          Writeln('Неверный ввод. Повторите.');
      end;
    until S = '';
    Writeln('Составлен список:');
    WriteList(L);
    Writeln;
 
    repeat
      Write('Задайте значение искомого элемента (E): ');
      Readln(S);
      Val(S, E, Code);
      if Code <> 0 then
        Writeln('Неверный ввод. Повторите.');
    until Code = 0;
    repeat
      Write('Задайте значение вставляемого элемента (F): ');
      Readln(S);
      Val(S, F, Code);
      if Code <> 0 then
        Writeln('Неверный ввод. Повторите.');
    until Code = 0;
 
    {Ищем первый элемент со значением E и в случае его обнаружения
    вставляем перед ним элемент со значением F.
    Чтобы вставить перед элементом новый элемент мы должны знать указатель
    на предыдущий элемент. Для этого заведена переменная PPrev.}
    PPrev := nil; {Указатель на предыдущий элемент списка.}
    PElem := L.PFirst; {Указатель на текущий элемент списка.}
    PNew := nil; {Указатель на новый элемент.}
    while (PElem <> nil) and (PNew = nil) do
      if PElem^.Data = E then begin
        {Выделяем память для нового элемента и получаем указатель на неё.}
        New(PNew);
        {Записываем данные.}
        PNew^.Data := F;
        {К новому элементу прикрепляем ту часть списка, которая идёт после элемента PPrev.}
        PNew^.PNext := PElem;
        {К элелменту PPrev прикрепляем элемент PNew. (А к PNew уже прикреплена остальная часть списка.)}
        if PPrev = nil then
          L.PFirst := PNew
        else
          PPrev^.PNext := PNew;
      end else begin {Переходим к следующей паре элементов.}
        PPrev := PElem;
        PElem := PElem^.PNext; {Получаем указатель на следующий элемент списка.}
      end;
 
    if PNew <> nil then begin
      Writeln('Новый элемент F вставлен в список.');
      Writeln('Список после вставки:');
      WriteList(L);
      Writeln;
    end else
      Writeln('Элемента Е нет в списке. Новый элемент F в список не вставлен.');
 
    {Освобождение памяти, занятой под список.}
    Free(L);
    Writeln('Память, занятая под список, освобождена. Работа завершена.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.