Составьте программу, которая напечатает на экране число, удовлетворяющее заданным условиям

function yes(n:integer):boolean;
var m,c,s,p,c4,c7:integer;
begin
m:=n;
s:=0;
p:=0;
c4:=0;
c7:=0;
while m>0 do
 begin
  c:=m mod 10;
  s:=s+c;
  if c=4 then c4:=1;
  if c=7 then c7:=1;
  p:=10*p+c;
  m:=m div 10;
 end;
yes:=(s=39)and(c4=1)and(c7=1)and(p=n);
end;
 
begin
var n:=9999999;
while (n>1000000)and not yes(n) do dec(n);
if n=1000000 then writeln('Такого числа нет')
else writeln(n);
end.

begin
  var a:=arr(9,9,9,9,9,9,9); /// 1.Запись числа состоит из семи цифр. + 6.Число является максимальным
  repeat
    var i := 0;
    a[i] -= 1;
    while a[i] < 0 do
      begin
        a[i] := 9;
        i += 1; if i = 7 then begin WriteLn('Нетуть!'); Halt; end;
        a[i] -= 1;
      end;
  until
    (a.Sum = 39) and /// 2.Сумма всех цифр числа равна 39.
    (a.Count(n->n=4)>0) and /// 3.В записи числа хотя бы одна цифра 4.
    (a.Count(n->n=7)>0) and /// 4.В записи числа хотя бы одна цифра 7.
    (a.JoinIntoString('') = a.Reverse.JoinIntoString('')); /// 5.Запись числа является палиндромом
  foreach var i in a.Reverse do Write(i); WriteLn;
end.

function sc(n:Integer):Integer:=n>0?sc(n div 10)+(n mod 10):0;
function yes(n:Integer):Boolean;
begin
  Result := False;
  if sc(n) <> 39 then Exit;
  if n.ToString.IndexOf('4') < 0 then Exit;
  if n.ToString.IndexOf('7') < 0 then Exit;
  if n.ToString <> n.ToString.Reverse.JoinIntoString('') Then Exit;
  Result := True;
end;
begin
  WriteLn(Range(1000000,9999999).Where(n->yes(n)).Max);
end.

begin
  Range(9999999, 1000000, -1).Select(n -> n.ToString).
  Where(n ->
    (n.Sum(ch -> StrToInt(ch)) = 39) and
    n.Contains('4') and n.Contains('7') and 
    (n = ReverseString(n))  
  ).Take(1).Println;
end.