Записать в файл информацию, прочитать, вывести самое распространенное имя

const
  fName = 'students.lst';
  
type
  tStudent = record
    /// Фамилия
    family : String[20];
    /// Имя
    name   : String[12];
    /// Пол (true - мужской / false - женский)
    male   : Boolean;
    /// Возраст
    age    : Byte;
    /// Курс
    education : Byte;
  end; // tStudent
 
function sCount : Integer;
begin
  if System.IO.File.Exists(fName) then
    begin
      var f : file of tStudent;
      Reset(f, fName);
      Result := f.FileSize;
      Close(f);
    end
  else
    Result := 0;
end;
 
function Gender : Boolean;
begin
  var answer : String;
  repeat
    answer := ReadLnString('пол (1 - мужской / 0 - женский):');
  until (answer.Length > 0) and (answer[1] in [#48, #49]);
  Result := answer[1] = #49;
end;
 
procedure AddStudent;
begin
  WriteLn(NewLine*5, '='*50, NewLine, 'Введите данные о студенте:');
  var S : tStudent;
  S.family := ReadLnString('фамилия:');
  S.name   := ReadLnString('    имя:');
  S.male   := Gender;
  S.age    := ReadLnInteger('возраст:');
  S.education := ReadlnInteger('   курс:');
  
  var f : file of tStudent;
  if System.IO.File.Exists(fName) then
    begin
      Reset(f, fName);
      Seek(f, f.FileSize);
    end
  else
    Rewrite(f, fName);
    
  Write(f, S);
  Close(f);
end;
 
procedure Wait := ReadLnString('Нажмите ENTER для продолжения.');
 
procedure StatName;
begin
  if sCount = 0 then
    begin
      WriteLn(NewLine*5, 'Нет записей о студентах!', NewLine);
    end
  else
    begin
      var f : file of tStudent;
      var S : tStudent;
      Reset(f, fName);
      var d := new Dictionary<String,Integer>;
      var maxCount := 0;
      while Not EOF(f) do
        begin
          Read(f, S);
          if S.male then
            begin
              var name : String := S.name;
              d[name] := d.Get(name) + 1;
              maxCount := max(maxCount, d.Get(name));
            end;
        end;
      Close(f);
      if maxCount = 0 then
        WriteLn(NewLine*5, 'Нет записей о студентах мужского пола.')
      else
        begin
          Write(NewLine*5, 'Самое распространённое мужское имя:');
          var countNames := 0;
          foreach var z in d do
            if z.Value = maxCount then
              begin
                var name := z.Key;
                Write((countNames > 0 ? ', ' : ' '), name);
                countNames += 1;
              end;
          WriteLn('.');
        end;
    end;
  Wait;
end;
 
procedure MainMenu;
begin
  var answer : String;
  repeat
    WriteLn(NewLine*5, '='*50, NewLine, 'В файле данных записей: ', sCount, NewLine*2, 'Основное меню:');
    WriteLn('-'*30);
    WriteLn('+ (плюс) - добавить студента');
    WriteLn('/ (слэш) - прочитать файл и вывести самое распространённое имя');
    WriteLn('0 (ноль) - выход из программы');
    answer := ReadLnString('.'*30 + NewLine + 'Введите желаемое действие:').ToLower;
    
    if answer.Length > 0 then
      case answer[1] of
        '+' : AddStudent;
        '/' : StatName;
      end;
  until (answer.Length > 0) and (answer[1] = '0');
end;
 
begin
  MainMenu;
  WriteLn(NewLine*5, '='*50, NewLine, 'Программа завершила свою работу.');
end.