Нужно переделать программу,написанную на Turbo Pascal в ту,чтобы работала на Pascal ABC.NET пожалуйста

program lab2;
 
uses
  Crt;
 
const
  Nmax = 15; { MAX element mnozestva A }
 
type
  T = Char; { Tip element mnozestva A }
  TPair = Record
    a, b: T;
  end;
  TSet = Array[1..Nmax] of T;
  TMatrix = Array[1..Nmax, 1..Nmax] of Byte;
 
procedure Sort(var A: TSet; const N: Integer);{ Sortirovka viborom po niubivaniy }
var
  i, j, k: Integer;
  tmp: T;
begin
  for i := 1 to N - 1 do begin
    k := i;
    for j := i + 1 to N do
      if A[j] < A[k] then k := j;
    tmp := A[i];
    A[i] := A[k];
    A[k] := tmp;
  end;
end;
 
function Search(const x: T; const A: TSet; const N: Integer): Integer;
{ Vozvrashenie index elementa x v A, esli elementa net to -1}
var
  i: Integer;
begin
  for i := 1 to N do
    if x = A[i] then begin
      Search := i;
      Exit;
    end;
  Search := -1;
end;
 
function Reflex(const M: TMatrix; const N: Integer): Boolean;{ proverka na reflexsivnost }
var
  i: Integer;
begin
  Reflex := False;
  for i := 1 to N do
    if M[i, i] = 0 then Exit;
  Reflex := True;
end;
 
function Symmetry(const M: TMatrix; const N: Integer): Boolean;{ proverka na semitrichnost }
var
  i, j: Integer;
begin
  Symmetry := False;
  for i := 1 to N - 1 do
    for j := i + 1 to N do
      if M[i, j] <> M[j, i] then Exit;
  Symmetry := True;
end;
 
function Antisymmetry(const M: TMatrix; const N: Integer): Boolean;{ proverka na antisimitrichnost }
var
  i, j: Integer;
begin
  Antisymmetry := False;
  for i := 1 to N do
    for j := 1 to N do
      if (i <> j) and (M[i, j] * M[j, i] <> 0) then Exit;
  Antisymmetry := True;
end;
 
function Transit(const M: TMatrix; const N: Integer): Boolean;
{ proverka na tranzivnost}
var
  i, j, k: Integer;
  S: TMatrix;
begin
  Transit := False;
  for i := 1 to N do
    for j := 1 to N do begin
      S[i, j] := 0;
      for k := 1 to N do
        S[i, j] := S[i, j] or M[i, k] and M[k, j];
    end;
  for i := 1 to N do
    for j := 1 to N do
       if M[i, j] < S[i, j] then Exit;
  Transit := True;
end;
 
procedure Keys; 
{ Vivod klavish }
begin
  ClrScr;
  WriteLn('Viberite deistvie');
  WriteLn;
  WriteLn('1 - spisok elementov mnozestva A');
  WriteLn('2 - spisok par binarnogo otnoshenia');
  WriteLn('3 - matrica binarnogo otnoseniya');
  WriteLn('4 - svoistva binarnogo otnosheniya');
  WriteLn('5 - izmenit 1 paru binarnogo otnosheniya');
  WriteLn('6 - udalit 1 paru binarnogo otnosheniya ');
  WriteLn('7 - dobavit paru binarnogo otnosheniya');
  WriteLn('0 - Ochistit konsol');
  WriteLn('Esc - Zavershit');
  WriteLn
end;
 
var
  i, j, N, k, z: Integer;
  x, y: T;  
  A: TSet;  
  M: TMatrix;
  P: Array[1..Nmax] of TPair;
  F: Boolean;
  v: Char;
begin
  ClrScr;
  WriteLn('Vvedite mnozestvo A -#cherez probel#-');
  N := 0;
  while not SeekEoLn do begin
    Inc(N);
    Read(A[N]);
  end;
  Sort(A, N);
  F := False;
  i := 1;
  while i < N do begin
    if A[i] = A[i + 1] then begin
      F := True;
      Dec(N);
      for j := i to N do
        A[j] := A[j + 1];
    end
    else
      Inc(i);
  end;
  if F then WriteLn('Povtoryayshiesa element udalen');
  for i := 1 to Nmax do
    for j := 1 to Nmax do
       M[i, j] := 0;
  WriteLn;
  WriteLn('Vvedite spisok par. Kazduy paru cherez probel, element par Probel');
  WriteLn(' Zavershenie vmesto vvoda par, vedite  Enter.');
  Reset(Input);
  k := 0;
  while not SeekEoLn do begin
    Read(x);
    if SeekEoLn then Reset(Input);
    ReadLn(y);
    if (Search(x, A, N) = -1) or (Search(y, A, N) = -1) then begin
       WriteLn('Element dolzen iz mnozestva A, eta para propushena');
       Continue;
    end;
    F := False;
    for i := 1 to k do
      if (P[i].a = x) and (P[i].b = y) then begin
         WriteLn('Para povtoryaetsa, Propusheno');
         F := True;
         Break;
      end;
    if F then Continue;
    M[Search(x, A, N), Search(y, A, N)] := 1;
    Inc(k);
    P[k].a := x;
    P[k].b := y;
  end;
  Keys;
  repeat
    v := ReadKey;
    case v of
    '1':
      begin
        WriteLn('Element mnozestva A:');
        for i := 1 to N do
          Write(A[i], ' ');
        WriteLn;
      end;
    '2':
      begin
        WriteLn('Spisok par binarnogo otnosheniya:');
        for i := 1 to k do
          WriteLn(i, '. (', P[i].a, ', ', P[i].b, ')');
      end;
    '3':
      begin
        WriteLn('Matrica binarnogo otnosheniya:');
        Write('    ');
        for i := 1 to N do
          Write(A[i]:3, ' ');
        WriteLn;
        for i := 1 to N do
        begin
          Write(A[i]:3, ' ');
          for j := 1 to N do
            Write(M[i, j]:3, ' ');
          WriteLn;
        end;
      end;
    '4':
      begin
        WriteLn('Videnoe othoshenie');
        if Symmetry(M, N)     then  WriteLn('Simmetrichno')     else WriteLn('ne Simmetrichno ');
        if Antisymmetry(M, N) then  WriteLn('Antisimmetrichno') else WriteLn('ne antisimetrichno');
        if Reflex(M, N)       then  WriteLn('reflixsivno')     else WriteLn('ne reflexsivno');
        if Transit(M, N)      then  WriteLn('trazivno®')     else WriteLn('ne tranzivno');
      end;
    '5':
      begin
        WriteLn('Nomer par kotoruy izmenit');
        {$I-}
        ReadLn(z);
        {$I+}
        while IOResult <> 0 do begin
          WriteLn('Neverno, zanovo');
          {$I-}
          ReadLn(z);
          {$I+}
        end;
        if (z > k) or (z < 1) then
          WriteLn('Par net')
        else begin
          WriteLn('Vvedite novoe znachenie par cherez probel`');
          Reset(Input);
          Read(x);
          if SeekEoLn then Reset(Input);
          ReadLn(y);
          if (Search(x, A, N) = -1) or (Search(y, A, N) = -1) then
            WriteLn('Znachenie dolzn bit iz mnozestva A')
          else begin
            F := False;
            for i := 1 to k do
              if (P[i].a = x) and (P[i].b = y) then begin
                WriteLn('eta para uze bila');
                F := True;
                Break;
              end;
            if not F then begin
              M[Search(P[z].a, A, N), Search(P[z].b, A, N)] := 0;
              P[z].a := x;
              P[z].b := y;
              M[Search(x, A, N), Search(y, A, N)] := 1;
              WriteLn('Izmeneno');
            end;
          end;
        end;
      end;
    '6':
      begin
        WriteLn('Nomer par udaleniya');
        {$I-}
        ReadLn(z);
        {$I+}
        while IOResult <> 0 do begin
          WriteLn('Vvedwno neverno, Zanovo');
          {$I-}
          ReadLn(z);
          {$I+}
        end;
        if (z > k) or (z < 1) then
          WriteLn('ЌҐв в Є®© Ї ал')
        else begin
          M[Search(P[z].a, A, N), Search(P[z].b, A, N)] := 0; { “¤ «пҐ¬ Ї аг Ё§ ¬ ваЁжл }
          Dec(k);
          for i := z to k do  { Udalenie par iz spiska P }
            P[i] := P[i + 1];
          WriteLn('Udaleno');
        end;
      end;
    '7':
      begin
        WriteLn('Vvedite paru elementa cherez probel');
        Reset(Input);
        Read(x);
        if SeekEoLn then Reset(Input);
        ReadLn(y);
        if (Search(x, A, N) = -1) or (Search(y, A, N) = -1) then
          WriteLn('Znachenie dolzno bit iz mnozestva A, ne dobavleno')
        else begin
          F := False;
          for i := 1 to k do
            if (P[i].a = x) and (P[i].b = y) then begin
              WriteLn('Eta para uze est');
              F := True;
              Break;
            end;
          if not F then begin
            Inc(k);
            P[k].a := x;
            P[k].b := y;;
            M[Search(P[k].a, A, N), Search(P[k].b, A, N)] := 1;
          end;
        end;
        if not F then WriteLn('Dobavleno');
      end;
      '0': Keys;
    end;
  until v = #27;
end.