Разработать программу шифрования и расшифровки текста

program Project1;
 
{Кодирование/декодирование.}
function EncDec(S : String) : String;
var
  i, j : Integer;
  Ct, C1, C2 : Byte;
begin
  {Перебор пар символов.}
  for i := 1 to Length(S) div 2 do begin
    {Индекс второго символа в очередной паре.}
    j := i * 2;
    {Определяем коды символов в паре.}
    C1 := Ord(S[j - 1]);
    C2 := Ord(S[j]);
    {Меняем местами младшие 4 бита.}
    Ct := C1;
    {(C1 and $F0) - обнуление 4-ёх младших разрядов в C1.
     (C2 and $0F) - обнуление 4-ёх старших разрядов в C2.}
    C1 := (C1 and $F0) or (C2 and $0F);
    C2 := (C2 and $F0) or (Ct and $0F);
    {Заменяем прежние символы на символы с новыми кодами.}
    S[j - 1] := Chr(C1);
    S[j] := Chr(C2);
  end;
  EncDec := S;
end;
 
var
  S : String;
begin
  repeat
    Writeln('Задайте текст:');
    Readln(S);
 
    Writeln('Закодированный текст:');
    S := EncDec(S);
    Writeln(S);
 
    Writeln('Раскодированный текст:');
    S := EncDec(S);
    Writeln(S);
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.