Определить, будет ли пешеход переходить дорогу. Верно ли я решил задачу?

procedure Solve(A, B : boolean; C: integer);
var r: boolean;
begin
case C of
1: { - послушный и осторожный }
r:= A and not B;
2: { - послушный, но беспечный }
r:= A;
3: { - хитрый вольнодумец }
r:= not A and not B;
4: { - непримиримый вольнодумец }
r:= not A;
5: { - экстремал }
r:= not A and B;
6: { - безбашенный }
r:= true;
7: { - запуганый }
r:= false;
else
r:= false;
end;
if r
then Writeln('Вперед!')
else Writeln('Стой!');
end;
 
var X: char;
A, B : boolean;
C : integer;
 
begin
repeat
Write('Характер пешехода (1..7)= '); Readln(C);
if C=0 then break;
Write('Светофор зеленый? '); Readln(X);
A:= X='y';
Write('Есть опасность от транспорта? '); Readln(X);
B:= X='y';
Solve(A, B, C);
until false
end.

var
  a, b: boolean;
  c: integer;
 
procedure Reshenie (a, b: boolean; c: integer);
var
  x, y: string;
begin
  x := 'Пешеход станет переходить улицу';
  y := 'Пешеход не станет переходить улицу';
  Case c Of
    1: If (a = True) and (b = False) Then WriteLn (x) Else WriteLn (y);
    2: If (a = True) Then WriteLn (x) Else WriteLn (y);
    3: If (a = False) and (b = False) Then WriteLn (x) Else WriteLn (y);
    4: If (a = False) Then WriteLn (x) Else WriteLn (y);
    5: If (a = False) and (b = True) Then WriteLn (x) Else WriteLn (y);
    6: WriteLn (x);
    7: WriteLn (y)
  End;
End;
 
Begin
  WriteLn ('Введите True, если горит зелёный сигнал светофора, иначе False');
  ReadLn (a);
  WriteLn ('Введите True, если поблизости опасно движется транспорт, иначе False');
  ReadLn (b);
  WriteLn ('Введите число от 1 до 7, определяющее характер пешехода так:');
  WriteLn ('1 - послушный и осторожный — учитывает и светофор и опасность;');
  WriteLn ('2 - послушный, но беспечный — смотрит только на светофор');
  WriteLn ('3 - хитрый вольнодумец — идет только на красный, если это ничем не грозит;');
  WriteLn ('4 - непримиримый вольнодумец — идет только на красный;');
  WriteLn ('5 - экстремал — идет только на красный, и так, чтобы грозила опасность;');
  WriteLn ('6 - «безбашенный» — идет, несмотря ни на что;');
  WriteLn ('7 - запуганный — никогда не идет через дорогу, а ищет подземный переход');
  Repeat
    Write ('c = ');  ReadLn(c);
    If (c < 1) or (c > 7) Then WriteLn ('Ошибка! Число должно быть от 1 до 7');
  Until (c > 0) and (c < 8);
  Reshenie (a, b, c);
  ReadLn
End.

If a and not b Then ...

procedure Solve(A, B: boolean; C: integer);
var r: boolean;
begin
  r:= false;              { - запуганый и прочие }
  case C of
  1: r:= A and not B;     { - послушный и осторожный }
  2: r:= A;               { - послушный, но беспечный }
  3: r:= not A and not B; { - хитрый вольнодумец }
  4: r:= not A;           { - непримиримый вольнодумец }
  5: r:= not A and B;     { - экстремал }
  6: r:= true;            { - безбашенный }
  end;
  if r then Writeln('Вперед!') else Writeln('Стой!');
end;

procedure Solve(A, B: boolean; C: integer);
var r: boolean;
begin
  case C of
  1: r:= A and not B;     { - послушный и осторожный }
  2: r:= A;               { - послушный, но беспечный }
  3: r:= not A and not B; { - хитрый вольнодумец }
  4: r:= not A;           { - непримиримый вольнодумец }
  5: r:= not A and B;     { - экстремал }
  6: r:= true;            { - безбашенный }
  7: r:= false;           { - запуганый }
  else begin WriteLn('*** Ошибка: неизвестный характер.'); Exit; end;
  end;
  if r then Writeln('Вперед!') else Writeln('Стой!');
end;

procedure Solve(A, B: boolean; C: integer);
begin
  if (c<1) or (c>7) 
  then WriteLn('*** Ошибка: неизвестный характер.')
  else if (c=1) and A and not B  { - послушный и осторожный }
    or (c=2) and A               { - послушный, но беспечный }
    or (c=3) and not A and not B { - хитрый вольнодумец }
    or (c=4) and not A           { - непримиримый вольнодумец }
    or (c=5) and not A and B     { - экстремал }
    or (c=6)                     { - безбашенный }
  then Writeln('Вперед!')
  else Writeln('Стой!');
end;