Узнать текущее время, часы, минуты, секунды по отдельности

@Alex Spacon · Регистрация: 03.10.2015

Author24 — интернет-сервис помощи студентам

Какая функция в Паскале (Именно Pascal ABC.NET) позволяет узнать текущее время, желательно ЧАСЫ, МИНУТЫ, СЕКУНДЫ по отдельности. На Турбо это есть, на ABC (без .NET) читал, тоже вроде как имеется. Но вот как в .NET это реализовать?
Надо что-то типа

.... Бла-бал-бла....

H := ТекущееВремя.Часы;
M := ТекущееВремя.Минуты;
S := ТекущееВремя.Секунды;

Ну и с датой можно также поступить?
Что-то покопался в справке, в Сети, может к вечеру глаз замылил, но не могу найти...

@volvo · 09.10.2015, 17:55

Pascal

1 2	var dt : System.DateTime := System.DateTime.Now; { и работаешь с dt.Hour, dt.Minute, dt.Second }

@Puporev · 09.10.2015, 17:57

Pascal

uses System;
begin
  var d: DateTime := DateTime.Now;
  writeln(d.Day,'.',d.Month,'.',d.Year);
  writeln(d.Hour,':',d.Minute,':',d.Second);
end.

@Alex Spacon · 10.10.2015, 11:38 **[ТС]**

Всем спасибо. Вот что выродил! Еще теперь бы рашпилем доработать...

Pascal

Program Karry_Clock; //Электронные часы
{$version v.1.00}
 
uses
  GraphABC, System;
 
Const FS = clYellow; // Цвет цифр
      FF = clBlack;  // Цвет фона
 
Var MaxX, maxY: Integer;        // Максимальные размеры экрана
    CenterX, CenterY: Integer;  // Центр окна программы
    XH1, XH2, YH1: Integer;     // Позиции часовых цифр
    XM1, XM2, YM1: Integer;     // Позиции минутных цифр
    XS1, XS2, YS1: Integer;     // Позиции секундных цифр
    Kf: real;                   // Коэффициент (массштаб) цифр
    FlagKey: boolean;           // Флаг нажатия клавиши
    H1, H2: array [1..2] of Integer;    // Цифры часов и минут по разрядам
    M1, M2: array [1..2] of Integer;    // Цифры часов и минут по разрядам
    S1, S2: array [1..2] of Integer;    // Цифры секунд по разрядам
    
Procedure Quit (Key: integer);  // Процедура, меняющая значение флага при нажатии клавиши Escape
  Begin                         
  If Key = VK_Escape then
    Begin
    FlagKey := false;    // Меняем флаг
    End;
  End;    
 
Procedure Segment (X, Y: Integer; Kf: Real; N: Char);
  Begin
    Pen.Color   := FS;
    Brush.Color := FS;
    
    If N = 'A' Then // Сегмент A
    Begin
      MoveTo (Round (X + 11 * Kf), Round (Y + 10 * Kf));
      LineTo (Round (X + 21 * Kf), Round (Y + 20 * Kf));
      LineTo (Round (X + 59 * Kf), Round (Y + 20 * Kf));
      LineTo (Round (X + 69 * Kf), Round (Y + 10 * Kf));
      LineTo (Round (X + 59 * Kf), Round (Y));
      LineTo (Round (X + 21 * Kf), Round (Y));
      LineTo (Round (X + 11 * Kf), Round (Y + 10 * Kf));
      FloodFill (Round (X + 13 * Kf), Round (Y + 10 * Kf), FS)
    End;
    
    If N = 'B' Then // Сегмент B
    Begin
      MoveTo (Round (X + 70 * Kf), Round (Y + 11 * Kf));
      LineTo (Round (X + 60 * Kf), Round (Y + 21 * Kf));
      LineTo (Round (X + 60 * Kf), Round (Y + 59 * Kf));
      LineTo (Round (X + 70 * Kf), Round (Y + 69 * Kf));
      LineTo (Round (X + 80 * Kf), Round (Y + 59 * Kf));
      LineTo (Round (X + 80 * Kf), Round (Y + 21 * Kf));
      LineTo (Round (X + 70 * Kf), Round (Y + 11 * Kf));
      FloodFill (Round (X + 70 * Kf), Round (Y + 13 * Kf), FS)
    End;    
    
    If N = 'C' Then // Сегмент C
    Begin
      MoveTo (Round (X + 70 * Kf), Round (Y + 71 * Kf));
      LineTo (Round (X + 60 * Kf), Round (Y + 81 * Kf));
      LineTo (Round (X + 60 * Kf), Round (Y +119 * Kf));
      LineTo (Round (X + 70 * Kf), Round (Y +129 * Kf));
      LineTo (Round (X + 80 * Kf), Round (Y +119 * Kf));
      LineTo (Round (X + 80 * Kf), Round (Y + 81 * Kf));
      LineTo (Round (X + 70 * Kf), Round (Y + 71 * Kf));
      FloodFill (Round (X + 70 * Kf), Round (Y + 73 * Kf), FS)
    End;  
    
    If N = 'F' Then // Сегмент F
    Begin
      MoveTo (Round (X + 10 * Kf), Round (Y + 11 * Kf));
      LineTo (Round (X), Round (Y + 21 * kf));
      LineTo (Round (X), Round (Y + 59 * Kf));
      LineTo (Round (X + 10 * Kf), Round (Y + 69 * Kf));
      LineTo (Round (X + 20 * Kf), Round (Y + 59 * Kf));
      LineTo (Round (X + 20 * Kf), Round (Y + 21 * Kf));
      LineTo (Round (X + 10 * Kf), Round (Y + 11 * Kf));
      FloodFill (Round (X + 10 * Kf), Round (Y + 13 * Kf), FS)
    End;
 
    If N = 'E' Then // Сегмент E  (2)
    Begin
      MoveTo (Round (X + 10 * Kf), Round (Y + 71 * Kf));
      LineTo (Round (X), Round (Y + 81 * kf));
      LineTo (Round (X), Round (Y +119 * Kf));
      LineTo (Round (X + 10 * Kf), Round (Y +129 * Kf));
      LineTo (Round (X + 20 * Kf), Round (Y +119 * Kf));
      LineTo (Round (X + 20 * Kf), Round (Y + 81 * Kf));
      LineTo (Round (X + 10 * Kf), Round (Y + 71 * Kf));
      FloodFill (Round (X + 10 * Kf), Round (Y + 73 * Kf), FS)
    End;    
    
    If N = 'G' Then // Сегмент G (6)
    Begin
      MoveTo (Round (X + 11 * Kf), Round (Y + 70 * Kf));
      LineTo (Round (X + 21 * Kf), Round (Y + 80 * Kf));
      LineTo (Round (X + 59 * Kf), Round (Y + 80 * Kf));
      LineTo (Round (X + 69 * Kf), Round (Y + 70 * Kf));
      LineTo (Round (X + 59 * Kf), Round (Y + 60 * Kf));
      LineTo (Round (X + 21 * Kf), Round (Y + 60 * Kf));
      LineTo (Round (X + 11 * Kf), Round (Y + 70 * Kf));
      FloodFill (Round (X + 13 * Kf), Round (Y + 70 * Kf), FS)
    End;
    
    If N = 'D' Then // Сегмент D
    Begin
      MoveTo (Round (X + 11 * Kf), Round (Y +130 * Kf));
      LineTo (Round (X + 21 * Kf), Round (Y +140 * Kf));
      LineTo (Round (X + 59 * Kf), Round (Y +140 * Kf));
      LineTo (Round (X + 69 * Kf), Round (Y +130 * Kf));
      LineTo (Round (X + 59 * Kf), Round (Y +120 * Kf));
      LineTo (Round (X + 21 * Kf), Round (Y +120 * Kf));
      LineTo (Round (X + 11 * Kf), Round (Y +130 * Kf));
      FloodFill (Round (X + 13 * Kf), Round (Y + 130 * Kf), FS)
    End;  
  End;                                     // Конец процедуры рисования сигментов цифр
  
Procedure ClrS (X, Y: Integer; Kf: Real);  // Очистка цифр, закрашивание цветом фона
  Begin
    Pen.Color   := FF;
    Brush.Color := FF;
    FillRect(X, Y, Round (X + 80 * Kf) + 1, Round (Y + 140 * Kf) + 1);
  End;
  
Procedure Cifer (X, Y, Cif: Integer; Kf: Real); // Рисование цифр
  Begin
  
  If Cif = 1 Then // Рисуем циферь 1
    Begin
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'C');
    End;
  
  If Cif = 2 Then // Рисуем циферь 2
    Begin
      Segment (X, Y, Kf, 'A');
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'G');
      Segment (X, Y, Kf, 'E');
      Segment (X, Y, Kf, 'D');
    End;
    
    If Cif = 3 Then // Рисуем циферь 3
    Begin
      Segment (X, Y, Kf, 'A');
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'G');
      Segment (X, Y, Kf, 'C');
      Segment (X, Y, Kf, 'D');
    End; 
    
    If Cif = 4 Then // Рисуем циферь 4
    Begin
      Segment (X, Y, Kf, 'F');
      Segment (X, Y, Kf, 'G');
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'C');
    End; 
    
    If Cif = 5 Then // Рисуем циферь 5
    Begin
      Segment (X, Y, Kf, 'A');
      Segment (X, Y, Kf, 'F');
      Segment (X, Y, Kf, 'G');
      Segment (X, Y, Kf, 'C');
      Segment (X, Y, Kf, 'D');
    End; 
    
    If Cif = 6 Then // Рисуем циферь 6
    Begin
      Segment (X, Y, Kf, 'A');
      Segment (X, Y, Kf, 'F');
      Segment (X, Y, Kf, 'E');
      Segment (X, Y, Kf, 'D');
      Segment (X, Y, Kf, 'C');
      Segment (X, Y, Kf, 'G');
    End; 
    
    If Cif = 7 Then // Рисуем циферь 7
    Begin
      Segment (X, Y, Kf, 'A');
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'C');
    End;
    
    If Cif = 8 Then // Рисуем циферь 8
    Begin
      Segment (X, Y, Kf, 'G');
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'A');
      Segment (X, Y, Kf, 'F');
      Segment (X, Y, Kf, 'C');
      Segment (X, Y, Kf, 'D');
      Segment (X, Y, Kf, 'E');
    End;
    
    If Cif = 9 Then // Рисуем циферь 9
    Begin
      Segment (X, Y, Kf, 'G');
      Segment (X, Y, Kf, 'F');
      Segment (X, Y, Kf, 'A');
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'C');
      Segment (X, Y, Kf, 'D');
    End;
    
    If Cif = 0 Then // Рисуем циферь 0
    Begin
      Segment (X, Y, Kf, 'B');
      Segment (X, Y, Kf, 'C');
      Segment (X, Y, Kf, 'D');
      Segment (X, Y, Kf, 'E');
      Segment (X, Y, Kf, 'F');
      Segment (X, Y, Kf, 'A');
    End;
    
  End;
 
  
BEGIN
  Window.Title := 'Электронные часы от Карины';
  Window.IsFixedSize := True;
  MaximizeWindow;
  //SetWindowSize (640, 480);
  Window.Clear(clBlack);
  Window.CenterOnScreen;
  MaxY := WindowHeight;
  MaxX :=  WindowWidth;
  Kf := MaxX/(380+20);
  CenterX := Round (MaxX / 2);
  CenterY := Round (MaxY / 2);
      
  YH1 := CenterY - Round ( 70 * Kf) - 50;
  YM1 := CenterY - Round ( 70 * Kf) - 50;
  YS1 := CenterY + Round ( 70 * Kf) + 20;
  XH1 := CenterX - Round (190 * Kf);
  XH2 := CenterX - Round (100 * Kf);
  XM1 := CenterX + Round ( 20 * Kf);
  XM2 := CenterX + Round (110 * Kf);
  XS1 := CenterX - Round (40 * Kf);
  XS2 := CenterX + Round (10 * Kf);
    
  Pen.Width   := 1;
  FlagKey     := true; // Установим флаг в true
  Pen.Color   := FS;
  Brush.Color := FS;
  
  var CurDT1: DateTime := DateTime.Now;
  
  H1[1] := Trunc (CurDT1.Hour/10);     // Десятки часов
  H2[1] := CurDT1.Hour - H1[1]*10;     // Единицы часов
  M1[1] := Trunc (CurDT1.Minute/10);   // Десятки минут
  M2[1] := CurDT1.Minute - M1[1]*10;   // Единицы минут
  S1[1] := Trunc (CurDT1.Second/10);   // Десятки секунд
  S2[1] := CurDT1.Second - S1[1]*10;   // Единицы секунд
    
  Cifer (XH1, YH1, H1[1], Kf);
  Cifer (XH2, YH1, H2[1], Kf);
  Cifer (XM1, YM1, M1[1], Kf);
  Cifer (XM2, YM1, M2[1], Kf);
  Cifer (XS1, YS1, S1[1], Round (Kf/2));
  Cifer (XS2, YS1, S2[1], Round (Kf/2));
  
  Repeat
    
    var CurDT: DateTime := DateTime.Now;
    
    H1[1] := Trunc (CurDT.Hour/10);     // Десятки часов
    H2[1] := CurDT.Hour - H1[1]*10;     // Единицы часов
    M1[1] := Trunc (CurDT.Minute/10);   // Десятки минут
    M2[1] := CurDT.Minute - M1[1]*10;   // Единицы минут
    S1[1] := Trunc (CurDT.Second/10);   // Десятки секунд
    S2[1] := CurDT.Second - S1[1]*10;   // Единицы секунд
        
    If S1[2] <> S1[1] Then
    Begin
      S1[2] := S1[1];
      ClrS (XS1, YS1, Round (Kf/2));
      Cifer (XS1, YS1, S1[1], Round (Kf/2));
    End;
    
    If S2[2] <> S2[1] Then
    Begin
      S2[2] := S2[1];
      ClrS (XS2, YS1, Round (Kf/2));
      Cifer (XS2, YS1, S2[1], Round (Kf/2));
    End;
    
    If M1[2] <> M1[1] Then
    Begin
      M1[2] := M1[1];
      ClrS (XM1, YM1, Kf);
      Cifer (XM1, YM1, M1[1], Kf);
    End;
    
    If M2[2] <> M2[1] Then
    Begin
      M2[2] := M2[1];
      ClrS (XM2, YM1, Kf);
      Cifer (XM2, YM1, M2[1], Kf);
    End;
    
    If H1[2] <> H1[1] Then
    Begin
      H1[2] := H1[1];
      ClrS (XH1, YH1, Kf);
      Cifer (XH1, YH1, H1[1], Kf);
    End;
   
    If H2[2] <> H2[1] Then
    Begin
      H2[2] := H2[1];
      ClrS (XH2, YH1, Kf);
      Cifer (XH2, YH1, H2[1], Kf);
    End;    
    
  Onkeydown := quit; // Ждем нажатия Escape
  Until not FlagKey;
    
  Window.Title := 'Электронные часы от Карины. Программа завершена!';
  Sleep (500);
  CloseWindow;         // Закрытие окна
END.

А через какую хитрозакрученную функцию получить текущий день недели?
Пошарился в Сети, везде предлагается алгоритм вывода дня недели, исходя из введенного номера. А мне надо что бы компьютер сам сказал или день или хотя бы номер дня недели.

@Puporev · 10.10.2015, 11:49

Я так делал

Pascal

uses System;
const 
  week:array[1..7] of string = ('Понедельник','Вторник','Среда','Четверг','Пятница','Суббота','Воскресенье');
var
  a:DateTime;
  b:integer;
  c:byte;
begin
a:=DateTime.Now;
b:=a.day;
c:=ord(a.DayOfWeek);
writeln(c);//если нужен только номер
write('Сегодня ',b,' ',week[c]);//если нужно название
end.

@volvo · 10.10.2015, 12:01

Alex Spacon, поменяй свою ужасно тормозящую (из-за FloodFill) процедуру Segment вот на такую:

Pascal

procedure Segment(X, Y: Integer; Kf: Real; N: Char);
var
  p: array of Point;
var
  arrX: array[1.. 7, 1.. 7] of integer := 
  (
      (11, 21, 59, 69, 59, 21, 11),
      (70, 60, 60, 70, 80, 80, 70),
      (70, 60, 60, 70, 80, 80, 70),
      (10, 0, 0, 10, 20, 20, 10),
      (10, 0, 0, 10, 20, 20, 10),
      (11, 21, 59, 69, 59, 21, 11),
      (11, 21, 59, 69, 59, 21, 11)
  );
var
  arrY: array[1.. 7, 1.. 7] of integer := 
  (
      (10, 20, 20, 10,  0,  0, 10),
      (11, 21, 59, 69, 59, 21, 11),
      (71, 81, 119, 129, 119, 81, 71),
      (11, 21, 59, 69, 59, 21, 11),
      (71, 81, 119, 129, 119, 81, 71),
      (70, 80, 80, 70, 60, 60, 70),
      (130, 140, 140, 130, 120, 120, 130)
  );
  ix: integer;
 
begin
  Pen.Color   := FS;
  Brush.Color := FS;
  ix := Pos(N, 'ABCFEGD');
  SetLength(P, 7);
  for var i := 0 to 6 do
  begin
    p[i].X := Round(X + arrX[ix, i + 1] * Kf);
    p[i].Y := Round(Y + arrY[ix, i + 1] * Kf);
  end;
  
  FillPolygon(p);
end;// Конец процедуры рисования сигментов цифр

, она тут же перестанет тормозить.

@Alex Spacon · 10.10.2015, 12:01 **[ТС]**

Класс!!! Я вроде так и делал, используя по аналогу Дня, Месяца и Года a.DayOfWeek, но почему-то не фунциклировало. СПАСИБО!

И про замену тоже думал, но пока лениво было вошкаться. Раньше таких примочек не встречал. СПАСИБО! Но при небольшом тормозе цифры видно как прорисовываются, а не резко выскакивают, я даже изначально специально Sleep ставил.
Я так понимаю, эта новая процедура тоже под различные разрешения монитора адаптирована?

@volvo · 10.10.2015, 12:19

Сообщение от Alex Spacon

Я так понимаю, эта новая процедура тоже под различные разрешения монитора адаптирована?

Она работает абсолютно так же, как работала та, старая.

@Alex Spacon · 10.10.2015, 12:27 **[ТС]**

ГЕНИАЛЬНО! Маэстро!!! Я уже проверил, всё укучку собрал...
А можно по той процедуре Segment комментов накидать? А то, боюсь, что я сестрёнке объяснить не смогу, хотя потихоньку уже вроде как догадываюсь что к чему.

@volvo · 10.10.2015, 12:33

А какие там комменты нужны? Просто все коэффициенты при X и Y для расчета точек собираем в отдельные массивы (строки - это сегменты, в порядке, заданном строкой 'ABCFEGD'; столбцы - это сами коэффициенты для каждой точки сегмента). Потом просто находим ix - номер сегмента - по его названию (чтобы не пользоваться селекторами типа if then или case of), и собираем массив точек в переменную p. Когда все точки были занесены в массив - вызываем FillPolygon, рисующий по этим точкам заполненный полигон текущими Brush и Pen.

Где именно сложность в понимании?

@Alex Spacon · 11.10.2015, 07:53 **[ТС]**

Дабы излишне не засорять тему, пока отвечу кратко - сложность во всей этой процедуре. Просто раньше не сталкивался. Суть-то я понял, теперь пооператорно буду разбираться. Я же говорю, по-стариковски мастырю, через If-Thet и For-To да Line и Circle.

Добавлено через 41 минуту
Еще один вопрос по ходу этой программки, хоть уже и не в тему. Можно ли из этого безобразия сделать ScreenSaver?

Добавлено через 18 часов 18 минут

Сообщение от Puporev

week:array[1..7] of string = ('Понедельник','Вторник','Среда','Четверг','Пятница','Суббота','Воскресенье');

Можно маленько поправить? Сегодня столкнулся с проблемой, что в ночь с Сб на Вс программулина матюгнулась на массив. Вызвал данные на экран, получилось, что сегодня в Вс CurDT1.DayOfWeek = 0. Покубатурил, понял, что у Америкосов же первый день недели Вс, а нумерация в Паскале не 1-7, а 0-6, переписал код так:

Pascal

1	Den: array[0.. 6] of string = ('воскресенье', 'понедельник', 'вторник', 'среда', 'четверг', 'пятница', 'суббота');

Теперь работает. Но возник вопрос относительно месяцев, они у меня по порядку как у людей, и в массиве [1..12]. Сейчас работают, ждём Нового Года!

Узнать текущее время, часы, минуты, секунды по отдельности

Решение

Решение

Решение

@Alex Spacon 0 / 0 / 0 Регистрация: 03.10.2015 Сообщений: 20
		1
	Узнать текущее время, часы, минуты, секунды по отдельности 09.10.2015, 17:48. Показов 3067. Ответов 10 Метки нет (Все метки) Какая функция в Паскале (Именно Pascal ABC.NET) позволяет узнать текущее время, желательно ЧАСЫ, МИНУТЫ, СЕКУНДЫ по отдельности. На Турбо это есть, на ABC (без .NET) читал, тоже вроде как имеется. Но вот как в .NET это реализовать? Надо что-то типа .... Бла-бал-бла.... H := ТекущееВремя.Часы; M := ТекущееВремя.Минуты; S := ТекущееВремя.Секунды; Ну и с датой можно также поступить? Что-то покопался в справке, в Сети, может к вечеру глаз замылил, но не могу найти... 0

@Alex Spacon 0 / 0 / 0 Регистрация: 03.10.2015 Сообщений: 20
	10.10.2015, 12:01 [ТС]	7
	Класс!!! Я вроде так и делал, используя по аналогу Дня, Месяца и Года a.DayOfWeek, но почему-то не фунциклировало. СПАСИБО! И про замену тоже думал, но пока лениво было вошкаться. Раньше таких примочек не встречал. СПАСИБО! Но при небольшом тормозе цифры видно как прорисовываются, а не резко выскакивают, я даже изначально специально Sleep ставил. Я так понимаю, эта новая процедура тоже под различные разрешения монитора адаптирована? 0

@volvo Супер-модератор 32836 / 21173 / 8148 Регистрация: 22.10.2011 Сообщений: 36,432 Записей в блоге: 8
	10.10.2015, 12:19	8
	Сообщение от Alex Spacon Я так понимаю, эта новая процедура тоже под различные разрешения монитора адаптирована? Она работает абсолютно так же, как работала та, старая. 1

@Alex Spacon 0 / 0 / 0 Регистрация: 03.10.2015 Сообщений: 20
	10.10.2015, 12:27 [ТС]	9
	ГЕНИАЛЬНО! Маэстро!!! Я уже проверил, всё укучку собрал... А можно по той процедуре Segment комментов накидать? А то, боюсь, что я сестрёнке объяснить не смогу, хотя потихоньку уже вроде как догадываюсь что к чему. 0

@volvo Супер-модератор 32836 / 21173 / 8148 Регистрация: 22.10.2011 Сообщений: 36,432 Записей в блоге: 8
	10.10.2015, 12:33	10
	А какие там комменты нужны? Просто все коэффициенты при X и Y для расчета точек собираем в отдельные массивы (строки - это сегменты, в порядке, заданном строкой 'ABCFEGD'; столбцы - это сами коэффициенты для каждой точки сегмента). Потом просто находим ix - номер сегмента - по его названию (чтобы не пользоваться селекторами типа if then или case of), и собираем массив точек в переменную p. Когда все точки были занесены в массив - вызываем FillPolygon, рисующий по этим точкам заполненный полигон текущими Brush и Pen. Где именно сложность в понимании? 1

	11.10.2015, 07:53