Можно ли отсылаться из одной функции к какой-то определенной из нескольких? Или вписывать в аргументы формулу

@Ksardas_178 · Регистрация: 01.01.2018

Студворк — интернет-сервис помощи студентам

Есть функция, считающая определенный интеграл от еще одной функции.
Хотелось бы сделать возможным подстановку в нее вместо f(x) еще j(x) и прочих, не переписывая заново для каждого случая. И, желательно, без case-ов, так как придется дублировать циклы

Вот сама ф-ция:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
function Simpson(n:integer):real;//Метод Симпсона
var
 h,x,s:real;
 
begin
  h:=2*l/accuracy;
  x:=-l+h;
  while x<l do
    begin
    result+=(4*Y(x));
    x+=h;
    result+=(2*Y(x));
    x+=h;
  end;
  result:=h/3*(result+Y(a)-Y(b));
end;

Если интересно задание: надо рассчитать коэффициенты для ряда Фурье к заданной f(x) (саму функцию можно вводить прямо в текст программы, тут ограничений нет).

Добавлено через 2 часа 28 минут
Я расписал отдельные функции для A0, An и Bn. Некрасиво, но, похоже, работает. Вопрос до сих пор открыт. И вдруг кто найдет неточности в программе. Буду признателен.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
const accuracy = 10;
 
var l:real;
  n:integer;
 
function Y(x:real):real:=sqrt(1+x*x+2*x);//Функция f(x)
 
function a_nil:real;//A0
var
 h,x,s:real;
 
begin
  h:=2*l/accuracy;
  x:=-l+h;
  while x<l do
    begin
    result+=(4*Y(x));
    x+=h;
    result+=(2*Y(x));
    x+=h;
  end;
  result:=h/3*(result+Y(-l)-Y(l));
  result/=l;
end;
 
function an(n:integer):real;//Рассчет An
var
 h,x:real;
 
begin
  h:=2*l/accuracy;
  x:=-l+h;
  while x<l do
    begin
    result+=(4*Y(x)*cos(pi*n*x/l));
    x+=h;
    result+=(2*Y(x)*cos(pi*n*x/l));
    x+=h;
  end;
  result:=h/3*(result+Y(-l)-Y(l));
  result/=l;
end;
 
function bn(n:integer):real;//Рассчет Bn
 
var
 h,x:real;
 
begin
  h:=2*l/accuracy;
  x:=-l+h;
  while x<l do
    begin
    result+=(4*Y(x)*sin(pi*n*x/l));
    x+=h;
    result+=(2*Y(x)*sin(pi*n*x/l));
    x+=h;
  end;
  result:=h/3*(result+Y(-l)-Y(l));
  result/=l;
end;
 
begin
  writeln('Введите границы промежутка L. Рассчитываем коэффициенты на [-L;L]: ');
  read(l);
  writeln('Введите n (количество рассчитываемых коэффициентов): ');
  read(n);
  writeln('Преобразованная функция: ');
  writeln(a_nil:6:2,'/2+');
  for var i:integer:=1 to n do writeln('+(',an(i):6:2,'cos(',i,'X)+',bn(i):6:2,'sin(',i,'X))');
end.

@volvo · 12.01.2018, 20:30

Так красивее?

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
const accuracy = 10;
 
var l:real;
  n:integer;
 
function Y(x:real):real:=sqrt(1+x*x+2*x);//Функция f(x)
 
type
  tfunc = function(n : integer; x, l : real) : real;
 
function f(n : integer := 0; func : tfunc := nil) : real;
var
 h,x:real;
begin
  h:=2*l/accuracy;
  x:=-l+h;
  while x<l do
    begin
    result+=(4*Y(x)* (func = nil ? 1.0 : func(n, x, l)));
    x+=h;
    result+=(2*Y(x)*(func = nil ? 1.0 : func(n, x, l)));
    x+=h;
  end;
  result:=h/3*(result+Y(-l)-Y(l));
  result/=l;
end;
 
function fa(n : integer; x, l : real) := cos(pi*n*x/l);
function fb(n : integer; x, l : real) := sin(pi*n*x/l);
 
begin
  writeln('Введите границы промежутка L. Рассчитываем коэффициенты на [-L;L]: ');
  read(l);
  writeln('Введите n (количество рассчитываемых коэффициентов): ');
  read(n);
  writeln('Преобразованная функция: ');
  writeln(f():6:2,'/2+');
  for var i:integer:=1 to n do writeln('+(',f(i, fa):6:2,'cos(',i,'X)+',f(i, fb):6:2,'sin(',i,'X))');
end.

@Ksardas_178 · 14.01.2018, 12:02 **[ТС]**

Гораздо красивее! Спасибо большое.

@Ksardas_178 · 16.01.2018, 00:34 **[ТС]**

Вот. Дописал в графическом представлении. Код тоже не идеален, но теперь стало наглядней и симпатичней для пользователя

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
uses GraphABC;
 
const
  accuracy = 1000;//Точность
  x0 = 450;//Центр системы координат
  y0 = 400;
  scale = 30;//Масштаб
  width = 3;//Толщина линии
 
var
  l: real;
  n: integer;
 
function Y(x: real): real := abs(x+6);//Функция f(x)
 
type
  tfunc = function(n: integer; x, l: real): real;
 
function f(n: integer := 0; func: tfunc := nil): real;
var
  h, x: real;
begin
  h := 2 * l / accuracy;
  x := -l + h;
  while x < l do
  begin
    result += (4 * Y(x) * (func = nil ? 1.0 : func(n, x, l)));
    x += h;
    result += (2 * Y(x) * (func = nil ? 1.0 : func(n, x, l)));
    x += h;
  end;
  result := h / 3 * (result + Y(-l) - Y(l));
  result /= l;
end;
 
function fa(n: integer; x, l: real) := cos(pi * n * x / l);
 
function fb(n: integer; x, l: real) := sin(pi * n * x / l);
 
procedure draw_fx;
var
  h, x, y1, y2: real;
begin
  SetPenWidth(2);
  SetPenColor(RGB(0, 205, 0));
  h := 2 * l / accuracy;
  x := -l + h;
  while x < l do 
  begin
    y1 := -Y(x);
    x += h;
    y2 := -Y(x);
    line(round((x - h) * scale) + x0, round(y1 * scale) + y0, round(x * scale) + x0, round(y2 * scale) + y0);
  end;
end;
 
procedure draw;
var
  h, x, y1, y2: real;
begin
  SetPenWidth(width);
  SetPenColor(RGB(0, 0, 205));
  h := 2 * pi / accuracy;
  x := -pi + h;
  while x < pi do 
  begin
    y1 := -f() / 2;
    for var i: integer := 1 to n do y1 -= f(i, fa) * cos(i * x) + f(i, fb) * sin(i * x);
    x += h;
    y2 := -f() / 2;
    for var i: integer := 1 to n do y2 -= f(i, fa) * cos(i * x) + f(i, fb) * sin(i * x);
    line(round((x - h) * scale * l/pi) + x0, round(y1 * scale) + y0, round(x * scale *l/pi) + x0, round(y2 * scale) + y0);
  end;
end;
 
procedure draw_all;
var
  h, x, y1, y2: real;
begin
  SetPenWidth(width);
  h := 2 * pi / accuracy;
  for var j:integer:=1 to n do 
    begin
  x := -pi + h;
  SetPenColor(RGB(0,round(255-255/n*j),round(255-255/n*j)));
  while x < pi do 
  begin
    y1 := -f() / 2;
    for var i: integer := 1 to j do y1 -= f(i, fa) * cos(i * x) + f(i, fb) * sin(i * x);
    x += h;
    y2 := -f() / 2;
    for var i: integer := 1 to j do y2 -= f(i, fa) * cos(i * x) + f(i, fb) * sin(i * x);
    line(round((x - h) * scale * l/pi) + x0, round(y1 * scale) + y0, round(x * scale *l/pi) + x0, round(y2 * scale) + y0);
  end;
  end;
end;
 
procedure draw_separate;
var
  h, x, y1, y2: real;
begin
  SetPenWidth(width);
  h := 2 * pi / accuracy;
  line(round(-l*scale+x0),round(-f()/2)+y0,round(l*scale)+x0,round(-f()/2)+y0);
  for var i:integer:=1 to n do 
    begin
  x := -pi + h;
  SetPenColor(RGB(random(256),random(256),random(256)));
  while x < pi do 
  begin
    y1:=0;
    y1 -= f(i, fa) * cos(i * x) + f(i, fb) * sin(i * x);
    x += h;
    y2:=0;
    y2 -= f(i, fa) * cos(i * x) + f(i, fb) * sin(i * x);
    line(round((x - h) * scale * l/pi) + x0, round(y1 * scale) + y0, round(x * scale *l/pi) + x0, round(y2 * scale) + y0);
  end;
  end;
end;
 
begin
  randomize;
 
  Window.Width:=900;
  Window.Height:=700;
  writeln('Введите границы отрезка L. Рассчитываем коэффициенты на [-L;L]: ');
  read(l);
  writeln('Введите n (количество рассчитываемых коэффициентов): ');
  read(n);
  writeln('Преобразованная функция: ');
  writeln(f():6:2, '/2+');
  for var i: integer := 1 to n do writeln('+(', f(i, fa):6:2, 'cos(', i, 'X)+', f(i, fb):6:2, 'sin(', i, 'X))');
  
  line(x0, y0 + 30 * scale, x0, y0 - 30 * scale);
  line(x0 + 30 * scale, y0, x0 - 30 * scale, y0);
  
  draw;//Рисуем график Фурье
  draw_all;//Рисовка с постепенным уточнением
  draw_fx;//Исходная функция
  draw_separate;//Рисуем графики отдельно
end.

Новые блоги и статьи Все статьи Все блоги /
Жизнь в неопределённости kumehtar 23.03.2026 Жизнь — это постоянное существование в неопределённости. Например, даже если у тебя есть список дел, невозможно дойти до точки, где всё окончательно завершено и больше ничего не осталось. В принципе,. . .	Модель здравоСохранения: работники работают быстрее после её введения. anaschu 23.03.2026 geJalZw1fLo Корпорация до введения программа здравоохранения имела много невыполненных работниками заданий, после введения программы количество заданий выросло. Но на выплатах по больничным это. . .	1С: Контроль уникальности заводского номера Maks 23.03.2026 Алгоритм контроля уникальности заводского (или серийного) номера на примере документа выдачи шин для спецтехники с табличной частью. Данные берутся из регистра сведений, по которому настроено. . .	Хочу заставить корпорации вкладываться в здоровье сотрудников: делаю мат модель здравосохранения anaschu 22.03.2026 e7EYtONaj8Y Z4Tv2zpXVVo https:/ / github. com/ shumilovas/ med2. git
1С: Программный отбор элементов справочника по группе Maks 22.03.2026 Установка программного отбора элементов справочника "Номенклатура" из модуля формы документа. В качестве фильтра для отбора справочника служит группа номенклатуры. Отбор по наименованию группы. . .	Как я обхитрил таблицу Word Alexander-7 21.03.2026 Когда мигает курсор у внешнего края таблицы, и нам надо перейти на новую строку, а при нажатии Enter создается новый ряд таблицы с ячейками, то мы вместо нервных нажатий Энтеров мы пишем любые буквы. . .	Krabik - рыболовный бот для WoW 3.3.5a AmbA 21.03.2026 без регистрации и смс. Это не торговля, приложение не содержит рекламы. Выполняет свою непосредственную задачу - автоматизацию рыбалки в WoW - и ничего более. Однако если админы будут против -. . .	1С: Программный отбор элементов справочника по значению перечисления Maks 21.03.2026 Установка программного отбора элементов справочника "Сотрудники" из модуля формы документа. В качестве фильтра для отбора служит значение перечислений. / / Событие "НачалоВыбора" реквизита на форме. . .

@Ksardas_178 58 / 42 / 21 Регистрация: 01.01.2018 Сообщений: 273
	14.01.2018, 12:02 [ТС]
	Гораздо красивее! Спасибо большое. 0

Можно ли отсылаться из одной функции к какой-то определенной из нескольких? Или вписывать в аргументы формулу

Решение