Процедура, вычислить интеграл

@vitavita · Регистрация: 26.03.2017

Студворк — интернет-сервис помощи студентам

Помогите закончить задачу и исправить ошыбки на процедуру: По заданным числам c и d (с < d) вычислить

Интегралы вычислять приближенно по формуле трапеций при n = 20 для первого интеграла и при n = 100 для второго:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Program va;
const n1=20; n2=100;
Procedure int(x:real; var s,h,n,integ:real);
begin
s:=0;
h:=(c-d)/n;
for i:=1 to n-1 do
S:=S+f(c + h*i);
integ:=h*((f(d)+f(c))/2+S);
end;
var d,c,S1,S2,h1,h2,integ1,integ2: real;
    i: integer;
begin
writeln('d,c=: '); readln(d,c);
f:=(arctan(x)*arctan(x));
Procedure(s1,h1,n1);
integ1:=integ;
writeln('Інтеграл1=',integ1:2:2);
d:=0; c:=Pi;
n:=n1;
f:=(sin(exp(ln(e)*(10*x))));
Procedure(s2,h2,n2);
integ2:integ;
writeln('Інтеграл2=',integ2:2:2);
integ:=integ1+integ2;
writeln('Інтеграл=',integ:2:2);
end.

@JuriiMW · 06.04.2017, 05:59

Ошибка в слове „ошибки“:

Сообщение от vitavita

ошыбки

Позор!

Почему у вас какие-то странные недоделанные объявления процедур прямо в модуле программы?

А ещё вторая функция…
Вы хоть можете представить, какой интеграл должен получиться?
Он не влазит в тип Real!
Поэтому, извините за вольность, в прилагаемой программе я фторую функцию интегрирую на интервале [0…π/4].

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
type fType = function (x : Real) : Real;
 
function f1(x : Real) := sqr(arctan(x));
function f2(x : Real) := sin(exp(10*x));
 
function integral(f : fType; a, b : Real; n : Integer) : Real;
begin
  Result := 0;
  var h := (b-a)/2;
  for var i := 1 to n-1 do
    Result += f(a + i*h);
  Result := h * (f(a)/2 + Result + f(b)/2);
end;
 
begin
  var c := ReadReal(' Нижний предел интегрирования первой функции: с =');
  var d := ReadReal('Верхний предел интегрирования первой функции: d =');
  var r1 := integral(f1, c, d, 20);
  var r2 := integral(f2, 0, pi/4, 100);
  WriteLnFormat('Ответ: {0} + {1} = {2}', r1, r2, r1+r2);
end.

P.S. Форматирование действительных переменных не делал из за огромной разницы в значениях интегралов.

ФедосеевПавел · 06.04.2017, 09:16

А почему интеграл второй функции не умещается в real? Результат sin от -1 до +1, значение exp(10*Pi)~exp(31) чуть больше 2⁴⁰.

Добавлено через 11 минут
Это только для второй функции

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
program AnyInt;
 
type
  TMethodFunc = function(a, b: real; n: integer): real;
 
  {интегрируемая функция}
  function F(x: real): real;
  begin
    F :=sin(exp(10*x));
    ;
  end;
 
  function tg(x: real): real;
  begin
    tg := sin(x) / cos(x);
  end;
 
  function IntSympson(a, b: real; n: integer): real;
  var
    Res: real;
    h: real; {величина шага}
    x: real;
    i: integer;
  begin
    h := (b - a) / n;
    Res := F(a) + F(b);
    i := 1;
    while i < n do
    begin
      x := a + i * h;
      Res := Res + 4 * F(x);
      Inc(i);
      x := a + i * h;
      Res := Res + 2 * F(x);
      Inc(i);
    end;
    Res := Res * h / 3;
    IntSympson := Res;
  end;
 
  function IntSquareR(a, b: real; n: integer): real;
  var
    Res: real;
    h: real; {величина шага}
    x: real;
    i: integer;
  begin
    h := (b - a) / n;
    Res := 0;
    i := 1;
    while i <= n do
    begin
      x := a + i * h;
      Res := Res + F(x);
      Inc(i);
    end;
    Res := h * Res;
    IntSquareR := Res;
  end;
 
  function IntTrapec(a, b: real; n: integer): real;
  var
    Res: real;
    h: real; {величина шага}
    x: real;
    i: integer;
  begin
    h := (b - a) / n;
    Res := (F(a) + F(b)) / 2;
    i := 1;
    while i < n do
    begin
      x := a + i * h;
      Res := Res + F(x);
      Inc(i);
    end;
    Res := h * Res;
    IntTrapec := Res;
  end;
 
  function Integral(a, b, Eps: real; IntMethod: TMethodFunc): real;
  var
    n: integer;   {количество подинтервалов интегрирования}
    Icur,         {значение интеграла на текущем шаге итерации}
    Ipre: real;   {значение интеграла на предыдущем шаге итерации}
  begin
    n := 2;
    Icur := IntMethod(a, b, n);
    repeat
      Ipre := Icur;
      n := 2 * n;                {увеличиваем количество подинтервалов}
      Icur := IntMethod(a, b, n);
    until Abs(Icur - Ipre) < Eps;
    Integral := Icur;
  end;
 
 
var
  a, b,        {границы интегрирования}
  Eps: real;   {погрешность численного интегрирования}
begin
  a := 0;
  b := Pi;
 
  WriteLn('      Eps     Sympson  R Squaries  Trapec');
  Eps := 0.001;
  Write(Eps: 10: 6);
  Write(Integral(a, b, Eps, @IntSympson): 10: 6);
  Write(Integral(a, b, Eps, @IntSquareR): 10: 6);
  Write(Integral(a, b, Eps, @IntTrapec): 10: 6);
  WriteLn;
 
  Eps := 0.0001;
  Write(Eps: 10: 6);
  Write(Integral(a, b, Eps, @IntSympson): 10: 6);
  Write(Integral(a, b, Eps, @IntSquareR): 10: 6);
  Write(Integral(a, b, Eps, @IntTrapec): 10: 6);
  WriteLn;
end.

Правда, проверял на FPC в режиме Delphi

Code
1
2
3
     Eps     Sympson  R Squaries  Trapec
  0.001000  0.067794  0.067908  0.067908
  0.000100  0.062478  0.063155  0.063155

Добавлено через 5 минут
Правда, я не доверяю этим результатам, т.к. слишком велика скорость изменения подинтегральной функции. Шаг должен быть менее 1/2⁵⁰.

Добавлено через 21 минуту
----------------------------------
В итоге

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
program Integral;
 
type
  TFunc = function(x: real): real;
 
  {интегрируемая функция}
  function F1(x: real): real;
  begin
    F1 := sqr(arctan(x));
  end;
 
  {интегрируемая функция}
  function F2(x: real): real;
  begin
    F2 := sin(exp(10 * x));
  end;
 
  function IntTrapec(F: TFunc; a, b: real; n: integer): real;
  var
    Res: real;
    h: real; {величина шага}
    x: real;
    i: integer;
  begin
    h := (b - a) / n;
    Res := (F(a) + F(b)) / 2;
    i := 1;
    while i < n do
    begin
      x := a + i * h;
      Res := Res + F(x);
      Inc(i);
    end;
    Res := h * Res;
    IntTrapec := Res;
  end;
 
var
  a, b, d, c,  {границы интегрирования}
  Int1, Int2, Int: real;
begin
  writeln('d,c=: ');
  readln(d, c);
  a := 0;
  b := Pi;
 
  Int1 := IntTrapec(F1, d, c, 20);
  Int2 := IntTrapec(F2, a, b, 100);
  Int  := Int1 + Int2;
  writeln('Інтеграл1=', Int1: 0: 6);
  writeln('Інтеграл2=', Int2: 0: 6);
  writeln('Інтеграл=', Int: 0: 6);
  WriteLn;
end.

@vitavita · 07.04.2017, 18:19 **[ТС]**

Там не h := (b-a)/2, а h := (b-a)/N должно быть. Поменяла, теперь вторую функцию вычисляет с Пи, а не Пи / 4

Новые блоги и статьи Все статьи Все блоги /
Модель ЗдрввоСохранения 7: больше работников, больше ресурсов. anaschu 08.04.2026 работников и заданий может быть сколько угодно, но настроено всё так, что используется пока что только 20% kYBz3eJf3jQ	Дальние перспективы сервера - слоя сети с космологическим дизайном интефейса карты и логики. Hrethgir 07.04.2026 Дальнейшее ближайшее планирование вывело к размышлениям над дальними перспективами. И вот тут может быть даже будут нужны оценки специалистов, так как в дальних перспективах всё может очень сильно. . .	Горе от ума kumehtar 07.04.2026 Эта мне ментальная установка, что вот прямо сейчас, мол, мне для полного счастья не хватает (нужное вписать), и когда я этого достигну - тогда и полный кайф. Одна из самых сильных ловушек на пути. . . .	Использование значений реквизитов справочника в документе, с определенными условиями и правами Maks 07.04.2026 1. Контроль срока действия договора Алгоритм из решения ниже реализован на примере нетипового документа "ЗаявкаНаРаботу", разработанного в конфигурации КА2. Задача: уведомлять пользователя, если. . .
Доступность команды формы по условию Maks 07.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа "СписаниеМатериалов", разработанного в конфигурации КА2. Задача: сделать доступной кнопку (команда формы "ЗавершитьСписание") при. . .	Уведомление о неверно выбранном значении справочника Maks 06.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа "НарядПутевка", разработанного в конфигурации КА2. Задача: уведомлять пользователя, если в документе выбран неверный склад. . .	Установка Qt Creator для C и C++: ставим среду, CMake и MinGW без фреймворка Qt 8Observer8 05.04.2026 Среду разработки Qt Creator можно установить без фреймворка Qt. Есть отдельный репозиторий для этой среды: https:/ / github. com/ qt-creator/ qt-creator, где можно скачать установщик, на вкладке Releases:. . .	AkelPad-скрипты, структуры, и немного лирики.. testuser2 05.04.2026 Такая программа, как AkelPad существует уже давно, и также давно существуют скрипты под нее. Тем не менее, прога живет, периодически что-то не спеша дополняется, улучшается. Что меня в первую очередь. . .

Процедура, вычислить интеграл

Решение

Решение

@vitavita 0 / 0 / 1 Регистрация: 26.03.2017 Сообщений: 18
	07.04.2017, 18:19 [ТС]
	Сообщение было отмечено ФедосеевПавел как решение Решение Там не h := (b-a)/2, а h := (b-a)/N должно быть. Поменяла, теперь вторую функцию вычисляет с Пи, а не Пи / 4 0